コマンドボタンで保存先のフォルダ指定は出来ますか？

質問

OSはWindowsNT、Excel97です。
PC素人の営業さんが使う見積書の作成をしています。
そこで質問です。
コマンドボタンで保存ボタンを作成し、それを押すと「名前をつけて選択」画面が開き、保存先として決まったのフォルダが選択されている状態になっているという事は出来るでしょうか？（要するにフォルダを探す手間を省きたいのです）
保存操作の流れとして、保存コマンドボタンを押す→ファイル名を入れる→保存を押すとしたいのです。
宜しくお願いします。

回答No.3

nishi6 · ベストアンサー

こんな感じでしょうか。コントロールツールボックスのコマンドボタンを使っています。
他Bookの関係が分からないのでExcelの終了はしていません。
終了ボタンのあるシートのコードウインドウに貼り付けます。ご参考に。(Excel2000です。97も問題ないと思います)

Private Sub CommandButton1_Click()
　　Const userPath = "D:\0001\・・・・・" '*** ここでドライブとフォルダを指定する ***

　　Dim myFileName As Variant '保存するファイル名

　　ChDrive userPath 'ドライブ変更
　　ChDir userPath 'フォルダの変更
　　With Application
　　　　'ファイル名を入力
　　　　myFileName = .GetSaveAsFilename(ActiveWorkbook.Name, "excel(*.xls),*.xls")
　　　　'キャンセルでなかったら
　　　　If myFileName <> False Then
　　　　　　'上書き確認
　　　　　　If Dir(myFileName) <> vbNullString Then
　　　　　　　　If MsgBox("既に同名ファイルが存在します。上書きしますか？", vbOKCancel, "上書確認") = vbCancel Then
　　　　　　　　　　Exit Sub '上書きの中止を選択
　　　　　　　　End If
　　　　　　End If
　　　　　　.DisplayAlerts = False 'メッセージを出さないようにする
　　　　　　ActiveWorkbook.SaveAs myFileName '指定ファイル名で保存する
　　　　　　.DisplayAlerts = True 'メッセージ表示を元に戻す
　　　　End If
　　End With
End Sub

お礼

ありがとうございました。