VBの質問です

質問

VB6を使って開発をしています。
AとB２つのMDBがあってAの全テーブルのデータをBの全テーブルにデータをコピーしたいのですがプログラムでどうやるのかがわかりません。
どなたかわかるかた私に教えてください。お願いします。

回答No.6

TAGOSAKU7 · ベストアンサー

サンプルです。

データレコード１件づつやらないでもできます。
CopyTableに二つのファイルパス（元、先）を指定してください。

Private Const CONNECTCONST　　　 As String = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="

Sub Main()
　　Call CopyTable("c:\A.mdb", "c:\B.mdb")
End Sub

Sub CopyTable(inSrcDB As String, inDstDB As String)
　　Dim Cnn As ADODB.Connection
　　Dim Cat As ADOX.Catalog
　　Dim wkTbl　 As ADOX.Table
　　Dim strConnect　As String

　　Dim strTblName　As String

　　Dim strSQL　　　As String

　　'まず初期化
　　Set Cnn = New ADODB.Connection
　　Set Cat = New ADOX.Catalog

　　'DBの接続文字
　　strConnect = CONNECTCONST & inSrcDB & ";"
　　'接続
　　Cnn.Open strConnect
　　'カタログ作成
　　Cat.ActiveConnection = Cnn

　　'カタログの中から、システムテーブル以外のものについて処理を行います。
　　For Each wkTbl In Cat.Tables
　　　　If wkTbl.Type = "TABLE" Then
　　　　　　'テーブル名を取得
　　　　　　strTblName = wkTbl.Name

　　　　　　'コピー先のテーブルデータを削除するSQL文の実行
　　　　　　strSQL = "delete from [" & inDstDB & "]." & strTblName
　　　　　　Cnn.Execute strSQL

　　　　　　'コピー元をコピー先へデータをコピーするSQL文の実行
　　　　　　strSQL = "insert into [" & inDstDB & "]." & strTblName & _
　　　　　　　　" select * from " & strTblName
　　　　　　Cnn.Execute strSQL

　　　　End If
　　Next wkTbl

　　Cnn.Close
　　Set Cnn = Nothing
End Sub