accessでテーブルに数式を保存し、クエリで演算

質問

ID,a,b,sikiという４つのフィールドを持つテーブルを元に
下記のような結果となるクエリを作りたいのです。
数式を簡単に変更できるようにテーブルに保存しようと考えています。

テーブル
ID　　a　　b　　siki
1　　 1　　2　　[a]*100+[b]
2　　 2　　2　　[b]-3
3　　 2　　4　　[a]-700

クエリ実行結果
ID　　kekka
1　　 102
2 　　 -1
3 　　 -698

回答No.6

山田 太郎（@f_a_007） · ベストアンサー

補足：自作関数を利用しない方法！

式1: DLookUp(Replace(Replace([siki],"[A]",[A]),"[B]",[B]),"テーブル名")

クエリのフィールドに直接に上記の式を書く。

PS、AccessのDLookup()はDBLookup()より３倍程処理時間がかかります。それだけの差です。

お礼

ありがとうございます。
いけそうです。
50件ほどのテーブルで使う予定ですので速度はそれほど問題にならないと思います。

replaceって使ったことないんですけど調べてみます。

ほんと助かりました。
ありがとうございました。

回答No.5

noname#212067

よく出来ました、パチパチパチ（拍手）

回答No.4

山田 太郎（@f_a_007）

＞関数を作ったことがない・・・。

Public Function DoKeisan(ByVal X As Double, ByVal Y As Double, ByVal Siki As String) As Double
　　Siki = Replace(Siki, "[A]", X)
　　Siki = Replace(Siki, "[B]", Y)
　　DoKeisan = DBLookup("SELECT " & Siki)
End Function

先の DBLookup()を標準モジュールに登録すれば DoKeisan()は僅かに３行ですよ。

お礼

ありがとうございます。
「標準モジュールに登録」ってとこらへんから勉強してみます。

初質問に回答してもらえてうれしかったです。

回答No.3

山田 太郎（@f_a_007）

補足：DoKeisan()の処理内容に関して。

それは、添付図を見れば一目瞭然です。
式の[A]と[B]とを実際の値に置換。
その後、それをSQL文として実行して結果を求めているだけです。
ただし、そこ場合にDLookup()は使用できませんので下に紹介する代替関数DBLookup()を使用します。
これで、DoKeisan()は僅か3行ほどで完成できる筈です。

Public Function DBLookup(ByVal strQuerySQL As String, _
　　　　　　　　　　　　　Optional ByVal ReturnValue = Null) As Variant
On Error GoTo Err_DBLookup
　　Dim DataValue
　　Dim rst　　　　 As ADODB.Recordset

　　Set rst = New ADODB.Recordset
　　With rst
　　　　.Open strQuerySQL, _
　　　　　　　CurrentProject.Connection, _
　　　　　　　adOpenStatic, _
　　　　　　　adLockReadOnly
　　　　If Not .BOF Then
　　　　　　.MoveFirst
　　　　　　DataValue = .Fields(0)
　　　　End If
　　End With
Exit_DBLookup:
On Error Resume Next
　　rst.Close
　　Set rst = Nothing
　　DBLookup = IIf(Len(DataValue & ""), DataValue, ReturnValue)
　　Exit Function
Err_DBLookup:
　　MsgBox "SELECT 文の実行時にエラーが発生しました。(DBLookup)" & Chr$(13) & Chr$(13) & _
　　　　　 "・Err.Description=" & Err.Description & Chr$(13) & _
　　　　　 "・SQL Text=" & strQuerySQL, _
　　　　　 vbExclamation, " 関数エラーメッセージ"
　　Resume Exit_DBLookup
End Function

お礼

回答ありがとうございます。

関数を作るというのはやったことがないので、すぐに実現するのは無理っぽいですので
強引にでも何か方法考えてみます。

一旦エクセルに渡して、答えをアクセスに戻す。
みたいな感じでいけるでしょうか。

回答No.2

noname#212067

関数化するとこまでは誰でも考え付きそうだが
関数に渡した式をどうやって計算するかってとこだな？
変数に入った式は計算出来ないが
変数に入った式と引数で計算結果を出力するクエリを作成
（テーブルを使用しないクエリ）し
クエリの値を返す関数を作れば出来そうだな
しかし、データが増えると遅くなりそうだが。。。。。

回答No.1

山田 太郎（@f_a_007）

Q、下記のような結果となるクエリを作りたい。
A、祈、奮闘と成功！

? DoKeisan(1, 2, "[a]*100+[b]")
102
? DoKeisan(2, 2, "[b]-3")
-1

私だったら、DoKeisan()　みたいな関数を考えるかな。