非アクティブシートでのグラフ作成方法について

質問

VBAを使ってアクティブなっていないシートのセルを参照したグラフを
作成したいと思っているのですが、可能でしょうか？
また、軸の最少最大値などのグラフの設定を同様に変更することは可能でしょうか？

例
シート１がアクティブになっているときに、
シート２のA1～B5のデータでグラフを作成する。
この時、シート２をアクティブにせずにグラフを作成したい。
さらにシート２をアクティブにせずにグラフの書式等を設定したい。

アクティブになっているシートでグラフを作成するのは
マクロで記録した物をいじくれば問題なく作れると思いますが、
グラフを複数のシートで作成する必要があり、
画面が一々切り替わるのはちょっと・・・と思い、
できればボタンを押して別のシートに移らずにグラフを作成したいのです。

回答No.4

mitarashi

アクティブで無いシートでグラフを作成するコード例です。
1番目のシートのA～C列に、列毎にデータがあり、当該シートにグラフを作成する例です。
どこのシートからでも実行可能です。
さわりしか記してないので応用されるならご自分で添削をお願いします。
Sub test()
Dim mychartObj As ChartObject
Dim targetRange As Range
Dim mySeries As Series
Dim i As Long
Dim sh As Worksheet

Set sh = Sheets(1)
Set mychartObj = sh.ChartObjects.Add(50, 50, 250, 250)
With sh
Set targetRange = Range(.Range("A2"), .Range("A" & .Rows.Count).End(xlUp)).Resize(, 3)
End With
With mychartObj.Chart
.ChartType = xlXYScatter
.HasLegend = False
.Axes(xlCategory).HasMajorGridlines = True
.Axes(xlCategory).MinimumScale = 10
.Axes(xlCategory).MaximumScale = 100
End With
For i = 2 To targetRange.Columns.Count
With mychartObj.Chart
Set mySeries = .SeriesCollection.NewSeries
mySeries.XValues = targetRange.Columns(1)
mySeries.Values = targetRange.Columns(i)
End With
Next i
End Sub

回答No.3

okormazd

#2です。
ちょっと訂正。
「selectメソッドを使わずに」
↓
「selectionを使わずに」

回答No.2

okormazd

selectメソッドを使わずに直接シート名で参照するか、setステートメントでオブジェクト変数を使うようにすれば、
シートをアクティブにすることはないと思うが。

回答No.1

MSZ006

>画面が一々切り替わるのはちょっと・・・と思い

画面が更新されなけばよいのでしたら、マクロの冒頭で
Application.ScreenUpdating = False
という記述をしておき、マクロの最後で
Application.ScreenUpdating = True
としておけば、途中でアクティブシートがコロコロ変わるのが表示されないと思います。