EXCEL VBAで行・列の該当データ

質問

出荷データ一覧のマクロを作りたいのですが、抽出の仕方で苦戦してます。

A2から下方向に商品名、B1から右方向に日付の入ったシートのA3から任意のセル（変わります）に
数値のデータが入ってます。
商品の有無により出荷日は日付通りにいかずランダムになります。
例えば、数値データセルを任意で黄色に塗りつぶしたところの数値と該当する商品名を抽出するにはどうすればいいのでしょうか。

現在は以下のようなマクロを必要数値以外を削除して実行していますが、新しいものを思案中です。

Sub 行列を非表示()
Rows("2:200").Hidden = True
Columns("B:AO").Hidden = True
Selection.SpecialCells(xlCellTypeConstants).EntireRow.Hidden = False
Selection.SpecialCells(xlCellTypeConstants).EntireColumn.Hidden = False
End Sub

回答No.2

keithin · ベストアンサー

＞数値データセルを任意で黄色に塗りつぶしたところの数値と該当する商品名を抽出する

ご利用のエクセルのバージョンが不明ですが、Excel2003以降で。

sub macro1()
　dim c as range
　dim c0 as string

　with range("A1").currentregion
　application.findformat.interior.colorindex = 6
　set c = .find(what:="", searchformat:=true)
　if c is nothing then exit sub
　c0 = c.address

　do
　　if c <> "" then
　　　msgbox cells(c.row, "A") & vblf & c.value
　　end if
　　set c = .find(what:="",after:=c,searchformat:=true)
　loop until c.address = c0
　end with
end sub

あとはまぁ、実際にヤリタカッタ事に応じて適宜応用してみて下さい。

お礼

ありがとうございます。

以下のように変えて思い通りのマクロができました。
まだまだ稚拙ではありますが勉強いたします。
しかし、今回は勉強になりました。
ダブルクォーテーションのないMsgboxを初めてみましたしその他難解なものもありました。

本当にありがとうございました。

Sub macro1()
Dim c As Range
Dim c0 As String
Dim G As Integer
Dim R As Integer

G = 1
R = 1

With Range("A1").CurrentRegion
Application.FindFormat.Interior.ColorIndex = 6
Set c = .Find(what:="", searchformat:=True)
If c Is Nothing Then Exit Sub
c0 = c.Address

Do
If c <> "" Then
D1 = Cells(c.Row, "A")
D2 = c.Value

With Worksheets(1)
.Cells(G, 1) = D1
G = G + 1
.Cells(R, 2) = D2
R = R + 1
End With

End If
Set c = .Find(what:="", after:=c, searchformat:=True)
Loop Until c.Address = c0
End With
End Sub

回答No.1

kybo

元の表の範囲がよくわかりません。

>A2から下方向に商品名

なのに、「A3から任意のセル」というのはおかしくないですか

元の表の範囲がB2:Z1000だとして

Sub macro()
Dim C As Range
For Each C In Range("B2:Z1000").SpecialCells(xlCellTypeConstants)
C.Interior.ColorIndex = 6
MsgBox "数値は：" & C.Value & vbTab & "商品名は：" & Range("A" & C.Row).Value
Next C
End Sub

お礼

ありがとうございます。
A3はB2の間違いでした。申し訳ありません。
コードを実行してみましたが、数値の入ったセルを黄色に塗りつぶし、その塗りつぶしたセルに該当の商品名と数値を返すものでした。

説明が足りなかったのかもしれませんが、人間の手で任意で黄色に塗りつぶしたセルの数値と該当する
商品名を返す方法をお願いします。