エクセル日にち間隔で日曜日を除いた値

質問

Ｂ列３行目以降　　　　　　　　Ｃ列　　　　　　　　Ｄ列　　　　　　　　　　　　　Ｅ列
（日付）　　　　　　　　　（日にち間隔数）　　　　（日曜日除く間隔数）　　（データ値）　
H23年6月22日(水)
H23年6月30日(木)　　　　　　８　　　　　　　　　　　７
H23年7月1日(金)　　　　　　１　　　　　　　　　　　１
H23年8月1日(月)　　　　　　31　　　　　　　　　　　26
H23年8月28日(日)　　　　　　27　　　　　　　　　　　24（28日の日曜日は含む）
H23年9月30日(金)　　　　　　33　　　　　　　　　　　28

日付入力は2011/6/21
Ｂ列表示形式はge"年"m"月"d"日"(aaa)
日付間隔は=IF(OR(ISBLANK(B3),ISBLANK(B4)),"",DATEDIF(B3,B4,"d"))　の式を
ネットで調べ、Ｂ列に不特定日を入力し、各、日にち間隔の数値を出しています。

・行いたいのは
　データの記録表を作成していますが、Ｂ列に不特定日を入力し、日曜日だけを除いた
　日にち間隔の数値をＤ列に出したいです。
　但し、Ｂ列に入力した日付が日曜日の場合は、その日も含みます。

エクセル素人につき、
＜WEEKDAY関数は、曜日に対応した数値を返します。数値と曜日の対応＞
などをどのように利用して良いか分かりません。
エクセルは２０００です。

アドバスの程よろしくお願いします。

過去（質問番号：6992865）で同じような質問させていただきましたが、質問内容が
悪く、締め切らせていただいてます。
（ご回答頂いた方々ありがとうございました。）

回答No.12

kagakusuki · ベストアンサー

回答番号ANo.5です。

>・・・・ご回答いただいた式をコピーして貼り付けし、下へオートフィルとは意味が違うでしょうか？

　幾つかの異なるやり方がありますので、必ずしも同じ意味という訳では御座いませんが、そのやり方でもOKです。

　それから、ANo.5の方法は、期間中に存在する日曜日以外の日を、1つずつカウントして行くというやり方ですが、日にち間隔数から、「期間中に存在する日曜日の日数」を差し引くというやり方では、D4セルに入力する関数は次の様なものとなります。

=IF(AND(COUNT($B3:$B4,1/0)=2,$B3<$B4),$C4-INT(($C4-(WEEKDAY($B4)=1))/7)-(WEEKDAY($B3+1,2)>WEEKDAY($B4,2)),"")

　尚、Excelの関数は、普通では、セルの切取り&貼付けや、挿入、削除、等の編集作業を行ないますと、参照先のセルの位置関係がずれてしまい、正常に動作しなくなりますが、上記の関数を基にした、次の様な関数としますと、セルの切取り&貼付けや、挿入、削除、等の編集作業で、セルの位置が上下方向に移動しても、正しい結果を表示させる事が出来ます。（左右にずれる場合には対応していません）

=IF(AND(COUNT(INDEX($B:$B,ROW()-1):INDEX($B:$B,ROW()),1/0)=2,INDEX($B:$B,ROW()-1)<INDEX($B:$B,ROW())),INDEX($C:$C,ROW())-INT((INDEX($C:$C,ROW())-(WEEKDAY(INDEX($B:$B,ROW()))=1))/7)-(WEEKDAY(INDEX($B:$B,ROW()-1)+1,2)>WEEKDAY(INDEX($B:$B,ROW()),2)),"")

　それから、動作チェックに関してですが、関数が入力されている行の1つ上の行に入力されている日の曜日が、土曜日、日曜日、月曜日である場合の3パターンと、関数が入力されている行に入力されている日の曜日が、土曜日、日曜日、月曜日である場合の3パターンが、それぞれ微妙な状況となりますから、
1つ上が土曜日で同じ行が土曜日というパターン、
1つ上が土曜日で同じ行が日曜日というパターン、
1つ上が土曜日で同じ行が月曜日というパターン、
1つ上が日曜日で同じ行が土曜日というパターン、
1つ上が日曜日で同じ行が日曜日というパターン、
1つ上が日曜日で同じ行が月曜日というパターン、
1つ上が月曜日で同じ行が土曜日というパターン、
1つ上が月曜日で同じ行が日曜日というパターン、
1つ上が月曜日で同じ行が月曜日というパターン、
の9パターンに関しては、しっかり確認しておいた方が宜しいかと思います。

補足

ご親切、ご丁寧にアドバイス頂き、ありがとうございます。

式の内容については、一度には理解が出来ないですが、
まずはご指摘の通り、動作確認をしてみます。

とりあえず、お礼までとさせていただき、
わかないことがあれば、再度補足質問させて頂きます。

回答No.13

KURUMITO

回答No8です。遅くなってごめんなさい。
次のURLを参考にしてください。

http://www.geocities.jp/chiquilin_site/data/071101_specific_day.html

お礼

お礼が大変遅くなりました。

ご回答頂いたＵＲＬを覗いてみます。

ありがとうございました。

回答No.11

某HN クロメート(Chromate)（@CoalTar）

ありゃりゃ 「3度目の正直ならぬ」、「2度あることは3度ある」でまた違いましたかorz
ということで正解も出たようなので退散します～～～(ToT)/~~~

お礼

ご回答頂きありがとうございました。

回答No.10

noname#204879

[No.7補足]へのコメント、

まだ検証結果を示されていないけど、私の提示した式は正答を返すのですね？

「日付未入力時」に何も表示されないようにするには、
D5: =IF(B5="","",提示式)
で如何でしょうか？
（そのくらいはお出来になると思ってました）

「日付未入力時など」の「など」は他にどんなことを含みますか？

何れにしても情報の後出しは勘弁願いたい、です。

お礼

ご無理を言いました。

検証結果、正答です。

＞「日付未入力時」に何も表示されないようにするには、
D5: =IF(B5="","",提示式)
で如何でしょうか？
・・・・D5: =IF(B5="","－",提示式)にしました。

＞「日付未入力時など」の「など」は他にどんなことを含みますか？
・・・・・必ずしも日付とは限らない（誤入力）意味です。余計なこと書きました。

ありがとうございました。

回答No.9

某HN クロメート(Chromate)（@CoalTar）

#2,#4です。両方とも違っていました
日付関係は苦手。。。

>　データの記録表を作成していますが、Ｂ列に不特定日を入力し、日曜日だけを除いた
>　日にち間隔の数値をＤ列に出したいです。
>　但し、Ｂ列に入力した日付が日曜日の場合は、その日も含みます。

出た数字が日曜日の箇所だけ、1日多くなりました。
なぜなら、「日曜日の場合は、その日も含みます」と書かれているから
+(WEEKDAY(B4)=1) で当日(B4セル)が日曜日なら+1するってこと

＞H23年12月31日（土）
＞H24年1月1日（日）　　　２・・・・本来なら１
日曜日の場合って当日含め、2じゃないの？
また、日曜日から始まるときの計算は？
正確なサンプルもほしい。

今度こそは!?
=IF(C4="","",C4-INT((6-WEEKDAY(B4)+C4)/7)+(WEEKDAY(B4)=1))

補足

補足回答ありがとうございます。
解りづらい質問と条件不足でした。

＞正確なサンプルもほしい。
・・・・・以下をご覧ください。
Ｂ列3行目以降　　　　Ｃ列　　Ｄ列　　　Ｅ列
H23年9月10日(土) 　基本 　No.９さん　　正解
H23年9月20日(火) 　　10 　9 　　8 　　・なぜか「9」になります。
H23年9月30日(金) 　　10 　9 　　9
H23年10月13日(木)　　13 　11 　　11
H23年10月31日(月)　　18 　15 　　15
H23年11月19日(土)　　19 　17 　　17
H23年11月20日(日)　　　1 　　2 　　1　　　・日にち間隔なので「1」が
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　正解になります。
H23年11月21日(月)　　　1 　　1 　　1
H23年12月11日(日)　　　20 　　18 　　18
H23年12月18日(日)　　　7　　　7 　　7 　　・日曜日間隔は正解です。
H23年12月26日(月)　　　8　　　7 　　7
H23年12月31日(土)　　　5　　　5 　　5
H24年1月1日(日) 　　　1 　　2 　　1 　　・日にち間隔なので「1」が
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　正解になります。　
H24年12月31日(月)　　365　　313 　313
H25年1月1日(火) 　　　1 　　1 　　1
H25年1月4日(金) 　　　3　　　3 　　3
H25年12月31日(火)　　　361　309 309
H26年1月1日(水) 　　　1 　　1 　　1

条件１．日にちの間隔数のうち日曜日を除く数を出したいです。
　　２．入力日付は不特定日です。
　　３．入力日付に日曜日の時もあります。
　　４．２．３．の条件により日付は土曜日、明くる日の日曜日とつづく場合があります。
　　５．２．３。の条件により日付は日曜日から次週の日曜日もあります。
　　６．入力日付記入時の最大間隔日は3年です。

＞また、日曜日から始まるときの計算は？
　　・・・・条件３，４になります。

＞なぜなら、「日曜日の場合は、その日も含みます」と書かれているから
+(WEEKDAY(B4)=1) で当日(B4セル)が日曜日なら+1するってこと
　　・・・・条件４，５です。

・日曜日を除く日にち間隔のなかで、たまたま入力日付が日曜日だった場合はその日も含みます。
　ここがややこしくしていますね。

以上でお分かりいただけましたでしょうか？

よろしければお願いします。

回答No.8

KURUMITO

回答No1です。前の式は無かったことにしてください。

C4セルには次の式を入力して下方にオートフィルドラッグします。

=IF(B4="","",B4-B3-INT((B4-(B3-WEEKDAY(B3,3))+1)/7)+IF(WEEKDAY(B3,3)=6,1,0)+IF(WEEKDAY(B4,3)=6,1,0))

補足

お礼が大変遅くなりました。

ご指摘の式を入れたらうまく出来ました。

感動ものです。

よろしければ、関数式の意味をアドバイス頂きたいのですが・・。
あるいは、解りやすいサイト等を紹介していただきますと幸いです。

回答No.7

noname#204879

[No.3補足]へのコメント、

》 カレンダーを見て数えてますので間違いかもです

「かも」なんて仰らずに、貴方自身で検証すべきです。
8/28～09/30間に除外すべき日曜が何回あるかを数えるだけで好い！

それが、質問文を正しくするための、質問者のあるべき態度です。

「エラー表示」はそれからのこと！

補足

質問者側の怠慢でした。

大変失礼しました。

回答No.6

MackyNo1

日曜日のデータ処理が一部不明なところがありますが、休日を無視して日曜だけ除いた日付の差を計算するなら以下のような数式になります（最大50日後のデータまで計算できるようにしました）。

=SUMPRODUCT((WEEKDAY((B3+ROW($A$1:$A$50)-1))<>1)*(B3+ROW($A$1:$A$50)-1<B4))

回答No.5

kagakusuki

H23年8月28日(日)～H23年9月30日(金)の中で、日曜日ではない日数は29日ではないでしょうか。
　それは兎も角、D4セルに次の関数を入力してから、D4セルをコピーして、D5以下に貼り付けると良いと思います。

=IF(COUNT($B3:$B4)=2,SUMPRODUCT((WEEKDAY($B3+ROW(INDIRECT("Z1:Z"&INT($B4)-INT($B3))))>1)*1)+(WEEKDAY($B4)=1),"")

　※「ROW(INDIRECT("Z1:Z"&」の部分は、1から始まる「日にち間隔数」分の数値を自動的に作成するために、ROW関数を利用しただけのもので、Z列に特に意味がある訳ではなく、A列でもIV列でも、好きな列に変えて構いません。

補足

ご回答頂きましてありがとうございます。

＞H23年8月28日(日)～H23年9月30日(金)の中で、日曜日ではない日数は29日ではないでしょうか。
・・・・カレンダーをみて数えてますので間違いだと思います。すいません。

適当に日付、日にち間隔をとり
式を入力したら上手く日数が出ました。

＞D4セルに次の関数を入力してから、D4セルをコピーして、D5以下に貼り付けると良いと思います。
・・・・ご回答いただいた式をコピーして貼り付けし、下へオートフィルとは意味が違うでしょうか？

セル内のエラーチェックオプションは「エラーを無視する」でよろしいでしょうか？

よろしくお願いします。

回答No.4

某HN クロメート(Chromate)（@CoalTar）

＃２です。＃２の回答は、無視てください

D4セルは
=IF(C4="","",C4-INT((WEEKDAY(B4)+C4-1)/7)+(WEEKDAY(B4)=1))
下へオートフィル

補足

ご回答頂きましてありがとうございます。

又、親切に画像までつけていただき。

画像箇所で気づきましたが、

適当に日付入力、日付間隔を取り、式を入力させてもらい、
出た数字が日曜日の箇所だけ、1日多くなりました。

式の入力箇所等が間違っていますでしょうか？

回答No.3

noname#204879

「H23年9月30日(金)」の行の「日曜日除く間隔数」が「29」でなく、「28」になっている理由は？
もし「29」の間違いであるならば…

=C3-INT((B3-1)/7)+INT((B2-1)/7)+(MOD(B3,7)=1)

補足

ご回答頂きましてありがとうございます。

また、親切に画像までつけていただき、解りやすいです。

＞「H23年9月30日(金)」の行の「日曜日除く間隔数」が「29」でなく、「28」になっている理由は？
もし「29」の間違いであるならば…
・・・・・カレンダーを見て数えてますので間違いかもです。すいません。

式を入力後、うまく出来たように思えます（実際の日数を未だ数えていないので）
エラー表示（日付未入力時など）を回避出来ますか？
又は「０」を表示。

よろしければお願いします。