エクセル2003についてご質問です。目的のデータを抽出して数量合計を出

質問

エクセル2003についてご質問です。目的のデータを抽出して数量合計を出すVBAをおしえてください。

VBAは初心者で、マクロ自動記録を使っているのですが、自動記録で必要なデータを貼りつけるまでの作業はできるのですが、それ以降の下記の作業がVBA記述でないとできそうになく、どうしたらいいのか分からないので教えてください。

Aの列に入荷日付が入ってます。1月から今日までの日付が延々と入力されてます(日付は順番に並んでない時もあります)。
B列には商品名、C列には数量が入ってます。
マクロを実行して、一番最新の日を抽出して、その中でB列の商品が「事務用品」となってるセルの、C列の数量の合計数をメッセージボックスで出したいのですが。どうしたらいいのでしょうか？
また、それとは別に任意の日付を指定して(日付入力用のセルに入力して)、B列「事務用品」の数量合計をメッセージボックスで出す方法もおしえてください。

下記は例です。実際は各日にはもっとたくさんのデータが入力されています。日によってデータ数はバラバラです。
よろしくご指導ください。

A......................B.....................C
【日付】.............【商品名】.........【数量】
1/5..................お茶菓子..........2
1/5..................事務用品.........3
1/5..................事務用品.........5
1/6..................事務用品.........7
1/6..................事務用品.........2
1/7..................ホース..............1
1/8..................事務用品.........4
1/7..................懐中電灯.........1
1/6..................ヘルメット..........3
・
・
・(間の期日を省略します・・)
・
・
8/24................事務用品..........4
8/25................事務用品..........6
8/24................ドライバー..........1
8/26................事務用品..........3
8/26................事務用品..........7
8/26................コーヒー他..........5

回答No.3

jcctaira · ベストアンサー

VBAの例です。
なるべくEXCELの関数をVBAの中で使用しています。

Sub 数量表示()
　Dim 範囲A　　As Range
　Dim MAX日　　As Long
　Dim 数量式　　As String

　Set 範囲A = Range(Range("A2"), Cells(Rows.Count, "A").End(xlUp))
　MAX日 = Evaluate("Max(" & 範囲A.Address & ")")
　数量式 = "SUMPRODUCT("
　数量式 = 数量式 & "(" & 範囲A.Address & "=" & MAX日 & ")*"
　数量式 = 数量式 & "(" & 範囲A.Offset(0, 1).Address & "=""事務用品"")*"
　数量式 = 数量式 & 範囲A.Offset(0, 2).Address & ")"
　MsgBox (Format(MAX日, "最終日 = YYYY/MM/DD") & vbCrLf & _
　　　　　　Format(Evaluate(数量式), "数量　 = #,### 個"))
End Sub

＞　また、それとは別に任意の日付を指定して
上記の例ですと「MAX日」を表示したい日に代入すればできます。
例）MAX日 = #8/24/2010#

　試してみてください。

回答No.4

mitarashi

#1さんのお叱りを受けそうですが、日付シリアルでのオートフィルタはどうやるのかなと思って、トライしてみました。A列は書式指定（全行同じ書式）した、日付シリアル値が入っているとします。ご参考まで。
Sub test()
Dim targetRange As Range
Dim lastRow As Long
Dim lastDate As String

Application.ScreenUpdating = False
lastRow = Range("A" & Rows.Count).End(xlUp).Row
Set targetRange = Range("A1:C" & lastRow)
lastDate = Format(Application.WorksheetFunction.Max(Range("A2:A" & lastRow)), Range("A2").NumberFormatLocal)
If ActiveSheet.AutoFilterMode = True Then ActiveSheet.AutoFilterMode = False
With targetRange
.AutoFilter field:=1, Criteria1:=lastDate
.AutoFilter field:=2, Criteria1:="事務用品"
MsgBox Application.WorksheetFunction.Subtotal(9, targetRange.Columns(3))
.AutoFilter
End With
Application.ScreenUpdating = True
End Sub

回答No.2

ynkd

Ｎｏ．１の追伸です。

下記の操作を　マクロの記録で取れば　ある程度書けていると思いますが？
当然　無駄なコードの修正は必要になります。

subtotalをしたセルの値を　メッセージボックスに表示するようにすれば、出来ると思うんですが？

上記を　どこかにコマンドボタンなどを貼り付けて　実行するようにすれば　ＯＫかなと

コードも示さないで参考にならないと思うかもしれませんが、１つ１つ　やっつけていくと自分の実力になります。

excel vbaは　ネットにいくらでもあります。

回答No.1

ynkd

各列に　フィルターを掛けてｃ列をsubtotalでは　ダメなんですか？
どうしてもメッセージボックスでなければいけないんですか？