Access2002 フォームからのレコード入力の成功/不成功

質問

いつもお世話になっております。

早速ですが、従業員マスタテーブルがあり、それを元に従業員の情報を入力するフォームを作成しました。
従業員マスタテーブルは、「社員番号」だけをキーにしています。

例えば、新入社員のデータを、完全に新規に入力する場合、うまく行きます。
また、すでにいる社員の、「社員番号以外」のフィールドを更新することもできます。

しかし、社員番号が既存のものとかぶるような新規登録、あるいは情報変更に関しては、入力用フォーム上では正常終了したように見えますが、実際の従業員マスタテーブルをチェックしてみると、変更はされていません。

ですので、フォームしか触れないユーザは、自分の変更、新規追加がうまく行ったのかどうか、テーブルが見られないのでわからない、という状況になっています。

仕様要求としては、新規であれ、情報変更であれ、既存の社員番号に重なる場合はメッセージボックスで「更新失敗」を表示したいのです。

If Exist・・・のような分岐を情報を入力するフォームの「閉じる」ボタンの裏に設けたいのですが、やり方がイマイチわかっておりません。

ご存知の方がいらっしゃれば、ご教授、よろしくお願いします。

---------------------------------------------------------------

＜従業員マスタ＞
・社員番号・・・テキスト
・氏名・・・テキスト

＜仕様要求＞
社員番号「0001」と「0002」の社員が存在する場合・・・
・情報入力画面で、「0001」の社員の社員番号を「0002」に変更しようとすると、エラーメッセージ表示
・新規情報入力（新入社員など）の際、社員番号が「0001」や「0002」の社員として登録しようとすると、エラーメッセージ表示

以上、お時間のあるときによろしくお願いします。

回答No.5

30246kiku · ベストアンサー

フォーム上の社員番号のテキストボックス名を「txt社員番号」と仮定します。

そのテキストボックスの入力規則に以下を設定します。

DLookUp("社員番号","従業員マスタ","社員番号='" & [txt社員番号] & "'") Is Null

エラーメッセージに、「重複しています」等設定しておきます。

※　
DCount でも良いと思いますが、DLookUp は見つかった時点で戻ってくると思ってます。
DCount は、あってもなくても全レコードをみると思うので、どちらかと言えば DLookUp でしょうか。
（重複するものがなければ全レコードを見るのは変わらないと思いますけど）

お礼

ご回答ありがとうございます。

Dlookupにて、重複を避けることができました。
（結局こうしたかったんです）

ずばり、の回答でした。

ありがとうございました。

回答No.4

piroin654

>従業員マスタに、
>社員番号 氏名
>0001 たろう
>0002 じろう

>が登録されているとき、新規レコードとして、
>0001 さぶろう
>を登録しようとすると、入力したフォームは、特にエラーなく終了します（終了ボタンに、Docmd.closeを記述)

>しかし、テーブルを見ると、
>社員番号 氏名
>0001 たろう
>0002 じろう
>のままです。

社員番号が主キーならば、どのような形で
また、エラー回避して
保存しようとしても二重登録しようとすれば
システムエラーが出るはずです。したがって

Docmd.Closeでは明確にレコードは保存されません。
明確に保存するならば、
DoCmd.RunCommand acCmdSaveRecord
を宣誓して、
Docmd.Close
します。

としたのですが、これで二重登録をして
システムエラーが出るのか確認してください、
ということです。

単に、二重登録の防止ではなく、その前に
システムの弱点を見つけ、改善するのが
先決だと思いますが。違いますかね。

お礼

追加回答ありがとうございます。

システムエラー、でました。

＞システムの弱点を見つけ、改善するのが
＞先決だと思いますが。違いますかね。

おっしゃるとおりです。。。

回答No.3

DexMachina

【要点】
DCount関数などを使用して、指定した社員番号のレコードが新規か既存かを
判定し、レコードの追加/レコードの更新のどちらを行うかを切り替えて下さい。

【詳細】

> 入力用フォーム上では正常終了したように見えますが、実際の従業員マスタ
> テーブルをチェックしてみると、変更はされていません。

実際には保存時にエラーが発生しているのに、その旨のメッセージが表示されない、
という状況は、私の知る範囲では
　a)DoCmd.SetWarningsでメッセージを殺しているか
　b)CurrentDb.ExecuteでSQL文を実行しているか
　c)On Error Resume Nextなどでエラーを無視しているか
です(失念しているものがなければ(汗))。

ただ、連結フォームで、閉じることによる自動のレコード保存だとすると、「c)」による
可能性は薄いように思いますので、
　『「閉じる」ボタンのクリック時に、非連結フォームを使用し、クエリ又はSQL文で
　レコードの追加を行っている』
という仕様と推測して、以下、回答します。

・・・なお、「閉じる」ボタンで登録だと、登録の取り消し(中止)ができませんので、
ボタンは「登録」(登録＋閉じる)と「キャンセル」(閉じるのみ)にした方が便利かと
思います。

Private Sub 登録_Click()
On Error Goto エラー処理

　　'変数の宣言
　　Dim strSQL As String, strMsg As String

　　'DCount関数で、指定した社員番号の新規/既存を判定
　　If DCount("*", "従業員マスタ", "[社員番号]='" & Me!社員番号 & "'") = 0 Then
　　　　'新規の社員番号の場合は、レコード追加用のSQLを実行
　　　　strMsg = "指定した社員を新規登録します。"
　　　　strSQL = "Insert Into 従業員マスタ (社員番号, 氏名)" & vbCrLf _
　　　　　　　　& "Values ('" & Me!社員番号 & "', '" & Me!氏名 & "');"
　　Else
　　　　'既存の社員番号の場合は、レコード更新用のSQLを実行
　　　　strMsg = "指定した社員番号の氏名を更新します。"
　　　　strSQL = "Update 従業員マスタ" & vbCrLf _
　　　　　　　　& "Set 氏名 = '" & Me!氏名 & "'" & vbCrLf _
　　　　　　　　& "Where 社員番号 = '" & Me!社員番号 & "';"
　　End If

　　If MsgBox(strSQL, vbOkCancel, "確認") = vbOk Then
　　　　CurrentDb.Execute strSQL
　　　　DoCmd.Close acForm, Me.Name, acSavePrompt
　　End If

終了処理:
　　Exit Sub

エラー処理:
　　MsgBox Err.Number & "：" & Err.Description, , Me.Name & " 登録"
　　Resume 終了処理

End Sub

・・・以上です。

お礼

ご回答ありがとうございます。
　a)DoCmd.SetWarningsでメッセージを殺しているか
　b)CurrentDb.ExecuteでSQL文を実行しているか
　c)On Error Resume Nextなどでエラーを無視しているか
どれも、明示的には行なっておりません。

別回答で頂きました、Close処理の前に明示的にレコードの保存を行なうことで、システムメッセージが表示されるようになりました。

ご提示頂いたソースは、今後、参考にさせて頂きます。

ありがとうございました。

回答No.2

piroin654

>を登録しようとすると、入力したフォームは、
>特にエラーなく終了します（終了ボタンに、
>Docmd.closeを記述)

Docmd.Closeでは明確にレコードは保存されません。
明確に保存するならば、
DoCmd.RunCommand acCmdSaveRecord
を宣誓して、
Docmd.Close
します。

現状が、
フォームのコントロールが連結なのか
非連結なのか、あるいはサブフォーム
なのかはわかりませんが、
カレントレコードを移動するように
設計しているとそのレコードについては
保存されます。

以上を確認してみてください。
二重登録の防止は後で。

お礼

ご回答ありがとうございます。
Closeの前に、
DoCmd.RunCommand acCmdSaveRecord
を挿入することで、システムメッセージ（重複～～）が出て、保存できないようになりました。

フォームはサブフォームは使っていません。
一応、わざと社員番号を重複させるようなレコード入力をして、移動ボタンを押しても、上記と同じく、システムメッセージが出るようになりました。

一応、目的は達成です。

ありがとうございました。

回答No.1

noname#182251

簡単なサンプルで試してみました。
「社員番号」はマスターキーになっているんですね？

・「0001」の社員の社員番号を「0002」には変更できない
・既存であれば社員番号「0001」や「0002」は追加登録できない

どうも質問内容が理解できません。

お礼

言葉足らずで申し訳ありません。

「社員番号」はマスターキーです。

どういう部分がご理解いただけないのでしょうか？

切り分けのために、
・既存であれば社員番号「0001」や「0002」は追加登録できない
の部分を詳細化させていただきます。

従業員マスタに、
社員番号 氏名
0001 たろう
0002 じろう

が登録されているとき、新規レコードとして、
0001 さぶろう
を登録しようとすると、入力したフォームは、特にエラーなく終了します（終了ボタンに、Docmd.closeを記述)

しかし、テーブルを見ると、
社員番号 氏名
0001 たろう
0002 じろう
のままです。

これでは、ユーザは登録が完了したのか、失敗したのかがわからないだけでなく、メッセージが何も出ないため、完了したと思い込んでしまいます。（実際は完了していません）

せめて、「重複した～～～レコードの保存に失敗しました」というメッセージが出てくれればうれしいのですが。。。

もちろん、テーブルを開いてじかに新規レコードとして追加しようとしても、マスタキーの重複エラーではじかれます。この場合は、メッセージが出ます。

意味が通じていますでしょうか？