VBAで( )のものだけ( )に変更したい

質問

お世話になります。

現在エクセルの複数のセルに( )空白のスペースが入った()があります。
※()の中は半角・全角のスペースが中身が半角・全角のスペースの数がさまざまな形で入っています。
()の中に入っているのは半角・全角のスペースがはいている()のみ( )※全角スペース3個　のものに変換したいのです。

しかしながら、他のセルに(2222)などの()の間に数字や文字が入っているものがあり、それに対しては、そのままにしたいのです。

エクセルのVBAで実現したいのですが、どのようにすればよいでしょうか？

何卒よろしくお願いします。

回答No.4

n-jun · ベストアンサー

＃２です。

No.3さんの回答を参考にさせて頂き修正してみました。
セルＡ１の値をセルＡ２に書き出す物です。

Sub try2()
Dim RegExp As Object
Dim st As String
Dim match, matches

Set RegExp = CreateObject("VBScript.Regexp")
RegExp.Pattern = "\([ 　]*\)"
RegExp.Global = True

st = Range("A1").Value
Set matches = RegExp.Execute(st)

For Each match In matches
st = Replace(st, match.Value, "(　　　)")
Next

Range("A2").Value = st

Set RegExp = Nothing
Set matches = Nothing
End Sub

一例まで。

回答No.3

pkh4989

こんにちは。

'セルの内容が以下のように変換されます
'試してみてください。
'()()aaa(222) →(　　　)(　　　)aaa(222)
Sub 変換()
Dim c
Dim ExitFlg　　　　As Boolean
Dim wk　　　　　　 As String
Dim wk2　　　　　　As String
Dim wStr　　　　　 As String
Dim EditStr　　　　As String
Dim st　　　　　　 As Integer
Dim st2　　　　　　As Integer
'
With ActiveSheet
　　For Each c In Range("A1:B5")　　'←変換するセルの範囲
　　　　EditStr = ""
　　　　wStr = c
　　　　ExirFlg = False
　　　　Do While ExirFlg = False
　　　　　　st = InStr(1, wStr, "(")
　　　　　　If st > 0 Then
　　　　　　　　EditStr = EditStr & Left(wStr, st - 1)
　　　　　　　　st2 = InStr(st + 1, wStr, ")")
　　　　　　　　wk = Mid(wStr, st, st2 - st + 1)
　　　　　　　　wk2 = wk
　　　　　　　　wk2 = Replace(Replace(wk, " ", ""), "　", "")
　　　　　　　　If wk2 = "()" Then
　　　　　　　　　　wk = "(　　　)"
　　　　　　　　End If
　　　　　　　　EditStr = EditStr & wk
　　　　　　　　wStr = Mid(wStr, st2 + 1)
　　　　　　Else
　　　　　　　　EditStr = EditStr & wStr
　　　　　　　　ExirFlg = True
　　　　　　End If
　　　　Loop
　　　　c.Value = EditStr
　　Next
End With

回答No.2

n-jun

Sub try()
Dim RegExp As Object
Dim i As Integer
Dim st As String
Dim v(2)

Set RegExp = CreateObject("VBScript.Regexp")
RegExp.Pattern = "\(([ 　]+)\)"
RegExp.Global = True

v(0) = "(123)"
v(1) = "( )"
v(2) = "( 　　 )"

For i = 0 To 2
st = v(i)
If RegExp.Test(st) Then
st = Replace(st, RegExp.Replace(st, "$1"), "　　　")
End If
MsgBox st
Next

Set RegExp = Nothing
End Sub

一例まで。

回答No.1

mt2008

1.対象セルの文字列を変数に取り出す
2.取り出した文字列の、全角スペースと半角スペースを置換で削除
3.削除した結果が"()"なら、該当セルなので、セルの値を"(　　　)"にする

と、言った処理になるかと思います。
以下の例ではA1セルだけを対象に上記の処理を行って居ます。

Sub Sample()
　Dim sTarget As String
　Dim sWork As String
　sTarget = Range("A1")
　sWork = Replace(Replace(sTarget, "　", ""), " ", "")
　If sWork = "()" Then
　　Range("A1") = "(　　　)"
　End If
End Sub