ユーザーフォームへの文字の表示方法について

質問

ＶＢＡを始めたばかりの超初心者です。単純にユーザーフォームを作って検索ボタンを付け、検索結果を表示させる。こんな単純な事がわからずに困っています。
問題は何行もヒットしたらスクロールバーはどうするのか？
検索結果だけの部分をスクロールさせたい。
コントロールは何を張るのか？ラベル？テキストボックス？
検索したい情報はエクセルで有るのでそれを引っ張ってきたいだけなですが。。
出来れば同一のユーザーフォームに表示させたいです。
どなたか教えて下さい。宜しくお願い致します。

回答No.4

Masa2072

そこまでフォームにこだわる理由は何なんでしょうか
Excelのユーザーフォームってあまり大量データの表示に適したコントロールがありません。
コマンドボタンなどはワークシートに貼ることが出来ますので、一つのシートをフォームに見立てれば、データの表示に使うコントロールのことに頭を悩ませる必要がありません。

> コントロールは何を張るのか？ラベル？テキストボックス？
この辺は結果をどう表示するか、どう扱うかに関わってきます。
ユーザーに編集させる必要があればラベルというわけにはいきませんよね。

ワークシートに「データ」という名前のシートを作り
名前,金額,日付
aaa,100,1月1日
bbb,284,4月3日
ccc,343,3月4日
ddd,322,4月7日
aba,245,7月4日
bcb,234,4月7日
cdc,444,8月3日
ded,1234,5月5日
aac,3435,9月21日
bba,234,12月24日
ccd,765,7月31日
ddc,543,8月16日
のデータをA1から順番に入力
UserFormを作成し
テキストボックスを４つ、リストボックスを１つ（横幅を広めに）
コマンドボタンを３つ、作成してください。

コードを表示し以下のソースを
Dim Data As Object
Dim RC As Object
Dim Fst As Object

Private Sub CommandButton1_Click()
　　Set RC = Data.Find(Me.TextBox1.Value, LookIn:=xlValues)
　　If RC Is Nothing Then
　　　　MsgBox "条件に一致するデータが見つかりません"
　　　　Me.TextBox2 = ""
　　　　Me.TextBox3 = ""
　　　　Me.TextBox4 = ""
　　Else
　　　　Set Fst = RC
　　　　Me.TextBox2 = RC.Offset(0, 0)
　　　　Me.TextBox3 = RC.Offset(0, 1)
　　　　Me.TextBox4 = RC.Offset(0, 2)
　　　　Me.CommandButton2.Visible = True
　　End If
End Sub

Private Sub CommandButton2_Click()
　　Dim YesNo As Integer
　　Set RC = Data.FindNext(RC)
　　If RC = Fst Then
　　　　YesNo = MsgBox("最終データです" & vbCrLf & "先頭から検索しますか？", vbYesNo)
　　End If
　　If YesNo = vbYes Then
　　　　Me.TextBox2 = RC.Offset(0, 0)
　　　　Me.TextBox3 = RC.Offset(0, 1)
　　　　Me.TextBox4 = RC.Offset(0, 2)
　　End If
End Sub

Private Sub CommandButton3_Click()
　　Set RC = Data.Find(Me.TextBox1, LookIn:=xlValues)
　　Set Fst = RC
　　Me.CommandButton2.Visible = False
　　With Me.ListBox1
　　If Not RC Is Nothing Then
　　　　.AddItem
　　　　.Column(0, 0) = RC
　　　　.Column(1, 0) = RC.Offset(0, 1)
　　　　.Column(2, 0) = RC.Offset(0, 2)
　　　　Set RC = Data.FindNext(RC)
　　　　Do Until RC = Fst
　　　　　　.AddItem
　　　　　　.Column(0, .ListCount - 1) = RC
　　　　　　.Column(1, .ListCount - 1) = RC.Offset(0, 1)
　　　　　　.Column(2, .ListCount - 1) = RC.Offset(0, 2)
　　　　　　Set RC = Data.FindNext(RC)
　　　　Loop
　　Else
　　　　MsgBox "条件に一致するデータが見つかりません"
　　End If
End Sub

Private Sub UserForm_Initialize()
　　Dim DataStart As Long
　　Dim DataEnd As Long

　　Me.CommandButton1.Caption = "検索"
　　Me.CommandButton2.Caption = "次へ"
　　Me.CommandButton3.Caption = "抽出"
　　Me.CommandButton2.Visible = False

　　DataStart = 2

　　With Sheets("データ")
　　　　DataEnd = .Range("A65536").End(xlUp).Row
　　　　If DataEnd = 1 Then
　　　　　　DataEnd = 2
　　　　End If

　　　　Set Data = .Range(.Cells(DataStart, 1), .Cells(DataEnd, 3))
　　End With
End Sub

検索で
Textbox1に入力された文字列が含まれたデータ（A列）を検索し
Textbox2以下に表示します。
次へで
次に一致するデータを表示します。
抽出で
Listboxにデータを抽出します。

回答No.3

imogasi

>ユーザーフォームに表示をさせたいだけなんです
ばかり言っているが、それぐらい言うなら自分でやってみたら。
既出回答もそれなりのことを考えていっていますよ。
私がやってみてにヒント
（１）テキストボックスでも、リストボックスでも出来る
（２）テキストボックスの場合
プロパティで下記設定に注意
　　　・MultoLines=True
・EnterKeyBehavior=True
・ScrollBars=2 fmScrollBarsertical
またはBoth
ーーーーー
説明のためのテストをやってみました。
フォームのコマンドボタンのクリックイベントに
Private Sub CommandButton1_Click()
For i = 1 To 40
TextBox1.Text = TextBox1.Text & Cells(i, "F") & vbCrLf
Next i
End Sub
を入れてクリックする。
その前に、Ｆ列に１－４０行のデータを入れておく。そしてクリック。
テキストボックスには
aaa
bbb
ccc
・・・
のように
（１）明細は改行されて
（２）明細が追加される
（３）垂直スクロールバーも出てきた
が出来ました。
ーーー
実際には
コマンドボタンをクリックで、検索処理を始めて、検索して該当が見つかった都度
TextBox1.Text = TextBox1.Text & 検索結果 & vbCrLf
をやって行けばよいでしょう。
＞スクロールバーはどうするのか？
上記のようにプロパティを設定すると、多分該当行数が少なくても（Ｈｅｉｇｈｔ＝５０で明細が４行でもバーが付いた）Ｖスクロールが付くようだ。
ーー
以上で聞きたいことは判ったかな。
＞始めたばかりの超初心者です
には先へ行き過ぎと思う。

回答No.2

Masa2072

条件にあったデータを抽出する方法はいくつかありますが
・1件毎にチェックしていく総当り
・オートフィルタの操作をマクロ化する
・データ表をデータベースとしてみなしADO接続でSQL文による抽出
などなど
結果はフォーム上に出すよりも、新規にワークシートを追加し、そこに転記するとスクロールバーなどの心配が要らなくなります。

初心者とのことですので、一度に欲張らずまずはワークシート上で全てを行う方法などから試していかれてはどうでしょうか
http://www.google.co.jp/search?q=Excel+VBA+%E3%83%9E%E3%82%AF%E3%83%AD&lr=lang_ja&ie=utf-8&oe=utf-8&aq=t&rls=org.mozilla:ja:official

お礼

すみません。検索と書いたので誤解されてしまいました。
例えば、検索方法では無く、任意の検索では無いデータをエクセルに記載されてるデータを変数等に格納し、格納したデータを加工し同一のユーザーフォームに表示をさせたいだけなんです。
加工と行っても1+1をするくらいの単純な物で100行位あります。
それをユーザーフォームに表示をさせたい。のです。
引き続き宜しくお願いします。
説明が下手で本当に申し訳有りません。

回答No.1

hana-hana3

＞検索結果を表示させる。こんな単純な事がわからずに困っています。

何をどのように検索して表示するのか解りませんが、はっきり言ってそんな面倒な事はやりたくないです。

単純にやるなら、シートにオートフィルタを設定する方が遙かに簡単です。

まずは、検索マクロの動作を確認して、そこならどのようにしたら必要な情報を得る事ができるかを覚えましょう。

http://www.geocities.jp/happy_ngi/YNxv98c23.html

お礼

すみません。ワークシート等のシートは使わない方向です。
検索の方法では無く、単純にユーザーフォームに表示をさせたいだけなんです。早速のお返事有難う御座いました。引き続き宜しくお願い致します。