onRelease文での動作について・・・。

質問

ムービークリップをボタンにして、その階層の最初のフレームに
this.onRollOver = function() {
this.onEnterFrame = this.nextFrame;
};
onRelease=function(){
var num:Number=0
onEnterFrame=function(){
trace("LOOP num ="+num)
num ++
if(num>30){
delete onEnterFrame
}
}
}
stop()
最後のフレームに
this.onRollOut = function() {
this.onEnterFrame = function() {
if (this._currentframe > 1) {
this.prevFrame();
}
};
};
とした場合について質問です。
ボタン上にカーソルがある場合は30までカウントされます。
しかし、クリック直後にカーソルがボタン上から離れるとカウントが停止します。
ボタンから離れてもカウントを続けるにはどうすればよいでしょうか？？
ちなみに、このスクリプトは簡単に流れが分かるように作ったものなのでfor文などではなくonEnterFrame～での対処法を教えて下さい。
実際にはonEnterFrame以下はもっと長くなっているので・・・。

どうかお願いしますっ！！！ m(_ _)m

回答No.1

BlurFiltan · ベストアンサー

まず原因ですが。

this.onRollOver = function() { };　内の
this.onEnterFrame　も，

onRelease=function() { };　内の
onEnterFrame=function(){ }　も，

this.onRollOut = function() { };　内の
this.onEnterFrame = function() { } も，

全部そのムービークリップに対する，
onEnterFrameイベントハンドラメソッドの定義です。

つまり同じ関数を何度も定義し直していることと同じになるため，
前に定義しておいた onEnterFrameイベントハンドラメソッド が，
新しく定義される onEnterFrameイベントハンドラメソッド によって消されてしまうので，
ご質問で書かれていらっしゃるようなことになります。

次に解決できるかもしれないスクリプト例です。

しかしいまひとつさせたい動きがわかりません。
次のような感じでいかがでしょうか？

ムービークリップ内 フレーム1 ↓
----------------------------------
stop();

var flg1:Boolean = false;
var flg2:Boolean = false;
var num:Number;

this.onEnterFrame = function() {

if (!flg1) {
if (this._currentframe>1) {
this.prevFrame();
}
}

if (flg2) {
trace("LOOP num ="+num);
num++;
if (num>30) {
flg2 = false;
}
}

};

this.onRollOver = function() {
flg1 = true;
this.play();
};

this.onRelease = function() {
flg2 = true;
num = 0;
};
----------------------------------

ムービークリップ内 最終フレーム ↓
----------------------------------
this.stop();

this.onRollOut = function() {
flg1 = false;
};
----------------------------------

this.onEnterFrame = function() { } は１つです。
フラグを２つ作っておいて，
そのフラグによって this.onEnterFrame = function() { } 内の動向を変えています。

flg1 が　再生⇔逆再生　を切り替えるフラグで，
flg2 が　カウントアップ⇔カウント停止　を切り替えるフラグです。

お礼

ご回答ありがとうございます。
まず原因についてですが、onEnterFrame～は便利なのでついつい使ってしまいます。
その時は１つのｍｃに対して１つだけ使うようにすれば良いのでしょうか？
ロールオーバー時の動きの部分は見習う部分がありました。
ただこのスクリプトだと、ロールアウトするとカウントが止まってしまいます。
しかしその部分は別の関数を作ってonReleaseの中から呼び出す事で一応解決しました。
それはそれで新しい疑問が出てきましたが、頭の整理をしてからまた質問させて頂きます。

ありがとうございました。