起動ディスク

質問

Windows98のパソコンが何らかの不手際で、
「Explorer.exe の読み込みエラー。 Windows を再インストールしてください。」
と表示され、起動できなくなってしまいました。
そこで、MS-DOSモードでWindows98起動ディスクを作成するため、コマンドを入力していったのですが、
「EBD ディレクトリが存在しません。WINDOWS\COMMAND ディレクトリからもう一度やり直してください。」と表示されてしまいます。
これはどういうことなのでしょうか？
ここから解決策はあるのでしょうか？
よろしくお願いします。

回答No.4

nishi8

ちなみに、ご回答No2で提示されているMS社のサポートページの
bootdisk　コマンドは、バッチファイルで、以下の内容です。
ここで、EBDディレクトリが無いと判断されているのだと思います。

@echo off

set DefFloppyDrive1=A:
set DefFloppyDrive1_L=a:
set DefFloppyDrive2=B:
set DefFloppyDrive2_L=b:

set DefFloppyDrive=%1

cls

:CHECK
if not exist EBD\NUL goto NODIR
if "%1"=="/?" GOTO USAGE
if "%1"=="%DefFloppyDrive1%" goto FORMAT
if "%1"=="%DefFloppyDrive1_L%" goto FORMAT
if "%1"=="%DefFloppyDrive2%" goto FORMAT
if "%1"=="%DefFloppyDrive2_L%" goto FORMAT

:SET_FLOPPY
echo フロッピー ドライブのドライブ文字を指定してください。
echo ドライブが %DefFloppyDrive1% の場合は 1 を、
echo ドライブが %DefFloppyDrive2% の場合は 2 を押してください。
echo.
choice /c:12 オプションを選択してください。
if errorlevel 2 goto BDRIVE
if errorlevel 1 goto ADRIVE

:ADRIVE
set DefFloppyDrive=%DefFloppyDrive1%
goto FORMAT

:BDRIVE
set DefFloppyDrive=%DefFloppyDrive2%
goto FORMAT

:FORMAT
echo.
echo 起動ディスクの作成
echo "Windows 98 起動ディスク" というラベルの付いたフロッピーディスクを
echo %DefFloppyDrive% ドライブに挿入してください。
echo 注意: フロッピー ディスクに保存されているファイルはすべて削除されます。
pause
format %DefFloppyDrive% /u /v:EBD /autotest
if not errorlevel 0 goto FORMAT_ERROR

:COPY
echo.
echo ファイルを %DefFloppyDrive% ドライブにコピーしています...
copy .\EBD\*.* %DefFloppyDrive% > NUL
echo.
echo システム ファイルを転送しています...
sys %DefFloppyDrive% > NUL
echo.
echo 起動ディスクが作成されました。
echo.
goto END

:FORMAT_ERROR
echo.
echo 指定されたドライブをフォーマット中にエラーが発生しました。
echo Y を押すと再試行します。N を押すと処理をキャンセルします。
choice /c:yn
if errorlevel 2 goto FORMAT_CANCEL
if errorlevel 1 goto FORMAT
:FORMAT_CANCEL
echo .
echo 終了しています...
goto END

:USAGE
echo.
echo 使い方: bootdisk [ドライブ文字:]
echo 例 : bootdisk
echo または
echo bootdisk %DefFloppyDrive1%
echo.
echo このコマンドは、WINDOWS\COMMAND ディレクトリから実行してください。
echo.
goto END

:NODIR
echo.
echo EBD ディレクトリが存在しません。
echo WINDOWS\COMMAND ディレクトリからもう一度やり直してください。
echo.
goto END

:END
set DefFloppyDrive=
set DefFloppyDrive1=
set DefFloppyDrive1_L=
set DefFloppyDrive2=
set DefFloppyDrive2_L=

回答No.3

nishi8

cd windows\command
で、
C:\WINDOWS\COMMAND＞_
の画面になる所までは、OKでしょうか。

C:\WINDOWS\COMMAND＞dir /w
で、
[.] [..] [EBD] DOSIME.BAT JP.BAT
US.BAT CHEV.COM CHOICE.COM MSIME.DIC MSIMED.SYS
MSIMER.DIC ADDDRV.EXE DELDRV.EXE DELTREE.EXE IEXTRACT.EXE
MOVE.EXE MSIMEKEY.EXE MSIMELST.EXE MSIMERGN.EXE MSIMESET.EXE
SELKKC.EXE MSIMEKEY.INI JPRINTER.SYS MSIME.SYS MSIMEK.SYS
CSCRIPT.EXE DRVSPACE.BIN EXTRACT.EXE SCANDISK.COM SCANDISK.EXE
SCANDSK2.EXE SCANREG.EXE SULFNBK.EXE FDISK.EXE MSCDEX.EXE
DISKCOPY.COM DOSKEY.COM EDIT.COM FORMAT.COM MODE.COM
MORE.COM SYS.COM BOOTDISK.BAT ATTRIB.EXE CHKDSK.EXE
CVT.EXE DEBUG.EXE EDIT.EXE EDIT2.EXE FC.EXE
FIND.EXE LABEL.EXE MEM.EXE NLSFUNC.EXE SORT.EXE
START.EXE SUBST.EXE XCOPY.EXE XCOPY32.EXE EDIT.HLP
EDIT2.HLP SCANDISK.INI XCOPY32.MOD ANSI.SYS
61 個 2,981,365 バイトのファイルがあります.
3 ディレクトリ 　　　　　　 バイトの空きがあります.
のように表示されますか。
（特に、[EBD] がありますか。）

C:\WINDOWS\COMMAND＞cd ebd
で、
C:\WINDOWS\COMMAND\EBD＞_
になりますか。
それとも、「ディレクトリの指定が違います．」になってしまいますか。

C:\WINDOWS\COMMAND\EBD＞dir /w
で、
[.] [..] ANK16.FNT ANK19.FNT ASPI2DOS.SYS
ASPI4DOS.SYS ASPI8DOS.SYS ASPI8U2.SYS ASPICD.SYS AUTOEXEC.BAT
BILING.SYS BTCDROM.SYS BTDOSM.SYS COMMAND.COM CONFIG.SYS
DRVSPACE.BIN EBD.CAB EXTRACT.EXE FDISK.EXE FINDRAMD.EXE
FLASHPT.SYS HIMEM.SYS IO.SYS JDISP.SYS JFONT.SYS
JKEYB.SYS JKEYBRD.SYS KANJI16.FNT OAKCDROM.SYS RAMDRIVE.SYS
README.TXT SETRAMD.BAT
30 個 1,607,044 バイトのファイルがあります.
2 ディレクトリ バイトの空きがあります.
と表示されますか。

追記：
C:\WINDOWS\COMMAND\EBD＞_
から、
C:\WINDOWS\COMMAND＞_
に戻るには、
cd ..
です。（C:\＞_ に戻るには、cd \　）

ご回答No2の英語版を入手されたほうが早いかもしれませんね。

お礼

遅くなって申し訳ありません;;
ご回答ありがとうございます。
いくつか試してみようと思います。

回答No.2

kentacya

MS-DOS モードで Windows 98 起動ディスクを作成する方法は下記のとおりとなっていますが手順どおりでしょうか？
http://support.microsoft.com/kb/186300/ja
最悪できなかった場合は英語版ですが次のところから、起動ディスクは手に入ります。
http://bootdisk.com/bootdisk.htm

お礼

ご回答ありがとうございます。手順通り進めてはいたのですが、コマンド入力の後、エラーが表示されてしまいます。

回答No.1

tadasi8

これはどうでしょう？マイクロソフトのサイトです。
http://support.microsoft.com/kb/306618/ja

お礼

ご回答ありがとうございます。しかしエラーの内容が違うようでした。