文字列変換

質問

他人が作ったExcelデータを修正しなければいけなくなったのですが時間がかかって手間取っています。
する作業は、選択した文字列を

・カタカナは全角
・ローマ字は半角
・数字は半角

とすることです。
手作業ですると時間がかかるので、
マクロとかVBAで作業に無駄をなくせればと思いました。
それで調べてみたのですがStrConv関数というのが出てきましたが、
文字種ではしてくれなさそうなのです。
参考になりそうなものはないでしょうか？

回答No.2

Wendy02 · ベストアンサー

こんにちは。

>文字種ではしてくれなさそうなのです。

ご指摘のとおりです。マクロの流れは見えていらっしゃるようですね。

それなら、少し、解説させていただきます。

Replace関数は、分かっても、そこから、半角カタカナをどう抜き出すか分からなければ、これは解決しません。今回、実験していませんが、VBAの場合は、一文字ずつ、半角カタカナを全角にすると、半濁点や濁点がバラバラになってしまうようです。そこで、一まとめにして、StrConv(文字列,vbWide) としなければならないのです。それが、この全角・半角の注意点です。

それで、ここでは、正規表現を使います。本来、正規表現の「\uFF66-\uFF9F」の部分は、半角カタカナを使えばよいのですが、Webサイトでは、表示できないので、あえて、Unicode の半角コードで表現しています。この種のマクロは、何度も書いているはずなのに、今回のマクロは、今までとは変えてみました。お時間がありましたら、解読してみてください。

それと、私のWordのマクロに似せて作りました。Wordは、該当する文字や文字列は、Replace で、Document で、一括で出来ますが、Excelは、セルひとつずつに当たらなくてはなりません。

標準モジュールに貼り付けてください。

------------------------------------------------------------
Sub ChangeOneByteChars()
　　Dim rng As Range
　　Dim c As Range
　　Dim i As Long
　　On Error Resume Next
　　Set rng = ActiveSheet.UsedRange.SpecialCells(xlCellTypeConstants, xlTextValues)
　　On Error GoTo 0
　　If rng Is Nothing Then Exit Sub
　　Application.ScreenUpdating = False
　　For Each c In rng
　　　 c.Value = myRegExp(c.Value, i)
　　Next c
　　Application.ScreenUpdating = True
　　MsgBox i & "個のセルに対して置換・終了", vbInformation
End Sub

Private Function myRegExp(ByVal strText, ByRef i As Long)
　　Dim Matches As Object 'MatchCollection
　　Dim Match As Object 'as Match
　　Dim buf As String

　　With CreateObject("VBScript.RegExp")
　　　　.Pattern = "[\uFF66-\uFF9F０-９Ａ-ｚ]+"
　　　　.IgnoreCase = False
　　　　.Global = True
　　　　If .Test(strText) Then
　　　　　　i = i + 1
　　　　　　buf = StrConv(strText, vbNarrow)
　　　　　　.Pattern = "([\uFF66-\uFF9F]+)"
　　　　　　.Global = True
　　　　　　Set Matches = .Execute(buf)
　　　　　　If Not Matches Is Nothing Then
　　　　　　　　For Each Match In Matches
　　　　　　　　　　buf = Replace(buf, .Replace(Match.Value, "$1"), _
　　　　　　　　　　 StrConv(Match.Value, vbWide))
　　　　　　　　Next Match
　　　　　　End If
　　　　End If
　　　　If buf <> "" Then
　　　　　myRegExp = buf
　　　　Else
　　　　　myRegExp = strText
　　　　End If
　　End With
End Function
------------------------------------------------------------

お礼

親切に解説までしてくれてありがとうございます。

回答No.3

noname#79209

以下のような、正規表現による検索・置き換えダイアログが使えるフリーのエクセル用アドインがあります。
http://srcedit.pekori.jp/tool/excelre.html

お礼

フリーのアドインって手もありましたか。
ありがとうございます。

回答No.1

mshr1962

VBAで行うなら
StConv関数でカタカナ、数字、記号、英字を全角または半角にしてから
Replace関数で数字、記号、英字を半角かカタカナのみを全角にすればいいのでは？

フリーソフトを使うなら、下記にいろいろあります。
http://search.vector.co.jp/search?query=%95%B6%8E%9A%95%CF%8A%B7

お礼

お早い回答ありがとうございます。