画像を削除したい（ＶＢＡ）

質問

指定したセルにある画像を削除する様にしたいのですが、
マクロで記録すると、どうしても（Picture 32）のど写真に番号が付いてしまいます。
写真は、その都度変わるので、指定の場所にある例えば、C5セルにある画像だけを消すＶＢＡを教えて下さい。
宜しくお願いします。

回答No.3

KenKen_SP · ベストアンサー

こんにちは。

２つほどサンプルを。ご参考までに。

' // C5セル内に画像左上角がある場合は削除
' // 画像右下がC5セルからはみ出しているかどうかを問わない
Sub SampleProc1()

　　Dim Pic As Picture
　　For Each Pic In ActiveSheet.Pictures
　　　　If Pic.TopLeftCell.Address = "$C$5" Then
　　　　　　Pic.Delete
　　　　End If
　　Next

End Sub

' // セルの選択範囲内に完全に含まれる画像を削除
Sub SampleProc2()

　　Dim Pic As Picture
　　Dim r　 As Range

　　If UCase$(TypeName(Selection)) <> "RANGE" Then Exit Sub
　　For Each Pic In ActiveSheet.Pictures
　　　　Set r = Range(Pic.TopLeftCell, Pic.BottomRightCell)
　　　　If Selection.Address = Union(Selection, r).Address Then
　　　　　 Pic.Delete
　　　　End If
　　　　Set r = Nothing
　　Next

End Sub

お礼

大変助かりました。
ありがとうございました

回答No.2

zap35

こんな感じでしょうか。ただし画像左上がC5にないと削除されません。
セルを覆い隠すように配置されているなら補足してください

Sub Macro()
Dim shp As Shape
　For Each shp In ActiveSheet.Shapes
　　If shp.TopLeftCell.Address = "$C$5" Then
　　　shp.Delete
　　End If
　Next shp
End Sub

お礼

大変助かります。
ありがとうございました

回答No.1

marbin

TopLeftCell
で判断してはいかがでしょう？

お礼

TopLeftCellでも判断できました。
ありがとうございました。