条件式でループ再生したい

質問

ActionScript初心者です。
やり方が分からなくて困っている部分があるので
教えていただければ幸いです。

材料は
■ボタン
■テキストフィールドに変数名をつけたもの(time)
■ムービークリップ（roop_mc）
があり、

やりたい事は
ボタンを押すと、timeの値が0になるまでroop_mcをループ再生させるという事です。
（timeには、JavaScriptから読み込んだ数字（5とか10とか）が入ってます。）

for文を使うのかwhile文を使うのか・・
考えすぎて訳が分からなくなってしまいました（>_<）
本を見てもfor文やwhile文の例は、計算みたいなのが多くムービークリップをループ再生するやり方が分りません。。

初心者なので、意味不明なところがあるかもしれません
がもしご存知の方がいらっしゃいましたら教えていただきたいです。よろしくお願いします。

回答No.1

DPE · ベストアンサー

for や while は、１つのフレーム内で繰り返し処理をしたい場合に使います。
今回は複数のフレームをまたいだループになりますので、for や while は使えません。
要するに、time の値が０でなければ roop_mc のフレーム１に戻り、０の時は最後のフレームで止まればいいわけです。
roop_mc の最後のフレームで time の値を if 文で判断し、その値によって動作を変える、というのはいかがでしょう。
なお、変数名の time という名前は、Flash では識別子になっているようですので、ここでは times という名前で説明します。

ActionScript では、変数や関数・ムービークリップを操作する時は、それらがどの階層にあるかを指定しなければなりません。いわば、変数やムービークリップの持ち主が誰であるかを、はっきりと指定するようなものです。省略すると、自分自身が持っているものを参照する、という意味になります。
JavaScript で読み込んだ数字が入っているとすると、おそらく、変数 times を持っているのはムービー自身だと思います。
Flash では、ムービーそのものも _root という名前のムービークリップとして扱います。
roop_mc からムービー自身の持つ times を参照するには、

　_root.times = ・・・

という具合に、times の持ち主（ターゲットパスといいます）を指定して利用します。
roop_mc がステージに配置されている場合、roop_mc はムービー自身（ _root ）の子にあたります。子から親の階層を指す _parent という相対表現を使って、

　_parent.times = ・・・

でも、同じように times を利用できます。

times の値によって分岐するスクリプトは、大体、次のようになります。
このスクリプトは、roop_mc の最後のフレームにキーフレームを作り、そこに設定してください。ActionScript 専用のレイヤーを用意しておくといいでしょう。

（↓このスクリプトをコピーする場合は、各行頭に入っている全角のスペースを、全て半角のスペースかタブに置き換えてください。このまま使うとシンタックスエラーになります）

　//回数を減らす
　_root.times--;

　//指定回数だけループした場合は停止
　if( _root.times <= 0 )
　{
　　this.stop();
　}
　//それ以外の場合はループ（フレーム１に戻る）
　else
　{
　　this.gotoAndPlay( 1 );
　}

this はやはり階層を表す表現で、自分自身を指します。roop_mc で使った場合、this とは roop_mc を表します。
stop と gotoAndPlay は、_root や他のムービークリップでも利用できるメソッド（関数のようなもの）です。this は省略もできますが、ここでは roop_mc が持っている stop や gotoAndPlay を使うという意味で、あえて明示しています。

先述のスクリプトは、roop_mc のフレーム（タイムライン）に記述しました。フレームで実行するスクリプトは、”フレームアクション”といいます。
ステージにあるボタンやムービークリップのインスタンスにも、スクリプトを設定することができます。これらは”オブジェクトアクション”と呼ばれ、ボタンやムービークリップで指定の現象（イベント）が起きた時に、設定したスクリプトが実行されます。
イベントはいろいろありますが、よく使うものは、

　load : ステージにムービークリップが登場した時
　enterFrame : ステージに存在している間、常に発生している
　press : クリックされた瞬間
　release : クリックして、マウスのボタンが離された時

などです。

roop_mc が、ステージに登場するなり再生されたのでは困ります。最初は止めておきましょう。
”最初の１回だけ”実行したい処理は、ムービークリップがステージに登場した、その時１回だけ発生する
” load ”イベントを利用します。
次のようなスクリプトを、ステージにある roop_mc に設定してください。ムービーが始まった直後、roop_mc はフレーム１で止まった状態になります。

　//最初は止めておく
　onClipEvent(load)
　{
　　this.stop();
　}

onClipEvent は、ムービークリップにオブジェクトアクションを書く時の決まりごとです。(　) の中には、何のイベントが起きた時にスクリプトを実行するかを指定する文字列（イベントハンドラ）を書きます。

このままでは、roop_mc はいつまで経っても再生されません。
roop_mc が再生されるのはボタンがクリックされた時です。ボタンにもオブジェクトアクションを設定し、ボタンが押された時に roop_mc を再生するようにしましょう。
ボタンが押された時の処理には、” press ”か” release ”イベントを使います。
ボタンにオブジェクトアクションを設定する時は、onClipEvent ではなく on というアクションの中に書きます。

　on(release)
　{
　　//ムービークリップを再生
　　_root.roop_mc.gotoAndPlay( 1 );
　}

基本的にはこんなところです。
しかし、例えば roop_mc が再生中にボタンがクリックされると、再びフレーム１に戻ってしまうといった、不測の事態も考えられます。
簡単な対策としては、roop_mc が再生中であるという情報を変数に残し、再生中はボタンが押されても無視することです。
変数はどこに用意してもいいのですが、仮に _root に用意するとします。
メインのタイムラインのフレーム１に、次のようなアクションを設定します。

　//ムービークリップの再生フラグ：true の時、再生中
　play_flg = false;

_root 階層に、play_flg という変数が用意されます。最初は false という値を入れておき、roop_mc が再生中の時は、この変数に true を入れることにします。
ボタンでは if 文でこの変数の値を見て、false だった場合のみ、roop_mc を再生させます。
ちなみに、状況などを保存しておいて何かの判断の材料にする変数のことは、フラグとも呼ばれます。

ボタンのスクリプトに、play_flg を判断する処理を加えます。
先ほどボタンに設定したスクリプトを、次のように変更してください。

　on(release)
　{
　　//ムービークリップが再生中でなければ再生する
　　if( _root.play_flg == false )
　　{
　　　roop_mc.gotoAndPlay( 1 );

　　　//再生中にクリックされても無視されるようにする
　　　_root.play_flg = true;
　　}
　}

ボタンがクリックされた時は、roop_mc を再生させると同時に、” roop_mc が再生中である”という情報を、play_flg に残すようにします。
１度ボタンをクリックすると、play_flg の中身は true になります。次にクリックした時は if 文の条件が不成立になりますから、スクリプトが実行されなくなります。

ですが、今度は、roop_mc の再生が終わっているのに、ボタンをクリックしても２度と再生されないようになってしまいます。
再度再生できるようにするには、play_flg の中身を false に戻しておかなければなりません。
false に戻すタイミングは、roop_mc のタイムラインを止める時です。roop_mc に書いたスクリプトの、this.stop(); の後に

　//再度再生できるようにする
　_root.play_flg = false;

というスクリプトを追加してください。

何度も再生できるようにする場合は、times の値にご注意ください。一旦ループ再生した後は、times の中身は０になっています。
例えばテキストフィールドに回数を入力してもらって再生する場合は、times の値を予めチェックしてから roop_mc を再生するなどの工夫も必要です。

長くなってすみませんでした。
不明な点がありましたら補足してください。

お礼

DPEさん、ありがとうございます！
やってみたら一発で思ってた通りのことが出来て
大感激です（>_<）

色々細かく説明いただいたことも、ちょうど最近本で勉強していた部分だったので、「なるほど～」と思いながら理解できました。本当にありがとうございました。

今やっている作品は、これからも発展させていかなきゃいけないのでまだまだ前途多難です。。もしかしてまたいつか質問させていただく事があるかもしれませんが、その時はまたお助けいただけると嬉しいです。