エクセル 加算

質問

１つのセルに数字を入力すると加算されているマクロを探していたら
以下の回答がありました

Dim memo
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then Exit Sub
If Target.Value <> "**" And IsNumeric(Target.Value) = False Then Exit Sub
Application.EnableEvents = False
If Target.Value = "**" Then
memo = 0
Else
memo = memo + Target.Value
End If
Target.Value = memo
Application.EnableEvents = True
End Sub

このマクロですがＡ１に入力した場合に適用しますが、このマクロをたとえばＡ１からＣ１の範囲で使用した１場合にどのようなマクロをすればよいかわかりません
それか、このマクロではそのようなことができるのかもわかりませんので教えて頂けないでしょうか

回答No.2

SI299792 · ベストアンサー

若干仕様変更してあります。
上げたプログラムは、**入力でクリアしていましたが、
このプログラムはDel で削除するとクリアします。
A1～C1一度にクリアが可能です。別々でもできます。

Option Explicit
'
Private Sub Worksheet_Change(ByVal Target As Range)
'
　　Static Memo(1 To 3) As Long
　　Dim Cell As Range
'
　　If Intersect([A1:C1], Target) Is Nothing Then
　　　　Exit Sub
　　End If
'
　　For Each Cell In Target
'
　　　　If Cell = "" Then
　　　　　　Memo(Cell.Column) = 0
　　　　End If
　　Next Cell
　　Set Cell = Target(1)
'
　　If Not IsNumeric(Cell) Or Cell = "" Then
　　　　Exit Sub
　　End If
'
　　Application.EnableEvents = False
　　Memo(Cell.Column) = Memo(Cell.Column) + Target
　　Target = Memo(Cell.Column)
　　Application.EnableEvents = True
End Sub

お礼

早急な回答ありがとうございました。
こんなこともできるんですね＾＾

回答No.1

imogasi

こんなのは、ニーズに出くわして、調べて、覚えておくしかない。
「 Intersect」というメソッドをね。
Ｇｏｏｇｌｅで「ＶＢＡ　 Intersect」で照会すること。
質問の例で言うと
シートをＳｈｅｅｔ１として、そのＣｈａｎｇｅイベントに
下記を作る。
Private Sub Worksheet_Change(ByVal Target As Range)
With ActiveSheet
Set rngPvt = Intersect(Target, .Range("$A$1:$C$1"))
If Not rngPvt Is Nothing Then
MsgBox "範囲内"
End If
End With
End Sub
Ａ１：Ｃ１の値を変化させたら、「範囲内」とでる。
本番では、MsgBox "範囲内"　　の行に、実際の処理のコード行で入れ替える。