エクセルVBA カウンタ2つを入れ子にしたくない時

質問

皆さんこんにちは。
エクセル2013を使用しております。

エクセルVBAの繰り返し処理について質問させていただきます。

下記のコードですと入れ子があるので
A1にi、A3にi・・・・を一通り記載したあと
またA1にi+2、A3にi+2・・・を繰り返し
最終的にA列には全て同じ値が入ってしまいます。
（Step　2にしたのはA1:A2のように2行毎の結合セルだからです）
-----------------------------------------------------------------
　　　Dim i As Long
Dim j As long
Dim n As long
Dim k As long

　　　 i　＝Userform.textbox1.value
　　　 j =Userform.textbox2.value
　　　For k =i To j Step　2
For n = 1 to j Step 2

Range("A" & n) = k
　　　Range（”B”＆ｎ)＝ｋ+1

　　　Next
　　　Next
----------------------------------------------------------
もしiが1、jが10だとしたら
A1に1、B1に2、A3に3、B3に4、・・・A9に9、B9に10
が入るようにするにはどうしたら良いでしょうか。

iが必ず1から始まるのであればまだ分かるのですが
そうとも限らないので
カウンタはやはり2つ必要だと思うのですが
カウンタが2つあるのに入れ子にしないコードの書き方って
あるのでしょうか。
いくら本やネットを見ても分かりません。
ご教授いただけると幸いです。

回答No.3

kagakusuki · ベストアンサー

>カウンタはやはり2つ必要だと思うのですが

　いいえ、B列のセルに入力する値をｋ+1で増やしているのですから、For~Nextは1つだけでOKです。

Sub QNo8986765_エクセルVBA_カウンタ2つを入れ子にしたくない時()

Dim i As Long
Dim j As Long
Dim k As Long

i=UserForm.textbox1.Value
j=UserForm.TextBox2.Value

For k = i To j Step 2
With Range("A1").Offset(k - i)
.Value = k
.Offset(0, 1).Value = k + 1
End With
Next k

End Sub

お礼

iは必ずしも1で始まるわけではないので
Forで指定しなければ・・・
その都度セルのアドレス？も2個ずつ変わるから
Forで指定しなければ・・・
と考えていました。
確かにセルはA1から毎回開始するので
こちらはオフセットにしたら良かったのですね。
カウンタ2つは絶対必要だと思っていたので
延々と悩んでいました。
大変助かりました、ありがとうございます。

回答No.5

real beatin（@realbeatin）

こんにちは。

まず、単一セルをオブジェクトを捉える場合は、
RangeよりもCellsを使うのが基本的な書法ですし、
今回の課題への答としても有効です。
　　Cells(i,j).　　と、
タイプしてもヒントが出てこないのはトッツキ難いかもですが、
結果的に構文が楽になる場合が多いですし、
他にもいいことあるってこれから気づくこともあるかと思います。

さて、
質問の趣旨を追わずに、「やりたいこと」だけをみて、効率を考えず、
解り易い方法を概念として提示するなら、
' ----------------------------------------------------------
　　For n = i To j Step 2
　　　　Cells(n, 1) = n
　　Next n
　　For n = i + 1 To j Step 2
　　　　Cells(n - 1, 2) = n
　　Next n
' ----------------------------------------------------------
このような記述も、アリ、ですね。
今後、どのような方法を採るにしても、
上記の方法を概念として理解しておくことは重要なステップです。

では、本題
> カウンタ2つを入れ子にしたくない
ということだと、セルに代入する数値を基準にループして、
セルの番地の方を演算する形になります。

慣れない内は、
オブジェクトへの参照に失敗することが多いことを気にするせいか、
参照する側を固定する発想に縛られる傾向があるようですが、
以下のように右辺をシンプルにする書き方もあって、
案外スッキリ書くことができます。
' ----------------------------------------------------------
' ' １）「商」と「剰余」で番地を求める方法
　　For n = i To j
　　　　Cells(((n - 1) \ 2) * 2 + 1, (n - 1) Mod 2 + 1) = n
　　Next n
' ----------------------------------------------------------
ＶＢＡのヘルプで「算術演算子」で検索して、
「\ 演算子」「Mod 演算子」 を確認しておいてください。
' ----------------------------------------------------------
' ' ２）「偶数／奇数」
' ' （２進数の１の位が１かどうか）で番地を求める方法
　　For n = i To j
　　　　Cells(n - 1 + (n And 1), 2 - (n And 1)) = n
　　Next n
' ----------------------------------------------------------
ＶＢＡのヘルプで「論理演算子」で検索して、
「And 演算子」 を確認しておいてください。
下段の「ビット単位の比較」を読んでから、
Web上で【二進数】や【ビット演算】について調べてみて下さい。
' ----------------------------------------------------------

「偶数／奇数」の判別には、
n Mod 2　が 0 か 1 か、で判別するのが一般的で、
例示１）で示しているのも「偶数／奇数」判別です。

「商」と「剰余」の扱いは、最初は概念的に馴染まずに難しく感じるかも
知れませんが、初級の内にしっかり身に付けておいた方がいいです。
１）が難しいようでしたら２）は後回しにしていいです。

とりあえず以上です。

お礼

realbeatinさんこんにちは。

1）2）の意味はなんとなく理解出来ましたが
実際使えるか・・というと自信がありません。
もうちょっと勉強してみます。
右辺をスッキリ書くなんて自分では思いつかないです。
いつもありがとうございます。

やはり基礎がないところに知識を詰め込むのに
ちょっと無理を感じてきていて
やりたい事と出来る事の差がどんどん開いてる感覚です。
エクセルワークシート関数の頭から離れられていないのが
自分でも分かります。

いただいたご回答を次に活かせるくらいの基礎を身に着けるべく
講習会に行ってみようかと本気で悩み中です。
あれだけお世話になっているのにもかかわらず
大した成長も出来なくて本当に申し訳ない・・・
もうちょっと高レベルな質問が出来るくらいには
なりたいのですが。。。

回答No.4

kagakusuki

以下の様な方法もあります。

Sub QNo8986765_エクセルVBA_カウンタ2つを入れ子にしたくない時_2()

Dim i As Long
Dim j As Long
Dim k As Long

i=UserForm.textbox1.Value
j=UserForm.TextBox2.Value

For k = i To j
Range("A1").Offset(WorksheetFunction.Floor_Precise(k - i, 2), _
Abs(WorksheetFunction.IsOdd(k - i))).Value = k
Next k

End Sub

お礼

WorksheetFunction.Floor_Preciseメソッド、
初めて知りました。
いろんなやり方があるんですね。
ありがとうございます。

回答No.2

mt2008

こういう事がしたいのでしょうか？

Sub aaa()
　　Dim i As Long
　　Dim j As Long
　　Dim n As Long
　　Dim k As Long

　　i = Userform.textbox1.value
　　j = Userform.textbox2.value
　　n = 1

　　For k = i To j Step 2
　　　　Range("A" & n) = k
　　　　If (k + 1) <= j Then Range("B" & n) = k + 1
　　　　n = n + 2
　　Next
End Sub

お礼

ｎ＝1を
ｎ＝ｎ+2にするやり方は大変勉強になりました。
ネット等にもA＝A+1と書いてあるのを見たことがありますが
実際こうやって使うものだとは知りませんでした。
とても分かりやすいコードで初心者の私にも理解出来ました。
ありがとうございます。

回答No.1

neKo_quatre

逐次計算してるわけでもないし、最終的にセルに入る値は１つなら、

> カウンタはやはり2つ必要だと思うのですが

これが間違いです。

> もしiが1、jが10だとしたら
外側ループのkの開始値と、内側ループの開始値が同じ1なので分かりにくいです。
i=3, j=5だとすると、

1) 外側ループは、k=3, 5
　k=3のとき、
　　2) 内側ループは、n=1, 3, 5
　　　n=1のとき、
　　　　A1=3　　　　<-この処理はムダになる
　　　　B1=4　　　　<-
　　　n=3のとき、
　　　　A3=3　　　　<-
　　　　B3=4　　　　<-
　　　n=5のとき、
　　　　A5=3　　　　<-
　　　　B5=4　　　　<-
　k=5のとき、
　　2) 内側ループは、n=1, 3, 5
　　　n=1のとき、
　　　　A1=5
　　　　B1=6
　　　n=3のとき、
　　　　A3=5
　　　　B3=6
　　　n=5のとき、
　　　　A5=5
　　　　B5=6

が入ります。
最後のループで全部のセルの値は上書きされます。

なので、kの値はループさせる必要が無く、(j-1)が偶数ならj, (j-i)か奇数ならj-1を設定すればＯＫでは。

お礼

カウンタ2つが必要・・が間違い、
Kをループさせる必要がなかったんですね。
入れ子を知らずにコードを書いてみて
「なぜこんな結果になるんだ？！」と
ながらく調べた結果入れ子の存在を知ったど素人です。
初歩的な質問にご丁寧に説明付でご回答いただき
感謝しております。