exelのbookまたがりでセルをコピー貼付けたい

質問

エクセル2010のvbaで質問です。

シンプルなデータ表から、印刷向きレイアウトにした別BOOKにセル内容を
送りたいのですが、うまくいきません。

開いてあるbookまたがりでセル値のコピーをします。送り側は連結セルです。
行、列を可変として順次ループで回すので、RANGEでなくCELLS（行、列）の指定で行いますが、
実行時エラーが出ます。（インデックスが有効範囲にありません）

Sheets(OUTSHEET).Cells(行,列).Value = Sheets(INSHEET).Cells(行,列).Value

↑現在この書き方でエラーになります。うまくいく方法はないのでしょうか。

なお、手動でコピーして、送り側セルでエンター押すとできます。
でもそのマクロ記録ではセル番地指定なので、自動化にできません。
詳しい方、よろしくお願いします。

回答No.1

eden3616 · ベストアンサー

Sub テスト()
Dim INSHEET As String
Dim OUTSHEET As String
Dim 行 As Long '又は Integer
Dim 列 As Long '又は Integer
INSHEET = "Sheet1"
OUTSHEET = "Sheet2"
For 行 = 1 To 5
　　For 列 = 1 To 3
　　　　Sheets(OUTSHEET).Cells(行, 列).Value = Sheets(INSHEET).Cells(行, 列).Value
　　Next 列
Next 行
End Sub

このようなコードでインデックスが有効範囲外というエラーがでるとすれば
　Sheets(OUTSHEET)
　Sheets(INSHEET)
のシートが見つからない場合が考えられます。

変数「OUTSHEET」、「INSHEET」に設定してあるシート名に誤りがないか確認してください。

またブックを跨ぐとありますが、上記コードでは同一ブックのシートを跨ぐ書き方になります。
別ブックを指定する場合は以下のようにしてください。

Sub テスト()
Dim INSHEET As String
Dim OUTSHEET As String
Dim INBOOK As String
Dim OUTBOOK As String
Dim 行 As Long '又は Integer
Dim 列 As Long '又は Integer
INBOOK = ThisWorkbook.Name ' = "ブック名" のように指定も可能
INSHEET = "Sheet1"
OUTBOOK = "Book1"
OUTSHEET = "Sheet2"

For 行 = 1 To 5
　　For 列 = 1 To 3
　　　　Workbooks(OUTBOOK).Sheets(OUTSHEET).Cells(行, 列).Value = Workbooks(INBOOK).Sheets(INSHEET).Cells(行, 列).Value
　　Next 列
Next 行
End Sub

お礼

No.１様、早速の回答、ありがとうございます。

下の例をやったら、できました。
ご指摘の通り、bookまたがりに対する経験不足から、失敗していました。
色々なガイドのHPを見てはいたのですが、的確なご指導のおかげで、
無事解決しそうです。

大変助かりました。
ありがとうございました。