重複数字を除いて数字を表示する方法。

質問

どなたかご存じでしたらご回答をよろしくお願いします。

【質問】
　Ａ列～Ｕ列に数字が左から右に昇順で入っています。(数字は重複があります)
　 Ｖ列以降に重複を除いた数字を表示する方法が知りたいです。

●実行前
1　1　4　6　10　10　16　19　21　24　25　27　29　30　33　33　35　38　38　39　42
2　3　5　6　　7　9　10　13　14　18　21　23　27　27　28　31　32　33　39　41　42
3　4　5　6　　9　11　12　17　18　19　20　24　25　26　28　34　36　37　38　38　39
　　　　　　　　　　　　　　　　　　　　　　　　　　：
　　　　　　　　　　　　　　　　　　　　　　　　　　：
●実行結果（Ｚ列以降に重複した数字を除いた数字を表示する。）
A列～U列の数字：1　4　6　10　16　19　　21　24　25　27　29　30　33　35　38　39　42
A列～U列の数字：2　3　5　6　　7　　9　　10　13　14　18　21　23　27　28　31　32　33　39　41　42
A列～U列の数字：3　4　5　6　　9　　11　12　17　18　19　20　24　25　26　28　34　36　37　38　39 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　：
　　　　　　　　　　　　　　　　　　　　　　　　　　：
●注意事項
　・使用するエクセルは２０１０です。
　・Ａ～Ｕ列に入る数字は、１～４３です。

以上、よろしくお願いします。

回答No.3

bunjii · ベストアンサー

>Ｖ列以降に重複を除いた数字を表示する方法が知りたいです。
処理の都合でV列は空欄にさせて頂くとして次の数式を提案します。
W1=IF(MAX($A1:$U1)=MAX($V1:V1),"",SMALL($A1:$U1,COUNTIF($A1:$U1,"<="&V1)+1))
W1セルをAQ1までコピーして下へ必要数コピーしてください。

お礼

ご回答ありがとうございます。
割とシンプルな数式でできるのですね。
やってみて得たい結果になりました。
ありがとうございました。
またよろしくお願いします。

回答No.2

MackyNo1

元データがA1:U1にあり、Z1セルから右に重複のない数字を表示するなら以下の数式を入力します。

Z1セル（下方向にオートフィルコピー）

=MIN($A1:$U1)

AA1セル(右方向および下方向にオートフィルコピー）

=IF(Z1="","",IFERROR(SMALL($A1:$U1,1+COUNTIF($A1:$U1,"<="&Z1)),""))

お礼

いつもお世話になっております。
ご回答いただきありがとうございます。
２段階のやり方もあるのですね。
勉強になりました。
またよろしくお願いします。

回答No.1

keithin

結果を、Ｕ列のすぐ隣のＶ列からもう並べたいのか、それとも少し隙間を空けたＺ列から並べるのでよいのかによっても、数式の難易度が随分変わります。

とりあえず
Ｖ１：
=CHOOSE(SIGN(COLUMN(A1)-COUNT(0/FREQUENCY($A1:$U1,$A1:$U1)))+2,SMALL($A1:$U1,COUNTIF($A1:$U1,"<"&W1)),MAX($A1:$U1),"")
右にコピー、下向けにコピー

最初にＶ１に式を入れただけでは計算が終わらないので、キチンと最後まで手順を行ってください。

お礼

早速のご回答ありがとうございます。
教えて頂いたとおりやってみて、Ｖ１から重複なしで数字が表示できました。
ありがとうございました。