エクセルのかなり複雑な処理の解決法を教えて下さい！

質問

エクセルでこのような複雑な作業を組み込むことが可能なのかどうか教えてください。

重複した数値にインデックスされた文字列の昇順に関わる問題です。

任意の文字を並べた列の直下に（※ここでは<0>～<9>）、それぞれ数値を配置しているとします。

<0> <1> <2> <3> <4> <5> <6> <7> <8> <9>
17 , 14 , 15 ,14 , 10 , 16, 17 , 11 ,10 , 17

<0>と17、<5>と16など文字列と数値は上下セットとして考えます。

このセットを、数値の大きい順番に並び替え、さらにその並び替えた先で文字列も自動で一緒に並び替えるというのが目的です。

私なりに少ない頭を使って考えて、LARGE関数とINDEX関数＆MATCH関数をなんとか用い、値を昇順させ並び替え、さらに値を呼応させて文字列も並び替えるようにしてみたのですが、

ここでどうしても『数値の重複問題』という壁が出てきてしまいます。。

先の関数を用いるとこのように値が出力されます。

17 , 17 , 17 ,16 , 15 , 14, 14 , 11, 10, 10
<0> <0> <0> <5> <2> <1> <1> <7> <4> <4>

数値がすべて、重複せずに済めば事足りるのですが、数値が重複している場合、『<0> <0> <0> 』のように呼応している文字列も重複してしまいます。。これ以上はこの関数では自動で並び替えることができません。

ここからなのですが、このように数値が重複した場合、さらにここから重複している数値同士の間でさらに昇順を行い、文字列が<0>に近い順（セル上ならより左側にある文字列の順）で並び替えたいと思っています。

17 , 17 , 17 , 16 , 15 , 14, 14, 11, 10 , 10
<0> <6> <9> <5> <2> <1> <3> <7> <4> <8>

このような並び替えを自動でさせるにはどうしたら良いでしょうか？そもそも可能なのでしょうか。。

私のエクセルレベルは、関数をネットで調べてきてそこそこいじって組み込む程度のレベルです。

どなたか教えて下さると助かります。

所持しているエクセルは『Excel2010 windows7 版』です。よろしくお願いします。

回答No.3

KURUMITO · ベストアンサー

分かり易い方法は作業のための行を作って対応する方法です。
例えばA１セルからJ１セルにかけて<0>,<1>,<2>……が入力されており、A２セルからJ２セルにかけてお示しの数値が有るとします。
作業のための行を３行目に作るとしてA３セルには次の式を入力してJ３セルまで横にドラッグコピーします。

=A2+0.1/COLUMN(A1)

そこでお求めの２行目の数値を５行目に並べて表示させるとしたら次の式をA５セルに入力してJ５セルまでドラッグコピーします。

=INDEX($A2:$J2,MATCH(LARGE($A3:$J3,COLUMN(A1)),$A3:$J3,0))

また、１行目にデータを並べるとしたらA６セルには次の式を入力してJ６セルまで横にドラッグコピーします。

=INDEX($A1:$J1,MATCH(LARGE($A3:$J3,COLUMN(A2)),$A3:$J3,0))

お礼

回答してくださってありがとうございます！

すごいです！まさに求めていた通りの結果になりました！ありがとうございます。2回にかけて同じ種類の式を適用させるんですね、なるほど…

回答No.4

tom04

こんにちは！
一例です。

↓の画像で元データは2・3行目にあるとします。

A5セルは単に
=LARGE($A3:$J3,COLUMN(A1))

A6セルに
=INDEX($A2:$J2,,SMALL(IF($A3:$J3=A5,COLUMN($A1:$J1)),COUNTIF($A5:A5,A5)))
A6セルは配列数式になってしまいますので、Shift＋Ctrl＋Enterで確定！
この画面からコピー＆ペーストする場合は、
上記数式をドラッグでコピー　→　A6セルを選択　→　数式バー内でクリック　→　貼り付け
→　そのまま（編集可能のまま）Shift＋Ctrlキーを押しながらEnterキーで確定！
数式の前後に｛　｝マークが入り配列数式になります。

最後にA5・A6セルをオートフィルでコピー！
これで画像のような感じになります。m（_ _）m

お礼

ご回答ありがとうございます！

tom04さんの方法や、KURUMITOの方法でも両方とも自分の求めていた処理ができました！動いた時はもう、、感動です…！

わざわざ大変わかりやすい画像も添付してご指導くださり、ありがとうございました！

回答No.2

duke_kimura

少しずれるかも知れませんが。

EXCELで複雑な処理を行う際、EXCELの関数ではなくEXCEL VBAという物も利用でき、これは制約のあるプログラム言語(VB)のような物ですので、配列の計算程度であれば十分可能です。

もしプログラマの方でしたら、VBAの方がとっつきやすいかも、という話です。
関数での実装方法は分かりません。

お礼

回答していただいてありがとうございます！

はい、確かにおそらく配列のような本格的なプログラムを組んでいけば可能かな…という考えはあったのですが、それほど自身はプログラムに長けていません＾＾；　なのでパッチのような扱いやすい関数が無いものかと探しておりました。

ＶＢＡですか？？いまＰＨＰを勉強中の身なので、ちょっと調べてみようと思います。

ありがとうございました！

回答No.1

LHS07

どのような結果にしたいのかわかりませんが

各セル
A2に<0>,　B2に<1>、C2に<2>
A3に17,　B3に14、C3に15
となっていて
3列の順番にならべてかえたときに2列の数字も対応させたいのでしょうか？

お礼

説明が下手でごめんなさい。＾＾；

『tom04』さんと『KURUMITO』さんがご指導してくださったような変わった処理がしたかったのです＾＾

回答してくださって、ありがとうございました！