【VBA】任意のファイルの一括操作について

質問

こちらの識者の方々にはいつもお世話になっております。
VBAで教えていただきたいことがあり質問いたします。

C:\aaa\に下記のexcelファイルがあります。
【見本】東京.xls
【見本】埼玉.xls
【見本】神奈川.xls
【見本2】千葉.xls

これを
1.C:\bbb\へコピーし、
2.ファイル名の【見本】と【見本2】の文字列を削除し、
3.拡張子の前に本日の日付をyyyymmdd形式で追加し、
4.それぞれのexcelファイルのsheet1のa1セルにyyyymmdd形式で本日の日付を入力する。
というマクロを組みたいと思っています。

一つ一つnameステートメントでファイル名を変更したり、
open→Range("A1").Value→closeとやってもできるんですが、
条件もすこぶる単純ですし、一括でできるようなコードはないかと思っています。

最終的な期待するファイルのフルパスは↓のようになります。
C:\bbb\東京20130426.xls
C:\bbb\埼玉20130426.xls
C:\bbb\神奈川20130426.xls
C:\bbb\千葉20130426.xls

C:\bbb\へコピーするところまでは調べてできたのですが、
その先がこれというものを見つけられず。
どなたかご教示いただけないでしょうか。
宜しくお願い致します。

Sub Test()

Dim objFSO As FileSystemObject

Const cnsSOUR = "C:\aaa\*.xls"
Const cnsDEST = "C:\bbb\"

Set objFSO = New FileSystemObject
objFSO.CopyFile cnsSOUR, cnsDEST, True
Set objFSO = Nothing

End Sub

回答No.1

DOUGLAS_ · ベストアンサー

お示しの作業順序ではなくて、下記のようなことでお考えになってみてはいかがでしょうか？
１）C:\aaa\にある「下記」のexcelファイルを開く。
２）sheet1のa1セルにyyyymmdd形式で本日の日付を入力する。
３）ファイル名の【見本】と【見本2】の文字列を削除し、
４）拡張子の前に本日の日付をyyyymmdd形式で追加し、
５）C:\bbb\に保存する。

Sub Macro1()
    Dim myDate As String
    Dim myPath As String
    Dim myName1 As String
    Dim myBook As Workbook
    Dim myName2 As String
    myDate = Replace(Date, "/", "")
    myPath = "c:\aaa\"
    myName1 = Dir(myPath & "*.xls")
    Do While myName1 <> ""
        If myName1 Like "【見本*】*.xls" Then
            Set myBook = Workbooks.Open(myPath & myName1)
            myBook.Sheets("Sheet1").Cells(1, 1) = myDate
            myName2 = "C:\bbb\" & Replace(Mid(myName1, InStr(myName1, "】") + 1), ".xls", myDate & ".xls")
            myBook.SaveAs myName2
            myBook.Close
        End If
        myName1 = Dir
    Loop
End Sub

お礼

なるほど！
先にFileSystemObjectを使ってフォルダ内の.xlsファイルを全てコピペするのを見つけたので、提示した順番に拘ってしまいました。
見方を変えるとは正にこのことですね。
なぜこれで期待する動作になるのか自分でも調べてみたいと思います。
ありがとうございました。