Excelのシートを1枚にまとめる方法について

質問

Excelについて、日報のようなもので1つのファイル内に複数のシート（約30シート/1ファイル）が作成してあります。
これを1ページにまとめるような方法があればご教授ください。
コピー・ペーストで地道にやり始めましたが、操作ミスがあるような気がして、今一つ不安になってしまいます。
項目ごとに集計するのではなく、単純に縦に並べていきたいのです。
よろしくお願いします。

回答No.2

K Kazz（@JazzCorp）

'ブックの全シートを単純に１枚にまとめる
Option Explicit
Const xName_To = "Combiner"
Const xHeads = 1
Sub CombineSheets()
Dim xLast_From As Long
Dim xLast_To As Long
Dim kk As Long
Application.ScreenUpdating = False
Application.DisplayAlerts = False
For kk = 1 To Worksheets.Count
If (Worksheets(kk).Name = xName_To) Then
Worksheets(kk).Delete
Exit For
End If
Next
'先頭に集合用のワークシートを追加
Worksheets.Add Before:=Worksheets(1)
Worksheets(1).Name = xName_To
For kk = 2 To Worksheets.Count
'元データを選択してコピー
xLast_From = Worksheets(kk).Cells(Rows.Count, "A").End(xlUp).Row
Application.CutCopyMode = False
With Worksheets(xName_To)
'集合先のシートの行数を調べる
xLast_To = .Cells(Rows.Count, "A").End(xlUp).Row
Application.CutCopyMode = False
If (xLast_To = 1) Then
'ヘッダをコピー
Worksheets(kk).Rows("1:" & xHeads).Copy
.Range("A1").PasteSpecial
xLast_To = .Cells(Rows.Count, "A").End(xlUp).Row
Application.CutCopyMode = False
End If
'ヘッダを除いてコピー
Worksheets(kk).Rows(xHeads + 1 & ":" & xLast_From).Copy
.Range("A" & xLast_To + 1).PasteSpecial xlPasteValues
End With
Next kk
Worksheets(1).Select
Application.CutCopyMode = False
Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub

お礼

JazzCorpさん、ありがとうございます。
試してみたいのですが、ちょっと自分には難しそうなので
時間があるときに頑張ってみたいです。