LARGEで同じ値の時の順位

質問

いつもお世話になります。
WINDOWS7 EXCELL2010です。

添付図で説明しますと、
順位(F列)が　３位と４位の
E3(2.000) E4(2,000)が偶然に同一金額の時
会社名(B)も同一になる数式です。

この同一の金額の時、
H列で言うと　「A F B C D」もしくは「A F C B D」 とするには何かいい方法ってないでしょうか。
是非ともご指導を仰ぎたいです。

数式は次のようでご参考に
F1～F5 はただの数値
G1 =LARGE($E$2:$E$11,F2)

H2 =INDEX($A$2:$A11,MATCH(MAX($E$2:$E$11),$E$2:$E$11,0))

回答No.1

tom04 · ベストアンサー

こんばんは！

H2セルにMATCH関数をお使いですが、MATCH関数は最初にヒットした行（上側の行）しか返せません。

そこで一例です。

H2セルに
=IF(G2="","",INDEX(A$1:A$100,SMALL(IF(E$1:E$100=G2,ROW(A$1:A$100)),COUNTIF(G$2:G2,G2))))

これは配列数式になってしまいますので、Shift＋Ctrl＋Enterで確定！
この画面からコピー＆ペーストする場合はH2セルに貼り付け後、数式バー内で一度クリック！
編集可能になりますので、Shift＋Ctrlキーを押しながらEnterキーで確定！
数式の前後に｛　｝マークが入り配列数式になります。

これをオートフィルで下へコピーではどうでしょうか？

※　数式は100行目まで対応できるようにしています。m(_ _)m

お礼

いつもいつもご指導ありがとうござます。
思っていた通りにできました。

回答No.2

keithin

ごく簡単な計算だけで。

Ｄ２に
=RANK(E2,E:E)+ROW()/1000
と記入、ホームタブでカンマ区切り書式を入れておき、以下コピー

Ｆ２に
=SMALL(D:D,ROW(F1))
と記入、同様にカンマ区切り書式を入れて以下コピー

Ｇ２に
=VLOOKUP(F2,D:E,2,FALSE)
Ｈ２に
=INDEX(A:A,MATCH(F2,D:D,0))
以下コピーで完成。

Ｄ列を汚したくなければ、どこか邪魔にならないＺ列とかシート２とかに追いやって全然かまいません。

お礼

いつもご指導賜り感謝感激です。
一つの課題に対して複数のやり方があるのが勉強になりベストアンサーの判定には迷います。
判断として先に回答していただいた方にしました。
お許しください。