エクセルのマクロを使って未入力情報を知らせる方法

質問

数日前からマクロをかじり始めたばかりで、頭をかかえる日々が続いております。
テキスト本を片手に、作っているのですが、何を探せば良いかも分かっていない始末です。
そんなズブの素人なので、ご質問させて下さい。

A列に経費名、B列にその数値を入力するファイルがあります。
これを違うシートに貼り付けるマクロを作成しているのですが、未記入があればメッセージボックスで「記入漏れがありますがそのまま実行しますか？」的な警告を出したいです。

　　A　　 　B
1　家賃　50000円
2　食費　20000円
3　雑費　 5000円
4
5
6　合計　75000円

今B列には、「A列に文字があればB列を赤に」
「B列に何か入力されていれば白に」
と言う、条件付書式が入っています。
これだけでも充分、記入漏れは防げるのですが、更に念押しをしたいのです。

条件付書式を使って赤の判定が1つでもあれば「記入もれがあります」的なメッセージボックスをと考えたのですが、条件付書式の色を拾うのは難しいみたいですね。

そもそも「範囲内に空白箇所があればメッセージーボックス」にできれば、話は早いのでしょうが、他との兼ね合いで4・5の行は残しておかなければなりません。

色々ネットでも探してはいるのですが、ど～言った考え方をすれば良いのかも分かって無い状況で困り果てています。

例えば「A列のセル記入数と、B列のセル記入数が違えばメッセージ」など出来るのでしょうか？
ご教示、宜しくお願い致します。

回答No.1

keithin · ベストアンサー

＞これを違うシートに貼り付けるマクロを作成している

このマクロの中で、検査をさせてやればいいですね。

今のマクロの作成例：
sub macro1()
range("A1:B3").copy destination:=worksheets("Sheet2").range("A1")
end sub

そのマクロに追加する機能：
Ａ１とＢ１、Ａ２とＢ２、Ａ３とＢ３が、それぞれ「片方が記入されていて、他方が記入されていない」時に、警告を出して続行するか中断するかを求める

基本的な概念：
sub macro1r1()
　if application.counta(range("A1:B1"))=1 _
　or application.counta(range("A2:B2"))=1 _
　or application.counta(range("A3:B3"))=1 then
　　if msgbox("記入漏れ。続行しますか",vbokcancel) <> vbok then exit sub
　end if

　range("A1:B3").copy worksheets("Sheet2").range("A1")
end sub

変数を使い、もっと一般化すると：
sub macro2()
　dim r as long
　dim flg as string

　for r = 1 to 3
　　if application.counta(cells(r, "A").resize(1, 2)) = 1 then
　　　flg = "記入漏れ"
　　end if
　next r

　if flg = "記入漏れ" then
　　if msgbox("記入漏れ。続行しますか",vbokcancel) <> vbok then exit sub
　end if

　range("A1:B3").copy worksheets("Sheet2").range("A1")
end sub

＃参考
＞例えば「A列のセル記入数と、B列のセル記入数が違えばメッセージ」

これじゃダメですね。たとえばＡ列はＡ１に１個記入され、Ｂ列はＢ２に１個記入されていましたでは、通せません。

お礼

keithinさん

早速の回答ありがとうございます！自分の拙い文章だったにも関わらず、細かにご指摘頂き感激しております。

頂いた物を、足りない頭で理解しながら入力していたら、お返事が遅くなってしまいました。大変申し訳ありません。

今後、又つまづいた際に、ご縁がありましたら何卒宜しくお願いいたします。
本当にありがとうございました。