エクセル重複チェックでデータ追記方法について

質問

• 「Sheet5」のデータを「Sheet6」に重複チェックをしながら追記する方法について教えてください。
• 重複チェックは請求先コードと日付の２つで行いたいのですが、日付のデータ型を「Date」にしてどう記述すればよいか分かりません。
• また、請求先コードによる重複チェック後、データを昇順で並び替えたいです。

回答No.2

fumufumu_2006 · ベストアンサー

Dictionaryオブジェクトで重複チェックをしながら追記しました。

Sub sample()
Dim dic As Object
Dim r6 As Long
Dim r5 As Long
Dim key As String
'Sheet6のデータを取得
Set dic = CreateObject("Scripting.Dictionary")
r6 = 2 'Sheet6の注目行の初期値
Do While Sheets("Sheet6").Cells(r6, "A").Value <> ""
key = Sheets("Sheet6").Cells(r6, "A").Value & vbCrLf & Sheets("Sheet6").Cells(r6, "C").Value
If Not dic.Exists(key) Then
dic.Add key, 1
End If
r6 = r6 + 1
Loop
'Sheet5のデータをチェックしながらSheet5に追加
r5 = 2 'Sheet5の注目行の初期値
Do While Sheets("Sheet5").Cells(r5, "A").Value <> ""
key = Sheets("Sheet5").Cells(r5, "A").Value & vbCrLf & Sheets("Sheet5").Cells(r5, "C").Value
If Not dic.Exists(key) Then
dic.Add key, 1
Sheets("Sheet6").Cells(r6, "A").Resize(1, 3).Value = Sheets("Sheet5").Cells(r5, "A").Resize(1, 3).Value
r6 = r6 + 1
End If
r5 = r5 + 1
Loop
'Sheet6を並び替えるなら
Sheets("Sheet6").Columns("A:C").Sort Key1:=Sheets("Sheet6").Range("A2"), Order1:=xlAscending, Key2:=Sheets("Sheet6").Range("C2"), Order2:=xlAscending, Header:=xlYes
End Sub

お礼

fumufumu_2006　様、

わざわざプログラムを作成して頂き、ありがとうございます。
２つのキーを基準にしての重複チェックは完成しました。
処理も早くて驚きました。
ネットでサンプルを見ながら作成していました。
まだ、システムは完成していませんが、調べながら構築していきます。
ありがとうございました。