Flash初心者のためのMCの切り替え方

質問

• Flash初心者の方がMCの切り替えについて質問されています。attachMovieを使用してライブラリ内のMCをステージに呼び出す方法や、MCを押す度に切り替える方法についてのご質問です。
• MCを切り替える際には、MCを削除し新しいMCをステージに追加することで実現できます。また、MCを縦に並べる方法や横に並べる方法についても質問者さんが知りたいとのことです。
• MCを縦に並べる場合は、MCの識別子を数字ごとに比較し、昇順に並べ替えることが必要です。また、同じ数字のMCが複数ある場合は、横に並べる際に20pxの空白を挿入する必要があります。

回答No.1

DPE

作り方の一例です。

ａの１ ～５までの絵を１フレームに１つずつ配置したムービークリップを作り、リンケージ名を”a”にします。
この時、それぞれの絵の左上が、編集画面にある＋印の角に来る（絵の左上がＸ＝ 0、Ｙ＝ 0 になる）ように配置してください。
残るｂ～ｅも同様に、同じ名前の絵を１つのムービークリップにまとめ、リンケージ名を”b”や”e”にします。

「整列」のボタンを作り、ステージに配置してインスタンス名を付けます。
ここでは仮に”align_btn”とします。

メインのタイムラインに次のスクリプトを記述し、プレビューで確認してみてください。
ムービークリップをクリックすると絵が変わり、「整列」ボタンを押すと、上から５番を表示しているものから順に、横の並びは名前の順に並びます。

（↓　各行頭に全角のスペースが入っています。コピーする際は、全て半角のスペースかタブに置き換えてください）

/*
　初期設定
*/

//ムービークリップ（ＭＣ）の大きさ
var clip_w:Number = 80;
var clip_h:Number = 80;

//配置する際の基準の座標と余白（縦横兼用）の大きさ
var org_x:Number = 100;
var org_y:Number = 100;
var margin = 20;

//ＭＣの種類と絵柄の数
var type_max:Number = 5;
var pic_max:Number = 5;

//ＭＣがあるタイムラインを保持
var clip_addr:MovieClip = _root;

/*
　ＭＣの画像を切り替える関数
*/

function Change_Frame():Void
{
　//次のフレームに進める
　//最後まで行ったら１に戻る
　this.gotoAndStop( ( this._currentframe % this._totalframes ) + 1 );
}

/*
　並べ替えを行う関数
*/

function Clip_Align():Void
{
　var i:Number , j:Number , px:Number;
　var ref:MovieClip;

　//表示フレームを順に調べ、表示しているＭＣがあれば横に並べる
　for( i = pic_max ; i >= 1 ; i-- )
　{
　　//全てのＭＣをチェック
　　for( j = 0 , px = 0 ; j < type_max ; j++ )
　　{
　　　//操作するＭＣの参照を作成
　　　//97は”a”の文字コード
　　　ref = clip_addr[ String.fromCharCode( 97 + j ) ];

　　　//該当するＭＣがあった場合、横に並べていく
　　　if( ref._currentframe == i )
　　　{
　　　　ref._x = ( clip_w + margin ) * px + org_x;
　　　　ref._y = ( clip_h + margin ) * ( pic_max - i ) + org_y;

　　　　//次のためにpxを更新
　　　　px++;
　　　}
　　}
　}
}

/*
　セットアップ
*/

function SetUp()
{
　var i:Number;
　var name_str:String;
　var ref:MovieClip;

　//ＭＣのセットアップ
　for( i = 0 ; i < type_max ; i++ )
　{
　　//ＭＣを挿入し、フレーム１で止めておく
　　name_str = String.fromCharCode( 97 + i ) ;
　　ref = clip_addr.attachMovie( name_str , name_str , i );
　　ref.gotoAndStop( 1 );

　　//ボタン機能を定義
　　ref.onPress = Change_Frame;
　}

　//位置を決める
　Clip_Align();

　//「整列」ボタンの機能を定義
　align_btn.onRelease = Clip_Align;
}

//セットアップを実行
SetUp();

＊ ＊ ＊ ＊ ＊

字数制限の都合上、詳細は次の回答で説明いたします。