FLASHのアクションスクリプト2.0でカウントダウンタイマーを作る方法

質問

flashを勉強している者ですが

FLASHのアクションスクリプト2.0
或いは3.0カウントダウンの作り方をご存知の方が
おりましたらご教授願います。
例えば、現在が2009年11月10日の場合

12月20日までの残りの日数を
「あと〇〇日〇〇時間〇〇秒〇〇小数点の秒」
という風に表示させる方法になります。

過去の質問ログを参照して下記のスクリプトを書いたのですが
ドラえもん誕生まで、あとＮａＮ日ＮａＮ時間ＮａＮ分ＮａＮ秒と表示されました。
また、

＞＞target_date = new Date(2009,12,3)←これを現在より過去にすると
正常に”ドラえもんの時代は終了しました”と表示されます。

stop();
target_date = new Date(2009,12,3)
function display() {
today = new Date()
days = Math.floor((millenium-today)/(24*60*60*1000))
time1 = Math.floor(((millenium-today)%(24*60*60*1000))/(60*60*1000))
time2 = Math.floor(((millenium-today)%(24*60*60*1000))/(60*1000))%60
time3 = Math.floor(((millenium-today)%(24*60*60*1000))/1000)%60%60
if(today < target_date ){
countdown_txt.text = "ドラえもん誕生まで、あと"+days+"日"+time1+"時間"+time2+"分"+time3+"秒"}
else if (today > target_date && today < target_date + (24*60*60*1000)) {countdown_txt.text = "ドラえもん完成！！"
}else {countdown_txt.text = "ドラえもんの時代は終了しました…"
}tid = setTimeout(this, 'display', 1000)
}display();

回答No.2

screenstar

>「あと〇〇日〇〇時間〇〇秒」の後に
>〇〇ミリ秒（2桁）を加えて表現をする場合の方法

方法は先の回答を見ればわかるはずですが、補足を入れて説明します．
flashPlayerは、フレームレート（fps）毎に描画の更新を行います．
fpsをデフォルトの12fpsにしている場合、
1秒＝1000ミリ秒（以下ms）/12fps＝約84ms 毎に描画を更新します．
（ただし正確ではありません．環境や処理内容でずれます．）
つまり、タイマーを例えば10ms毎に動作するよう設定しても
12fpsの場合は約84msたたないとタイマーの結果を表示しないのです．
フレームによる描画を待たずに描画の更新を強制する
updateAfterEvent()メソッドがありますが、
このケースでは必要ないと思います．

上記をふまえ、以下の通り修正します．
まずフレームレートを40fpsにします．

//1秒毎に作動するタイマーを設定
var timer:Timer = new Timer(s);
sはconstで設定した秒なので1000msです．
つまり、上記タイマーは1秒毎に作動します．
これを25msごとに作動するようにします．
var timer:Timer = new Timer(25);

var seconds:～～（秒を取得）のあとにmsを取得するため
以下を追加します．10で割っているのは、
0～999msを1～2桁表示にするためです．
var mseconds:Number = Math.floor((millenium.getTime()-today.getTime()) % d % h % m % s / 10);

テキスト表示を修正します．
txt.text = "ドラえもん誕生まで、あと"+days+"日"+hours+"時間"+minutes+"分
"+seconds+"秒"+mseconds;

フレームレートを40fps、タイマーを25ms毎にしたのは
描画のタイミングとタイマーのタイミングを合わせるためです．
1秒＝1000ms/40fps＝25ms

お礼

具体的なご回答ありがとうございます。
仕組みが理解できましたので無事作成することが出来ました。

この度は大変お世話になりました。

回答No.1

screenstar

days,time1等をtraceすればすぐにわかりますが、
結果は「Nan」＝非数　となっています．
milleniumという設定されていない変数が
急にでてきているためです．
おそらくmilleniumはtarget_date（12月20日）と思われるので、
3行目にmillenium = target_date;と入れれば
target_dateが12月20日（未来）でも取りあえず表示はされます．
が、1ヶ月多く表示されるはずです．
Dateのコンストラクタは月を0からカウントして渡す必要があります．

>target_date = new Date(2009,12,3)
上記が12月3日を意図しているとして、以下の通り修正が必要です．
>target_date = new Date(2009,11,3)//2009年12月3日のこと

さらに、target_dateの日付を今日にすると、
期待される表示は「ドラえもん完成！！」ですが、
target_date + (24*60*60*1000)　
これはtarget_dateに1日足したことになっていないので
（traceして見てください）
target_date当日でも「ドラえもんの時代は終了しました」と
表示されてしまいます．

>アクションスクリプト2.0
>或いは3.0
3.0で説明します．

//何度もでてくるミリ秒から日付、時間、分、秒を取得する定数を設定
//定数とはその名の通り固定された値です．
const d:int = 1000 * 60 * 60 * 24;
const h:int = 60 * 60 * 1000;
const m:int = 60 * 1000;
const s:int = 1000;

//目標日12月3日午前0時0分0秒
var millenium:Date = new Date(2009,11,3);
//現在（タイマーの中で取得するので変数宣言のみ）
var today:Date;
//ドラえもん完成日（目標日＋24時間）を設定
var completeDay:Date = new Date();
completeDay.setTime(millenium.getTime() + d);

//テキストを表示するフィールドを設置
var txt:TextField = new TextField();
txt.autoSize = TextFieldAutoSize.LEFT;
addChild(txt);
txt.x = 50;
txt.y = 50;

//1秒毎に作動するタイマーを設定
var timer:Timer = new Timer(s);
//設定した時間（1秒）毎にdisplayを実行
timer.addEventListener(TimerEvent.TIMER, display);

//実行されるリスナー関数
function display(e:TimerEvent):void{
//現在を取得
today = new Date();
//milleniumから取得済みの現在を引き、日・時間・分・秒に直す
var days:Number = Math.floor((millenium.getTime()-today.getTime()) / d);
var hours:Number = Math.floor((millenium.getTime()-today.getTime()) % d / h);
var minutes:Number = Math.floor((millenium.getTime()-today.getTime()) % d % h / m);
var seconds:Number = Math.floor((millenium.getTime()-today.getTime()) % d % h % m /s);

if (today<millenium) {
txt.text = "ドラえもん誕生まで、あと"+days+"日"+hours+"時間"+minutes+"分"+seconds+"秒";
} else if (today > millenium && today < completeDay) {
txt.text = "ドラえもん完成！！";
} else {
txt.text = "ドラえもんの時代は終了しました…";
}
}

//タイマーの動作を開始
timer.start();

お礼

screenstar 様

早速のご回答ありがとうございます。
大変ご丁寧なご解説をありがとうございます。
ご回答の通りに作業をした所、無事に成功しました。

「あと〇〇日〇〇時間〇〇秒」の後に
〇〇ミリ秒（2桁）を加えて表現をする場合の方法も
ご存知でしたらご教授頂けたら幸いでございます。