エクセルの複数列の集計

質問

エクセル集計について質問です。

下記のように、列が複数あって、各教科ごとに集計をしたいのですが、列が複数ある場合、どの関数を使えばいいでしょうか？
よろしくお願いします。
　　　　　 朝 　　　 昼　　　 夜
９－１２ 英語 2 理科 3 国語 3
１－３ 国語 1 社会 2.5 算数 1.4
４－６ 社会 1.5 国語 3 理科 2
７－９ 理科 1 算数 1.3 算数 2
９－１２ 算数 1 英語 1 算数 1

回答No.3

某HN クロメート(Chromate)（@CoalTar）

#1のhige_082さんの回答で良いと思いますが、参考までに
C8セルに
=SUMIF($B$2:$F$6,B8,$C$2:$G$6)
下へオートフィル(添付図参照)

お礼

できました！
どうもありがとうございました！大変助かりました。

回答No.2

imogasi

既出回答にように各列でSUMIFで出して、列数分だけ＋で足すならすぐ思いつく。
まだまだエクセル関数は、複数列を対象にしてできる関数は少ない。
ほとんど無い。
SUMIF関数はその中でも出来るものなのですが（下記注）、その実体は
例データ
A1:G5で
9月12日 英語 2 理科 3 国語 3
1月3日 国語 1 社会 2.5 算数 1.4
4月6日 社会 1.5 国語 3 理科 2
7月9日 理科 1 算数 1.3 算数 2
9月12日 算数 1 英語 1 算数 1
として、
挿入ー名前　成績ーC,E,G列
挿入ー名前　範囲ーB,D,FG列
挿入ー名前　範囲1ーB列
挿入ー名前　成績1ーC列
と名づけて、空きセルに
=SUMIF(範囲,"国語",成績)　でエラー
=SUMIF(範囲1,"国語",成績1)で１
=SUMIF(範囲1,"国語",成績)でエラー
になる。それで目的を達せられない。
ーーー
従って他の方法は、VBAでユーザー関数を作るか、VBAでやるしかないと思う。
標準モジュールに
Function SUMIFX(a, b)
Dim cl As Range
t = 0
For Each cl In a
MsgBox cl
If cl = b Then
t = t + cl.Offset(0, 1)
End If
Next
SUMIFX = t
End Function
ーー
空きセルに
=sumifx(範囲,"国語")
結果は　7
上記コード内でMsgBoxの行は、科目列の全セルを１つづつ捉えていることを確認用で、本番では削除してください。
ーーー
（注）
SUMIF関数で複数列を対象に出来る例として
＝SUMIF(D3:D9,">60",D3:F9)
でD3:D9には全て数字が入っている例が解説書に挙がっている。
数字セル範囲の中から、有る数をこれる数だけ足せ、などは出来る。

お礼

VBAはまだ習得していないので、関数を使用したらできました！
どうもありがとうございました！

回答No.1

hige_082

Ａ　　　Ｂ　Ｃ　　Ｄ　Ｅ　　Ｆ　　Ｇ
1　　　　　 朝 　　　 　昼　　　　 夜
2　９－１２ 英語　2　　理科　3　　国語　3
3　１－３　 国語　1　　社会 2.5　 算数 1.4
4　４－６　 社会 1.5 　国語 3　 　理科 2
5　７－９ 　理科 1　　 算数 1.3　 算数 2
6　９－１２ 算数 1 　　英語 1 　　算数 1

として

英語=SUMIF($B$2:$B$6,B2,$C$2:$C$6)+SUMIF($D$2:$D$6,B2,$E$2:$E$6)+SUMIF($F$2:$F$6,B2,$G$2:$G$6)
国語=SUMIF($B$2:$B$6,B3,$C$2:$C$6)+SUMIF($D$2:$D$6,B3,$E$2:$E$6)+SUMIF($F$2:$F$6,B3,$G$2:$G$6)
社会=SUMIF($B$2:$B$6,B4,$C$2:$C$6)+SUMIF($D$2:$D$6,B4,$E$2:$E$6)+SUMIF($F$2:$F$6,B4,$G$2:$G$6)
理科=SUMIF($B$2:$B$6,B5,$C$2:$C$6)+SUMIF($D$2:$D$6,B5,$E$2:$E$6)+SUMIF($F$2:$F$6,B5,$G$2:$G$6)
算数=SUMIF($B$2:$B$6,B6,$C$2:$C$6)+SUMIF($D$2:$D$6,B6,$E$2:$E$6)+SUMIF($F$2:$F$6,B6,$G$2:$G$6)

べたですが

お礼

教えて頂いたとおり、できました！
どうもありがとうございました！