Microsoft Excel VBAの参照設定

質問

参照設定のデフォルト環境で
Microsoft Scripting Runtime
をオンにしておきたいのですがどうすればいいのでしょうか？

新しくExcelを起動し、その都度、
Microsoft Scripting Runtime
をオンにするのは非常に手間なので、わかる方いましたら教えてください。

回答No.1

KenKen_SP · ベストアンサー

こんにちは。

きちんと自分の手で参照設定するのがベストだと思います。そうでなければ、
参照が不必要なケースでも自動で参照設定されてしまうことになりますよ。
参照設定しなくとも CreateObject を使うという選択肢もありますし。

できない、、と言いたいところですが、下記のような方法で実現できそうです。
ただし、VBAProject へアクセスしますので、マクロのセキュリティーで

　　「VBAProjectプロジェクトへのアクセスを信頼する」

にチェックが入っていなければなりません。くどいようですが、推奨はしません。

以下手順。

1.　新規ワークブックを開く
2.　ThisWorkbook モジュールに下記ソースを貼り付け
3.　適当な名前を付けてアドインとして保存する(*.xla)
4.　上記のアドインをアドインフォルダに移動

　　Sub アドインフォルダのパス表示
　　　　Range("A1").Value = Application.UserLibraryPath
　　End Sub

　　このプロシージャで表示されるフォルダです。WindowsXP なら、

　　C:\Documents and Settings\ユーザー名\Application Data\Microsoft\AddIns\

　　ですね、、多分。

5.　Excel で[ツール]-[アドイン]-[参照] コマンドを実行し、アドインを
　　インストールします。

' // 以下ソース：　ThisWorkbook Module

Private WithEvents xlApp As Application

Private Sub Workbook_Open()
　　Set xlApp = Application
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
　　Set xlApp = Nothing
End Sub

Private Sub xlApp_NewWorkbook(ByVal Wb As Workbook)

　　' Microsoft Scripting Runtime
　　Const CLSID As String = "{420B2830-E718-11CF-893D-00A0C9054228}"

　　Wb.VBProject.References.AddFromGuid CLSID, 1, 0
　　Wb.Saved = True

End Sub

お礼

ありがとうございました。