『締月』『支払月』表示方法

質問

エクセルにて受注一覧表を作成中です。
別シートには顧客マスターがあります。

シート受注一覧表の列に
『締月』と『支払月』があるのですが
日にちまでは必要ないので、
せめて月のみ表示させたく
これも関数でどうにかできないかと・・・。
もし、ご存知のかた、ご教授お願いいたします。

　　　Ｃ　　　　　　　　Ｓ　　　　　　Ｔ　　　　　　　 Ｕ　　　　　　Ｖ
4　　受注日　　　　締日　　　支払日　　 　締月　　　支払月
5　　11/12　　　　 5日 翌月末日
6　　11/12　　　　 10日　　翌々月末日
7　　11/12　　　　 15日　　翌々月5日
8　　11/12　　　　 20日　　翌々月10日
9　　11/12　　　　 25日　　 翌月20日
10　　11/12　　　 末日　　 翌月15日
11　　11/12　　　 不明　　　不明　　　　　不明　　　不明

『Ｃ列（受注日）』は手入力
『Ｓ列（締日）』『Ｔ列（支払日）』には
シート名『顧客マスター』よりVLOOKUP関数が入っております。
『Ｕ列（締月）』と『Ｖ列（支払月）』の関数が知りたいのですが、
締日は上記のとおり、7通りあります。

※『Ｓ列（締日）』『Ｔ列（支払日）』『不明』表示ならば
　『Ｕ列（締月）』と『Ｖ列（支払月）』も『不明』表示で。。。

『Ｖ列（支払月）』の関数を出すには、
やはり、『Ｔ列（支払日）』を
月と日の列に分けた列を追加しなければならないのでしょうか？
（例）翌々月末日なら　

　　　　　　　Ｔ　　　　　　　　Ｕ　　　　　 Ｖ
　　　｜　翌々月末日　｜　2　｜　30　｜　　でしたっけ？

以上、宜しくお願いいたします。

回答No.7

hallo-2007 · ベストアンサー

やはり、翌月とか末日とか文字が式を厄介にしています。
>シート名『顧客マスター』よりVLOOKUP関数が入っております。
があるのであれば、列を追加して
締日(数値）　支払日（数値）に
　　１　　　　　２－００　　　末尾の場合は、月に１加え、日は０にします。
　１０　　　　　３－００　　　＜－これは翌々月末払いの場合
　２０　　　　　１－２０
　　０　　　　　１－１５　　　＜－締日の０は、末締のこと
　　Ｘ　　　　　Ｘ－ＸＸ　　不明の場合は、アルファベットでも入れておきます。
とか数値を入れて、引っ張ってこれませんか。

　　　Ｃ　　　 　　Ｓ　　　　Ｔ　　 　　 Ｕ　　　　　Ｖ
4　　受注日　　　締日　　支払日　　 　締月　　　支払月
5　　11/12　　　　 5　　　 2-00
6　　11/12　　　　 10　　 3-00
7　　11/12　　　　 15　　 2-15
8　　11/12　　　　 20　　 2-10
9　　11/12　　　　 25　　 1-20
10　　11/12　　　 　0　　 1-15
11　　11/12　　　 X　　　X-XX
とかなれば、目的が簡単に出来ると思います。
締日が
=DATE(YEAR(C5),IF(DAY(C5)<=S5,MONTH(C5),MONTH(C5)+1),S5)
支払い日が
=DATE(YEAR(U5),MONTH(U5)+LEFT(T5,1),RIGHT(T5,2))
で下フィルしてください。
式の意味を理解してください。
トリックは、日(DAY(0)は、前月の末日になります。
不明の処理はわかりませんでしたので、わざとエラーが出るようにしました。（数値でなくて、アルファベットなのでエラーになります）
日付が確定したら、手入力で日付入れると良いでしょう。
もし、これでよければ、上記の式のS5、T5のところに、現在S,Tに入っている、VLOOPの式を入れれば、一覧のシートのS,Tの行が省けると思います。

お礼

日にちまで表示させる関数は大変だろう思い、
月のみを表示させよう思っていました。
なのに・・・。
日にちまでもが表示され、感動しています。
毎回、大変お世話になります。
ありがとうございました。

回答No.6

noname#79209

S列とT列が共に文字列で返されているなら、結構厄介です。
W列にワーク列を設けないとキビシイです。
W2に、
=IF(OR($S2="不明",$S2="末日"),0,VALUE(LEFT($S2,LEN($S2)-1)))
として、下にコピー。
U列に、
=IF($S2="不明",$S2,IF($S2="末日",EOMONTH($C2,0),DATE(YEAR($C2),MONTH($C2)+(DAY($C2)>$W2),$W2)))
として、下にコピー
V列に、
=IF($T2="不明",$T2,EDATE($U2,1+(LEFT($T2,2)="翌々")))
として、下にコピー。
ただし、支払月は月数のみです。（完全な支払日のシリアル値にはなっていません）

U列、V列の表示書式は「m;;@」としてください。

お礼

お蔭様で解決いたしました。
ありがとうございました。

回答No.5

noname#79209

確認したいのですが、
支払日の起算日は、締め日でしょうか？
11/12売上で10日締めで翌々月末日支払いなら、
締め日は12/10で支払日は2/28ですか？

補足

はい。そうです。
質問方法わかりにくて、すみません。

回答No.4

nobu555

>　　　　　　Ｔ　　　　　　　　Ｕ　　　　　 Ｖ
>　　　｜　翌々月末日　｜　2　｜　30　｜　　でしたっけ？
先のサンプルの表では、V列は「支払月」になっていますが、
「30」って、「支払日」？

とりあえず、V列は「支払月」で回答します。
セルU5に下記数式を
=IF(C5="","",IF(S5="不明","不明",TEXT(edate(C5,1),"m月")))

セルV5に下記数式を
=IF(C5="","",IF(S5="不明","不明",TEXT(edate(C5,FIND("月",T5)-1),"m月")))

上記数式をそれぞれ必要分下方にコピーする。
必要以上にコピーしても良いように、
C列が空白時は、空白としました。

注意：edate関数は、メニューバー「ツール」の「アドイン」で「分析ツール」へのチェックが必要です。

お礼

お蔭様で解決いたしました。
ありがとうございました。

回答No.3

noname#204879

U5: =IF(S5="不明",S5,IF(S5="末日",C5,IF(DAY(C5)>SUBSTITUTE(S5,"日","")*1,DATE(YEAR(C5),MONTH(C5)+1,1),C5)))
V5: =IF(S5="不明",T5,IF(COUNTIF(T5,"翌月*"),DATE(YEAR(U5),MONTH(U5)+1,1),DATE(YEAR(U5),MONTH(U5)+2,1)))
何れも“ユーザー定義”で d に書式設定

【余談】貴方の質問、よく理解できましたよ。

お礼

お蔭様で解決いたしました。
ありがとうございました。

回答No.2

guchi_yama

質問の意味合いを自分なりに解読してみましたが、
履き違えていたならごめんなさい。

まず、U5セルに
=IF(S5="不明","不明",IF(DAY(C5)<S5,DATE(YEAR(C5),MONTH(C5),DAY(C5)),DATE(YEAR(C5),MONTH(C5)+1,1)))

を下へオートフィル。

次にV5セルに
=IF(U5="不明","不明",TEXT(DATE(YEAR(U5),MONTH(U5)+SEARCH("月",T:T)-1,DAY(1)),"m")&"月"&MID(T5,SEARCH("月",T5)+1,3))

を下へオートフィルで自分なりの〆月と支払日を出せたのですが、
いかがでしょう？

お礼

お蔭様で解決いたしました。
ありがとうございました。

回答No.1

imogasi

書式ーセルー表示形式ーユーザー定義
yyyy/mmの設定で済むのではないですか。
>ご存知のかた、ご教授どころじゃない、なぜこんな質問が出るのか、理解に苦しむ。
これだけ長い説明があるということは、小生のカン違いかな。
セルに入っているのは、日付けシリアル値であるのは当然として、月末日が、入ってなくても、途中日でも、書式設定yyyy/mmで年と月をそのセルに表示しますよ。

お礼

お蔭様で解決いたしました。
ありがとうございました。