あるセルにデータが入力された日を表示

質問

Ａ列(A1)のセルにデータが入った場合、Ｄ列(D1)にそのセルに
データが入力された日付を表示させたいのですが、どのように
やったらいいでしょうか？TODAY関数を使うと毎回更新されて
しまいます。

ＴＥＸＴ関数+ＴＯＤＡＹ関数で出来るかな？と思ったのですが、
=TODAY()を使うとセルに入力された日でなくて、ファイルを開いた
日付に毎回更新されてしまいます。

Ａ列のセルにデータが入った時にＤ列にその入力日を表示させたい
のです。こういう事は簡単に関数を使って出来ませんか？わかる方
がいれば教えてください。

回答No.4

zap35 · ベストアンサー

＃０２です。
Ａ列の値が変わったらＤ列に日付を入力するようにしました。Ａ列の複数セルにいっぺんに入力する場合(Ctrl+Enterで入力)でも大丈夫です。
なおＡ列が空白になったらＤ列も空白にするようにしてあります

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r, rng As Range
On Error GoTo end0
　If TypeName(Target) = "Range" Then
　　Set rng = Intersect(Target, Columns(1))
　　If Not rng Is Nothing Then
　　　Application.EnableEvents = False
　　　For Each r In rng
　　　　If r.Value = "" Then
　　　　　r.Offset(0, 3).Value = ""
　　　　Else
　　　　　r.Offset(0, 3).Value = Date
　　　　End If
　　　Next r
　　End If
　End If
end0:
　Application.EnableEvents = True
End Sub

お礼

すぐ回答いただきまして、ありがとうございます。
上記のプログラムを入れましたら、自動に表示できるように
なりました。助かりました。

回答No.5

noname#176215

ANo.1の者です。

> 試してみましたが、時間が表示されてしまいます。
Timeのところを Dateにして下さい。

お礼

ありがとうございます。
Dateにしたら、日付が表示できるようになりましたが、
A列部分空欄した時にD列部分の日付が消えないところが
難点です。

もう１人の方のプログラムでは、A列を空欄にした場合、
日付のところも空欄になる為、そちらを使わせてもらう
事にしました。何度も回答ありがとうございました。

回答No.3

noname#176215

ANo.1の者です。

Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo xErr
If Target.Column = 1 And Target.Value <> "" Then
Target.Offset(0, 3).Value = Time
End If
xErr:
End Sub

でできると思います。

お礼

すぐに回答いただきまして、ありがとうございます。
試してみましたが、時間が表示されてしまいます。

回答No.2

zap35

質問にある処理を行いたいシートのシート名タブを右クリックし「コードの表示」を選択したときに表示されるVBE画面に、以下のマクロを貼り付けてください。VBE画面を閉じて、A1の値が変更されるとD1に今日の日付がセットされます

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$A$1" Then
　Range("D1").Value = Date
End If
End Sub

でも実際にはA1を空白に戻したらどうするかなど、処理上は色々と考えなくてはならないと思います。その気があるならVBAも勉強してみてください。

お礼

回答ありがとうございます。
質問の仕方が悪かったのかもしれませんが、Ａ列に
どんどんデータが入ってきて、そのＤ列にその入力日
を表示させたいのです。プログラムしてもらったもの
をコピーして、やってみたのですが、これはA1に限定
されてしまいますよね？１ヶ所の入力でしたら、自動
表示する必要がありませんが、件数が多い為、自動に
入力日を表示させたいのです。

回答No.1

noname#176215

この質問 本当に多いですね……

> こういう事は簡単に関数を使って出来ませんか？
できません。VBAになります。

挿入した日付の自動更新を中止するには
http://okwave.jp/qa953510.html

自動日付入力方法
http://okwave.jp/qa2289506.html

このあたりを参考にされてはいかがでしょう。

お礼

回答ありがとうございます。
書き込みしていただいた自動日付入力方法を使ってみて、うまく
日付表示が出来るようになりましたが、入力間違えをして、Ａ列～
Ｂ列（例えばA1:B4)を範囲選択して、deleteを押すと、Ｂ列～Ｄ列
(例えばB1:C4すべてのセル)にかけて、日付が表示されてしまうと
いうおかしな現象が見られます。何が原因でしょうか？

入力間違えで範囲選択をして、deleteをする時が多々ありますので、
このような現象が出てきてしまうのも困ります。アドバイスをお願い
します。