条件が複数のＳＵＭＩＦ関数について

質問

sum関数なので、合計欄のセルに
ex.=SUM(C1:C6)などと書くときに、
a列が"1"の場合かつb列が"zz"の場合の時の合計欄のセルに加算したい場合は
どうやって書けばいいでしょうか？ （zzは任意の文字）
__A B C
1 1 zz 100
2 0 zz 200
3 1 xx 300
4 0 yy 400
5 1 zz 500
6 0 zz 600

回答No.2

gra · ベストアンサー

=SUMPRODUCT((A1:A6=1)*(B1:B6="zz")*(C1:C6))
で計算できるはずです。

お礼

あんびりーばぁぼー。あっというまに出来てしまいました。
ありがとうございました。

回答No.5

uko

エクセルのツールにある「条件付き合計式」を利用する方法もあります。
結果的にやってることは配列数式の作成なんですが、
ウィザードに従って選択していくだけで、
複数の条件の合計を導くことが出来ます。

「条件付き合計式」の使用方法は、

◆まずはアドインの追加
「ツール」－「アドイン」を選択し、「条件付き合計式ウィザード」を追加します。これでこの機能が追加されます。

◆式の作成
「ツール」－「ウィザード」－「条件付き合計式」を選択

あとはウィザードに従って、データ範囲・条件・抽出セルを指定していくだけで、複数の条件を満たすセルの合計が出す式が任意のセルに作成できます。

1列目に列ラベルを追加する必要がありますが、今回の例だと、

{=SUM(IF($A$2:$A$7=A9,IF($B$2:$B$7=B9,$C$2:$C$7,0),0))}

という配列数式が作成されるはずです。
配列数式に慣れないうちはこの方法で十分事足りるかと思います。

お礼

アドインがインストールされていなかったのでインストールしてやってみます。
ありがとうございました。

回答No.4

wolv

=SUM((A1:A6=1)*(B1:B6="zz")*(C1:C6))
を配列数式として入力（Ctrl＋Shift＋Enterで入力）すればできるようです。

もちろん、graさんの式
　=SUMPRODUCT((A1:A6=1)*(B1:B6="zz")*(C1:C6))
でも、配列数式として入力すれば、計算されます。

お礼

Ctrl + Shift + Enter キーで入力なんて技があったんですね。
ありがとうございます。

回答No.3

wolv

配列数式を使うと一発でできるようですが、
私には、まだ能力不足ですので、別の方法を示します。

D1を「=IF(AND(A1=1,B1="zz"),C1,0)」とし、
D2以下にコピーする。すると、
=sum(d1:d6)
で求める合計が計算できます。

回答No.1

nek784

下記ＵＲＬの過去ログはEXCEL97ですが，SUMIFで複数条件の設定はできない
と思います。

参考URL：

http://oshiete1.goo.ne.jp/kotaeru.php3?q=209260