VBE でワイルドカード的にファイルを指定したい

質問

いつも拝見させていただいています。
VBE 初心者です。
ファイルを開くとき、ワイルドカードのような指定はできますか？

毎日アメリカのサーバからデータをＤＬする作業をしています。
データは自動的にテキスト(CSV）ファイルでこちらのローカルドライブに保存されます。
そこまではアメリカでのコントロールです。
そのCSV ファイルに付いている名前が、毎日ちがうので困っています。
ＤＬするプログラム名に番号が割り振られて保存されているのです。

例
R554211J1_PJPPM000_945844_PDF.csv
R554211J1_PJPPM000_944634_PDF.csv
R554211J1_PJPPM000_935448_PDF.csv

このファイルを開いて加工するのですが、VBE に記述するときはどうしたらいいですか？
くっついてくる番号は、予想できません。

Workbooks.Open FileName:="c:\R554211J1_PJPPM000_*.csv"

としてみたらやはりダメでした(x_x)短絡的?
MS-DOS のREN コマンドのようなのがあれば、楽なのですが……。
エクセルのバージョンは97 SR-2 です。
よろしくお願いします。

回答No.2

nishi6 · ベストアンサー

特定のフォルダに保存されたファイルを、無条件で全ファイル処理するのか、一部を選択するのかで違ってくると思われます。

○フォルダ内の全csvファイルを無条件で処理するのであれば、
　『FileChoose1』のようにDirを使って、ファイル名を特定できます。
　今はSheet1のA列に書き出しています。

○フォルダ内の指定したcsvファイルを処理するのであれば、
　『FileChoose2』のようにしてGetOpenFilenameで複数ファイルを指定し、ファイル名を特定できます。
　複数ファイルの指定は、ダイアログボックスの選択で、Shiftキー、Ctrlキーを使います。
　今はSheet1のB列に書き出しています。

標準モジュールに貼りつけます。（ファイル名特定方法のサンプル）
↓
Sub FileChoose1()
　　Dim myFolder 'フォルダ
　　Dim myFilename As String 'ファイル名
　　Dim rw As Long '行カウンタ

　　myFolder = "A:\TEST\" '例です

　　'DirでExcelBookを探す
　　myFilename = Dir(myFolder & "*.csv")
　　While myFilename <> ""
　　　　rw = rw + 1
　　　　Worksheets("Sheet1").Cells(rw, 1) = myFolder & myFilename
　　　　'myFolder & myFilenameが抽出されたファイル名の１つ
　　　　'***** 処理を書くこともできる **** Workbooks.Open FileName:= ・・・

　　　　'次のファイル
　　　　myFilename = Dir
　　Wend
End Sub

Sub FileChoose2()
　　Dim fileToOpen As Variant
　　Dim myFilter As String 'フィルタ
　　Dim myTitle As String 'タイトル
　　Dim rw As Long '行カウンタ

　　myFilter = "excle(*.csv),*.csv"
　　myTitle = "ファイルを指定します"

　　fileToOpen = Application.GetOpenFilename(Filefilter:=myFilter, _
　　　　　　　　　　　　　　　　　　　　　　 Title:=myTitle, MultiSelect:=True)
　　If IsArray(fileToOpen) = False Then
　　　　MsgBox "キャンセルされました"
　　Else
　　　　For rw = 1 To UBound(fileToOpen)
　　　　　　Worksheets("Sheet1").Cells(rw, 2) = fileToOpen(rw)
　　　　　　'fileToOpen(rw)が選択したファイル名の１つ
　　　　　　'***** 処理を書くこともできる **** Workbooks.Open FileName:= ・・・

　　　　Next
　　End If
End Sub

お礼

ありがとうございました！
こちらの説明が足りなかったのにもかかわらず、素晴らしいお答えをいただきました。
実はＤＬするＣＳＶファイルは３つあって、パターンは同じでした。
ので、教えていただいた事をヒントに自分で下記のように応用してみたところ、条件をクリアしながら順に開く事ができました。
ＤＩＲコマンドについては、わたしが持っている（初心者向きの）市販本にはありませんでした……そろそろ買い替え時ですね。
またよろしくお願いします。

Sub FileChoose1()
Dim myFolder 'フォルダ
Dim myFilename As String 'ファイル名
' Dim rw As Long '行カウンタ

myFolder = "D:\"

'DirでExcelBookを探す
myFilename = Dir(myFolder & "R554211J1_PJPPM000*.csv") 'zaiko
While myFilename <> ""
' rw = rw + 1
Workbooks.Open FileName:=myFolder & myFilename
' Worksheets("Sheet1").Cells(rw, 1) = myFolder & myFilename

myFilename = Dir

Wend
End Sub

回答No.1

misatoanna

姑息な手法として――
セルＡ1に文字列でＣＳＶファイルの番号だけ入力し、
Range("A1").Select
AA = ActiveCell
Workbooks.Open FileName:="C:\R554211J1_PJPPM000_" & AA & "_PDF.csv"
としてマクロを実行されたらいかがでしょうか。

補足

さっそくありがとうございます！
少し補足します。

私だけでなく、同僚も抵抗なく実行できるようにしておきたいので…。
とくに同僚は年配ですしパソコンアレルギーの気もあり（笑）、
提示したようなファイル名を見ただけで拒絶反応を起こし、さらに
そこから数字を手で抽出して…なんて言おうものなら、
「オレには出来ない！」
と拒絶されてしまうことが目に見えているのです(^^;

苦手なことを無理やりやらせるのも可哀想なので、可能な限りマクロ
実行ボタン１個でプログラムが走るようにしておきたいのです。
いろいろすみません。