別シートに罫線がひけない

質問

表題どおりなのですが、別シートに罫線がかけません。
例えばSheet1にあるボタンをクリックするとSheet2に罫線をかく。
（コードは下記参照）としたときにエラーが発生します。
「1004　Rangeメソッドは失敗しました。」

そのため「ActiveSheet.」をはずしてみると”Sheet1”に描画されてしまいます。
なにか宣言が必要なのでしょうか？

Private Sub CommandButton1_Click()
Worksheets("sheet2").Activate　'.Selectでも同じ
For i = 4 To Range("G30").Column
ActiveSheet.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThin
ActiveSheet.Range(Cells(4, i), Cells(30,i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End Sub

回答No.1

popesyu · ベストアンサー

おそらくシートモジュールにプログラムを書いてるんですよね？
その場合、特に指定せずにRangeやCellsを使うとそれはそのシートモジュールのWorksheetを参照することになるという決まりごとがあります。これが標準モジュールの方ならとくに指定が無ければActiveSheetとするという決まりごとがあります。
つまり下記の部分は
ActiveSheet.Range(Cells(4, i), Cells(30, i))
↓
ActiveSheet.Range(Worksheets("sheet1").Cells(4, i), Worksheets("sheet1").Cells(30, i))
という認識になっているので正常に動作しません。もしシートモジュールの方に書くなら下のように正確に指定する必要があります。
ActiveSheet.Range(ActiveSheet.Cells(4, i), ActiveSheet.Cells(30, i))

他の対策としては標準モジュールに書いたコードをCallで呼び出す方式にするという方法もあります。その場合だと「ActiveSheet」を省略しても正常に動作します。

お礼

お礼が遅くなってしまいました．
確かにシートモジュールに書いていました．
原因が分かりスッキリです．
ありがとうございました．

回答No.3

imogasi

＃１でご指摘の方法
Ｓｈｅｅｔのシートモジュール
Private Sub CommandButton1_Click()
Module1.aaa
End Sub
Ｍｏｄｕｌｅ１に
Public Sub aaa()
Worksheets("Sheet2").Activate '.Selectでも同じ
For i = 4 To Range("G30").Column
ActiveSheet.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThick
ActiveSheet.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next i
End Sub
でうまくいきました。
Ｐｒｉｖａｔｅ　でなくＰｕｂｌｉｃにすること。
ーーー
Sub test01()
Worksheets("sheet2").Activate '.Selectでも同じ
For i = 4 To Range("G30").Column
ActiveSheet.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThin
ActiveSheet.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End Sub
で実行してもエラー
ーー
Ｓｈｅｅｔ１のシートモジュール
Sub test01()
For i = 4 To Range("G30").Column
Worksheets("Sheet2").Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThin
Worksheets("Sheet2").Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End Sub
でもエラー
ーーー
Ｓｈｅｅｔ１のシートモジュール
Sub test01()
Worksheets("sheet2").Activate
For i = 4 To Range("G30").Column
Worksheets("Sheet2").Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThin
Worksheets("Sheet2").Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End Sub
を実行でもエラー
ーーー
Ｓｈｅｅｔ１のシートモジュール
Private Sub CommandButton1_Click()
Worksheets("sheet2").Activate
For i = 4 To Range("G30").Column
Worksheets("Sheet2").Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThin
Worksheets("Sheet2").Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End Sub
でもエラー
ーーー
Private Sub CommandButton1_Click()
Dim sh2 As Worksheet
Set sh2 = Worksheets("Sheet2")
sh2.Activate
For i = 4 To Range("G30").Column
sh2.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThin
sh2.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End Sub
もエラー
ーーー
Sub test01()
Dim sh2 As Worksheet
Set sh2 = Worksheets("Sheet2")
For i = 4 To sh2.Range("G30").Column
sh2.Range(sh2.Cells(4, i), sh2.Cells(30, i)).Borders(xlLeft).Weight = xlThin
sh2.Range(sh2.Cells(4, i), sh2.Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End Sub
はＯＫ
ーーーー
＃２のご回答
Private Sub CommandButton1_Click()
With Worksheets("sheet2")
For i = 4 To Range("G30").Column
.Range(.Cells(4, i), .Cells(30, i)).Borders(xlLeft).Weight = xlThick
.Range(.Cells(4, i), .Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next i
End With
End Sub
はＯＫ。
以上参考のため、報告します。
シートモジュールの中で、他のシートのあＡｃｔｉｖａｔｅ　はできないのかと思ったが、そうではなくＳｈ２．をＣｅｌｌ（）の前にまでつけていなかったのが原因。
他シートを参照するなら、Ｒａｎｇｅ、Ｃｅｌｌｓの前に、徹底して
Ｓｈ２．（またはＷｏｒｋｓｈｅｅｔｓ（”Ｓｈｅｅｔ２”）をつけないといけないということでした。
Range(Cells(4, i), Cells(30, i)).のＣｅｌｌにはつけるのを忘れやすいですね。私も失敗した例を思いがしました。

お礼

お礼が遅くなってしまいました．
まとめていただいてありがとうございます．
原因が分かりスッキリです．
ありがとうございました．

回答No.2

dsuekichi

> 「1004　Rangeメソッドは失敗しました。」
> ActiveSheet.Range(Cells(4, i), Cells(30, i)).Borders(xlLeft).Weight = xlThin

「ActiveSheet」が指し示すのが「Sheet2」で、
「Cells」が指し示すのが「Sheet1」だからではありませんか？

> ActiveSheet.Range(ActiveSheet.Cells(4, i), ActiveSheet.Cells(30, i)).Borders(xlLeft).Weight = xlThin

こうしてみるとか・・・

一般に、「Active～」とか「Select～」は、不正確（想定外のもの）になることがあるので、
できるだけ使わないほうが良いですよ。

例えば、
------------------------------------------------------------
With Worksheets("sheet2")
For i = 4 To Range("G30").Column
.Range(.Cells(4, i), .Cells(30, i)).Borders(xlLeft).Weight = xlThin
.Range(.Cells(4, i), .Cells(30, i)).Borders(xlLeft).LineStyle = xlContinuous
Next
End With
------------------------------------------------------------
こうして、明示的に「Worksheets("sheet2")」を指定したほうが確実です。

お礼

お礼が遅くなってしまいました．
確かにシートモジュールに書いていました．
原因が分かりスッキリです．
ありがとうございました．