Accessの検索フォーム作成で。

質問

Access2000です。

一覧テーブルは
・名前
・項目1
・評価1
・項目2
・評価2

となっていて、
山田太朗　　｜　タバコのポイ捨てはしない　　｜　5　｜　１０分前行動　｜　4　｜
前田前　　　｜　交通ルールを守る　　　　　　｜　5　｜　挨拶をする　　｜　4　｜
大坪拳　　　｜　１０分前行動　　　　　　　　｜　4　｜　挨拶をする　　｜　5　｜

のようになっています。

これをもとに「検索フォーム」をデザインフォームで、

名前 　　［　　　　　］
項目1　　［　　　　　］
項目2　　［　　　　　］
項目3　　［　　　　　］
と作成し、「検索」というボタンを押すと、「検索結果フォーム」に検索結果が出るようにしました。
検索ボタンは

Private Sub コマンド9_Click()

Dim SQL As String
Dim WhereCond As String
Dim condName As String
Dim condKoumoku1 As String
Dim condKoumoku2 As String
Dim condKoumoku3 As String

WhereCond = ""

'名前
If Me!名前.Value <> "" Then
condName = "(一覧.名前 like '*" & Me!名前.Value & "*')"
WhereCond = WhereCond & " and " & condName
End If

'項目1
If Me!項目1.Value <> "" Then
condKoumoku1 = "(一覧.項目1 like '*" & Me!項目1.Value & "*')"
WhereCond = WhereCond & " and " & condKoumoku1
End If

：

WhereCond = Mid(WhereCond, 6)

DoCmd.OpenForm "検索結果フォーム", acNormal, , WhereCond

End Sub

となっています。

そこで、検索フォームで
項目に検索値を入れた場合、一覧の項目すべての中から検索できるようにするにはどうしたらいいのでしょうか？

また、今の状態ですとand検索ですが、or検索するにはどのようにしたらいいでしょうか？

回答No.4

maruru01 · ベストアンサー

こんなところでしょうか。
今現在の状態から、

変数宣言を追加します
Dim tempCond As String

「'項目1」の行の直前に追加します
tempCond = ""

項目1～3を以下のように変更します
'項目1
If Me!項目1.Value <> "" Then
　　condKoumoku1 = "(一覧.項目1 like '*" & Me!項目1.Value & "*')"
　　condKoumoku2 = "(一覧.項目2 like '*" & Me!項目1.Value & "*')"
　　condKoumoku3 = "(一覧.項目3 like '*" & Me!項目1.Value & "*')"
　　tempCond = tempCond & " OR (" & condKoumoku1 & " OR " & condKoumoku2 & " OR " & condKoumoku3 & ")"
End If

'項目2
If Me!項目2.Value <> "" Then
　　condKoumoku1 = "(一覧.項目1 like '*" & Me!項目2.Value & "*')"
　　condKoumoku2 = "(一覧.項目2 like '*" & Me!項目2.Value & "*')"
　　condKoumoku3 = "(一覧.項目3 like '*" & Me!項目2.Value & "*')"
　　tempCond = tempCond & " OR (" & condKoumoku1 & " OR " & condKoumoku2 & " OR " & condKoumoku3 & ")"
End If

'項目3
If Me!項目3.Value <> "" Then
　　condKoumoku1 = "(一覧.項目1 like '*" & Me!項目3.Value & "*')"
　　condKoumoku2 = "(一覧.項目2 like '*" & Me!項目3.Value & "*')"
　　condKoumoku3 = "(一覧.項目3 like '*" & Me!項目3.Value & "*')"
　　tempCond = tempCond & " OR (" & condKoumoku1 & " OR " & condKoumoku2 & " OR " & condKoumoku3 & ")"
End If

ここに以下の行を追加します
If tempCond <> "" then
　　tempCond = Mid(tempCond, 5)
　　WhereCond = WhereCond & tempOper & "(" & tempCond & ")"
End If

あとは同じ
これも試してないので分からないですけど。
では。

お礼

できました！
これです！
やっと完成しました。
今回も長々とありがとうございました。
また何かありましたら宜しくお願いします。

本当にありがとうございました。

回答No.3

maruru01

すみません、また間違えました。
下の方のMid関数でANDの場合は前の5文字を削除すればいいですが、ORの場合は4文字だけ削除しないといけません。
以下のように変更して下さい。

変数宣言を追加します
Dim strCount As Long　　'演算子の文字数

Select Caseの部分を以下のように変更します
Select Case Me!fraOper.value
　　Case 1　　'AND検索
　　　　tempOper = " AND "　　'前後の半角スペースを忘れずに
　　　　strCount = 5
　　Case 2　　'OR検索
　　　　tempOper = " OR "　　'前後の半角スペースを忘れずに
　　　　strCount = 4
End Select

下の方のMid関数の部分を以下のように変更します
WhereCond = Mid(WhereCond, strCount + 1)

それから検索方法ですが、KODAMARさんがどういうパターンの検索をしたいのかを明確にして下さい。
例えば、項目は3つありますが、項目1（または2、3）だけで検索したいことがあるのか、項目1～3のどれかに当てはまるもの（つまり最初の質問の1つ目）だけでいいのか。
さらに、名前と項目が両方とも当てはまるものを検索したいのか、また名前か項目のどちらかにあてはまればいいのか。
それぞれANDとORで必要なパターンを教えて下さい。
では。

お礼

はい、できました！ありがとうございます！！

＞それから検索方法ですが、KODAMARさんがどういうパターンの検索をしたいのかを明確にして下さい。

一覧テーブルの中身を
[T1]名前
[T2]項目1
[T3]項目2
[T4]項目3
とし、検索フォームの中身を
[F1]名前
[F2]項目1
[F3]項目2
[F4]項目3
とします。

1.[F1]山田　AND　[F2]10分前
とした場合は、[T1]に山田があり、[F2]～[F4]に10分前があるものを検索。
2.[F1]山田　AND　[F2]10分前　[F3]ポイ
とした場合は、[T1]に山田があり、[F2]～[F4]に10分前かポイがあるもの。

というようなことがしたいのです。
名前と項目の検索方法は「AND」か「OR」で選べるようにし、
項目同士は基本的にORでどこに入れても[T2]～[T4]から検索するようにしたいのです。

説明が下手ですがおわかりいただけたでしょうか？？

回答No.2

maruru01

ご苦労様です。

1つ目と2つ目の質問がごちゃごちゃになっているようです。
私の書いた1つ目は、検索フォームに[名前]と[項目]の2つしかない場合です。
つまり、1つの[項目]に対するキーワードで項目1～3の全部を検索するやり方です。
一方、2つ目は検索フォームに[名前]、[項目1]、[項目2]、[項目3]と入力欄があり、ANDなら4つ全ての条件を満たし、ORならどれかの条件を満たすというやり方です。
したがって、項目1～3を分ける（つまり1つ目の質問内容は無視する）場合は、元のKODAMARさんのコードの「'名前」の行より後ろを、ほとんどそのまま使用して下さい。
そして、名前、項目1～3の
WhereCond = ・・・・・
の行を、それぞれ
WhereCond = WhereCond & tempOper & condName
WhereCond = WhereCond & tempOper & condKoumoku1
WhereCond = WhereCond & tempOper & condKoumoku2
WhereCond = WhereCond & tempOper & condKoumoku3
に替えるだけです。
では。

お礼

ありがとうございます。

今現在コードは
------------------------------
Private Sub コマンド9_Click()

Dim SQL As String
Dim WhereCond As String
Dim condName As String
Dim condKoumoku1 As String
Dim condKoumoku2 As String
Dim condKoumoku3 As String
Dim tempOper As String '演算子

WhereCond = "" '変数の初期化。本当はいらないけど明示的に。

Select Case Me!fraOper.Value
Case 1 'AND検索
tempOper = " AND " '前後の半角スペースを忘れずに
Case 2 'OR検索
tempOper = " OR " '前後の半角スペースを忘れずに
End Select

'名前　　（入力欄がテキストボックスとする）
If Me!名前.Value <> "" Then
condName = "(一覧.名前 like '*" & Me!名前.Value & "*')"
WhereCond = WhereCond & tempOper & condName
End If

'項目1
If Me!項目1.Value <> "" Then
condKoumoku1 = "(一覧.項目1 like '*" & Me!項目1.Value & "*')"
WhereCond = WhereCond & tempOper & condKoumoku1
End If

'項目2
If Me!項目2.Value <> "" Then
condKoumoku2 = "(一覧.項目2 like '*" & Me!項目2.Value & "*')"
WhereCond = WhereCond & tempOper & condKoumoku2
End If

'項目3
If Me!項目3.Value <> "" Then
condKoumoku3 = "(一覧.項目3 like '*" & Me!項目3.Value & "*')"
WhereCond = WhereCond & tempOper & condKoumoku3
End If

WhereCond = Mid(WhereCond, 6)

DoCmd.OpenForm "検索結果フォーム", acNormal, , WhereCond

End Sub
------------------------------
となっています。

andを選択して検索をすると大丈夫なのですが、
orを選択するとエラーが出てしまいます。

何がだめなのでしょうか？

またこの方法だと、

名前が「山田」で
項目のどこかに「10分」と入る
という検索はできなくなるのでしょうか？

併せて宜しくお願いします。

回答No.1

maruru01

こんにちは。maruru01です。

まず最初の質問から。
＞項目に検索値を入れた場合、一覧の項目すべての中から検索できるようにするにはどうしたらいいのでしょうか？
これは、現在検索フォームで、[項目1]、[項目2]、[項目3]となっているのを[項目]1つだけにして、3つの項目のどれかに入っているものを抽出する、ということでいいですね。
項目のところだけ変更します。

'項目
If Me!項目.Value <> "" Then
　　condKoumoku1 = "(一覧.項目1 like '*" & Me!項目.Value & "*')"
　　condKoumoku2 = "(一覧.項目2 like '*" & Me!項目.Value & "*')"
　　condKoumoku3 = "(一覧.項目3 like '*" & Me!項目.Value & "*')"
　　WhereCond = WhereCond & " AND (" & condKoumoku1 & " OR " & condKoumoku2 & " OR " & condKoumoku3 & ")"
End If

次にOR検索ですが。
検索フォームに、オプショングループ（fraOper）と2つのオプションボタン（optAND、optOR）をおきます。（コントロール名は任意につけて下さい）
オプションボタンはグループ化し、オプションボタンのオプション値が1の方のキャプションを"AND"、同じく2の方を"OR"とします。

変数宣言を追加します。
Dim tempOper As String　　'演算子

WhereCond = "" のすぐ後ろに以下のコードを追加します。
Select Case Me!fraOper.value
　　Case 1　　'AND検索
　　　　tempOper = " AND "　　'前後の半角スペースを忘れずに
　　Case 2　　'OR検索
　　　　tempOper = " OR "　　'前後の半角スペースを忘れずに
End Select

各名前、項目のWhereCond = の式を以下のコードに変更します。
WhereCond = WhereCond & tempOper & condName
WhereCond = WhereCond & tempOper & condKoumoku1
・・・・・
要は、WhereCondの直後の" AND "をtempOperに替えるのです。

がんばって下さい。
では。

お礼

回答ありがとうございます。
以前もお世話になったKODAMARです。

早速試しました！
1つ目の方は無事うまくいきました。
が！2つ目がエラーになってしまうのです。

クエリ式がない・・・と。

実際のコードは
------------------------------
Private Sub コマンド9_Click()

Dim SQL As String
Dim WhereCond As String
Dim condName As String
Dim condKoumoku1 As String
Dim condKoumoku2 As String
Dim condKoumoku3 As String
Dim tempOper As String '演算子

WhereCond = "" '変数の初期化。本当はいらないけど明示的に。

Select Case Me!fraOper.Value
Case 1 'AND検索
tempOper = " AND " '前後の半角スペースを忘れずに
Case 2 'OR検索
tempOper = " OR " '前後の半角スペースを忘れずに
End Select

'名前　　（入力欄がテキストボックスとする）
If Me!名前.Value <> "" Then
condName = "(一覧.名前 like '*" & Me!名前.Value & "*')"
WhereCond = WhereCond & tempOper & condName
End If

'項目1
If Me!項目1.Value <> "" Then
condKoumoku1 = "(一覧.項目1 like '*" & Me!項目1.Value & "*')"
condKoumoku2 = "(一覧.項目2 like '*" & Me!項目1.Value & "*')"
condKoumoku3 = "(一覧.項目3 like '*" & Me!項目1.Value & "*')"
WhereCond = WhereCond & " tempOper (" & condKoumoku1 & " OR " & condKoumoku2 & " OR " & condKoumoku3 & ")"
End If

'項目2
If Me!項目1.Value <> "" Then
condKoumoku1 = "(一覧.項目1 like '*" & Me!項目2.Value & "*')"
condKoumoku2 = "(一覧.項目2 like '*" & Me!項目2.Value & "*')"
condKoumoku3 = "(一覧.項目3 like '*" & Me!項目2.Value & "*')"
WhereCond = WhereCond & " tempOper (" & condKoumoku1 & " OR " & condKoumoku2 & " OR " & condKoumoku3 & ")"
End If

'項目3
If Me!項目1.Value <> "" Then
condKoumoku1 = "(一覧.項目1 like '*" & Me!項目3.Value & "*')"
condKoumoku2 = "(一覧.項目2 like '*" & Me!項目3.Value & "*')"
condKoumoku3 = "(一覧.項目3 like '*" & Me!項目3.Value & "*')"
WhereCond = WhereCond & " tempOper (" & condKoumoku1 & " OR " & condKoumoku2 & " OR " & condKoumoku3 & ")"
End If

WhereCond = Mid(WhereCond, 6)

DoCmd.OpenForm "検索結果フォーム", acNormal, , WhereCond

End Sub
------------------------------
となっています。

どこが違うのでしょうか？

毎回申し訳ありませんが、宜しくお願いします。