iniについて

質問

SliderをMAX100、MIN-100の範囲にします。
初期設定？でiniを使って３５のところから起動時始めたいのですがiniの使い方が全くわかりません＞＜
教えてくださいお願いしますm(__)m

回答No.2

k-marumich

lark198220さん、はじめまして。

開発環境と実行環境が書かれていないので、
INIファイルを使用する環境を以下の環境と
想定して回答します。

開発環境：VB6.0
実行環境：Windows 2000/XP

INIファイルの読み書きについては、検索サイトで
検索すると山ほどヒットします。

1. 標準モジュールシートにAPIの宣言を追加します。

'INIファイルより読み込み
Declare Function GetPrivateProfileString Lib "Kernel32" _
Alias "GetPrivateProfileStringA" _
(ByVal lpApplicationName As String, _
ByVal lpKeyName As Any, _
ByVal lpDefault As String, _
ByVal lpReturnedString As String, _
ByVal nSize As Long, _
ByVal lpFileName As String) As Long

'INIファイルに書き込み
Declare Function WritePrivateProfileString Lib "Kernel32" _
Alias "WritePrivateProfileStringA" _
(ByVal lpApplicationName As String, _
ByVal lpKeyName As Any, _
ByVal lpString As Any, _
ByVal lpFileName As String) As Long

2. 標準モジュールシートにINIファイルの読み込み、
書き込み用の共通モジュール(プロシージャ)を定義
します。

'INIファイルからデータを取得する
Function getIniData(iniFile As String, section As String, key As String)
Dim iniValue As String * 1024
Dim lngStrLength As Long
Dim lngResult As Long

lngStrLength = Len(iniValue)
lngResult = GetPrivateProfileString( section, key, "", iniValue, 1024, iniFile)

getIniData = left(iniValue, InStr(iniValue, Chr(0)) - 1)

End Function

'INIファイルにデータを書き出す
Sub putIniData(iniFile As String, section As String, key As String, str As String)
Dim ret As Long

ret = WritePrivateProfileString( section, key, str, iniFile)

End Sub

3. 任意のシートから上記のモジュール(プロシージャ)
を呼び出します。

Sub Test()
Dim iniPath as String
Dim wkStr as String
Dim sliderVal as Integer

'適当な既定値を設定
sliderVal = 50

iniPath = App.Path & "\" & "MyIniFile.ini"

If Dir(iniPath) <> "" Then
'INIファイルからデータを取得
wkStr = getIniData(iniPath, "SYSTEM", "SliderVal")

If wkStr <> "" And Numeric(wkStr) Then
'INIファイルから取得した値を数値に変換
sliderVal = CInt(wkStr)
End If

Else

'INIファイルに書き出す
putIniData iniPath, "SYSTEM", "SliderVal", CStr(sliderVal)

End If

End Sub

--------------------------------------------------------
INIファイルの例(MyIniFile.ini)
--------------------------------------------------------
[SYSTEM]
SliderVal=35

--------------------------------------------------------

参考URL：

http://www.geocities.co.jp/SiliconValley/4805/vbtips/vbtips001.htm

回答No.1

kiki_s

初期設定という事ですが、
なぜiniを使って指定する必要があるのでしょうか？
通常のファイルでは駄目なのですか？
適当な名前のファイルを環境設定として作る方が楽だと思いますよ。