エクセルで

質問

以下のようなシートがあります。

Ａ　　　Ｂ　　　Ｃ
01　　　小林　　(1)
02　　　佐藤　　(2)
03　　　田中　　(1)
04　　　本多　　(1)
05　　　近藤　　(2)

Ａ列⇒個人別番号（上から下に大きな番号になる）
Ｂ列⇒名前
Ｃ列⇒グループ

以上のシートをもとに、別のシートに、『グループ(1)』と『グループ(2)』の名簿を作成したいのです。名簿のイメージは以下の通りです。

Ａ列　　　　　　Ｂ列
グループ(1)　　　グループ(2)
小林　　　　　　佐藤
田中　　　　　　近藤
本多

名前は、個人番号の小さい順番で並べていきたいのです。理想は関数で作成したいと考えています。宜しくお願い致します。

回答No.6

odessa7

この場を借りて一言申し上げたいのですが・・。

　ご質問者様は、ご回答者の方が提示された方法をちゃんとお試しになられたのでしょうか？

　＃２の方へ補足を書いていらっしゃいますが、その時点では皆さんの回答を目にされたのでしょう？皆さんが善意で解決案を提示されているのに、それを無視しておかれると言うのは如何なものでしょうか。

　試してみて上手くいったのか、そうでないのか、上手くいかなかったのであれば、どこがどうなったのか、どうしたいのか、具体的にお書きになればさらなる解決策もご提示できるかもしれませんが、それをしないでおいて＃２の方に「ＶＢＡの方法を提示しろ」とは、あまりに安直な要求ではないでしょうか？

　あなたがエクセルで関数を組まれたご経験があるなら理解いただけると思いますが、これだけの回答を提示するには、私を含め、皆さんそれなりに時間を費やしてこられたわけです。

　ここが無料で回答を求めることの出来る場であることを、どうか良くご理解いただきたく、あえて苦言を呈した次第です。では、誠意あるご対応のほどよろしくお願いいたします。

お礼

ご指摘ありがとうございます。
もちろん、すべての方法を試させていただいております。宜しくお願い致します。

回答No.5

odessa7

なるべく簡単な方法で・・。

　まず下図のように作業列を挿入します。ちなみにA列は不要になるので、削除してもかまいません。またこのシートのシート名を「データ」と仮定します。

Ａ　Ｂ　Ｃ　Ｄ　　　Ｅ
01　　　　小林　　(1)
02　　　　佐藤　　(2)
03　　　　田中　　(1)

　Ｂ1セルに下記の関数を入れ、下までコピー。
=IF(E1="(1)",ROW(A1),"")

　Ｃ1セルに下記の関数を入れ、下までコピー。
=IF(E1="(2)",ROW(A1),"")

　表示させたい別シートを下図とすると
　　　Ａ　　　　　　　　Ｂ
01　グループ(1)　　グループ(2)　　
02　小林　　　　　　佐藤　　　　　　
03　田中　　　　　　近藤　　　　

　Ａ2セルに下記の式をいれ下までコピー。
=VLOOKUP(SMALL(データ!$B$1:$B$5,ROW(A2)-1),データ!$B$1:$D$5,3,FALSE)

　Ｂ2セルに下記の式をいれ下までコピー。
=VLOOKUP(SMALL(データ!$C$1:$C$5,ROW(A2)-1),データ!$C$1:$D$5,2,FALSE)

　上記の関数では、例えばグループ(1)該当者が10人だと、関数を11個以上貼り付けた時にエラーが出ます。その場合は、ISERROR関数などで下記のように対処してください。

　A2セルに下記の式。
=IF(ISERROR(SMALL(データ!$B$1:$B$5,ROW(A2)-1)),"該当なし",VLOOKUP(SMALL(データ!$B$1:$B$5,ROW(A2)-1),データ!$B$1:$D$5,3,FALSE))
　これを下までコピー。

お礼

ありがとうございます。
こういう方法の発想はありませんでした。
勉強になります！

回答No.4

zenjee

実際はC列を基準にソートしてコピー&ペーストした方が遙かに簡単なのでしょうが、どうしても関数でやりたいということであれば、このような式の立て方もあるという程度の意味で、私なりの方法を投稿しますので、答の良否は別として気が向いたらたら参考にしてください。。
Sheet1が次のとおりとします。

1 小林　(1)
2 佐藤　(2)
3 田中　(1)
4 本多　(1)
5 近藤　(2)
6 山本 (2)
7 鈴木 (1)
8 大野 (2)

Sheet2のA～E列を作業列とし、最終の答をF、G列に出すことにします。
各列の1行目は見出し行とし、計算範囲は15行までとしておきます。
A列にはA2：A15まで一連番号（1～14）を入力します。
B2からG2まで各セルの入力式を次のとおりとします。
「C2」　 =IF(Sheet1!$C1="(1)",Sheet1!$B1,"")
「E2」　 =IF(Sheet1!$C1="(2)",Sheet1!$B1,"")
「B2」　 =IF(C2="","",COUNTA(C$2:C2)-COUNTIF(C$2:C2,""))
「D2」　　=IF(E2="","",COUNTA(E$2:E2)-COUNTIF(E$2:E2,""))
「F2」　 =IF(ISNA(MATCH($A2,B:B,0)),"",VLOOKUP($A2,B$2:C$15,2,FALSE))
「G2」　　=IF(ISNA(MATCH($A2,D:D,0)),"",VLOOKUP($A2,D$2:E$15,2,FALSE))
以上の後、「B2:G2」を「B15:G15」までコピーします。
この計算式のプロセスは、Sheet1から一旦(1)(2)のグループ別に、Sheet2のC、E列に名前を取り出し、そのままでは空白行が出来るので、A、B、Dに作業列を設け、最終的にF、G列に空白行を詰めてグループ別に名前を並べるということです。
一見簡単な問題のように見えても、関数でエラー値を出さずに空白行を詰めて並べ直すということは決して容易でなく、もしグループが(3)(4)…と増えていけば作業列や計算式もそれだけ増え、更に複雑化するでしょう。

回答No.3

noname#192382

データ→フィルタ→オートフィルタ
グループの列で（1）または（2）を抽出条件としてフィルターをかけると望みのデータが得られますからそれをコピーして別シートにはりつければ望みのデータが簡単に得られます。

回答No.2

imogasi

＞理想は関数で作成したいと・・
このタイプの問題は関数では難しいと思います。
関数では、抜き出しが結構難しい上に、横に並べて列挙して行くのも難しいです。
何とか近いものを出しますが、これ以上のものは難しいかもしれない。本当は、VBAでやりたい。
データ例　Sheet1の　A2:C10
A列　　B列　　C列　　　E列　F列　G列
1 小林 a 1 1 101
2 佐藤 b 2 1 201
3 田中 a 1 2 102
4 本多 c 3 1 301
5 近藤 b 2 2 202
6 鈴木 d 4 1 401
7 大島 d 4 2 402
8 植田 a 1 3 103
9 磐田 b 2 3 203
C列をa,b,c・・・にしたのは一般性を持たせるためです。
E2に=IF(COUNTIF($C$2:C2,C2)=1,MAX($E$1:E1)+1,VLOOKUP(C2,$C$2:$E$10,3,FALSE))
と入れてE10まで式を複写。
F2に=COUNTIF($C$2:C2,C2)と入れてF10まで式を複写。
G2に=E2*100+F2と入れて、F10まで式を複写。（１００を掛けているのはa,b,c・・などが９９人以下と仮定している。１０００掛ける必要がある場合も考えられる。）
なおF列は、E,F列の関数式を組み込んでG列だけの１式にすることはできるが、理解のため、あえて分けているもの。
E,F,G列の結果は上記の通り。
ーーーー
Sheet2に行って
A2に=INDEX(Sheet1!$A$2:$C$10,MATCH(COLUMN()*100+ROW()-1,Sheet1!$G$2:$G$10,0),2)と入れて式をA3まで複写する。
A2:A4を範囲指定し＋ハンドルを出して、D2:D4まで引っ張る。
結果は
小林 佐藤 本多 鈴木
田中 近藤 #N/A 大島
植田 磐田 #N/A #N/A
私の手抜きで、回答はここまでにします。＃N/Aが出ていますが
ISERROR関数をかぶせて、エラーが出ないようにするのは、やってみて
ください。あまりに式が長くなって、難しそうに見えるようになるので、載せることをあきらめています。
難しいといった意味がお分かりでしょうか。
これは私が自称imogasi方式といっているやり方の応用版です。
さて、もっと簡単な回答が出ますでしょうか。

補足

ご返答ありがとうございます。助かりますm(_ _)m
もし、ＶＢＡを使用した場合はどのようになりますか。

回答No.1

noname#32989

VLOOKUPがいいのではないでしょうか？

SUM　IFでもできそうには思いますが・・・