【Excel】 印をした行の内容を別のシートに表示します。

質問

こんにちは

───────────────────
sheet1

　A　　B　　　　　　 C　　　　 D
1　　　あいうえお　　東京都　　1000
2　　　かきくけこ　　大阪府　　2000
3 ● 　さしすせそ　　愛知県　　2500
4　　　たちつてと　　福岡県　　1800
5　　　・　　　　　　・　　　　・　
6　　　・　　　　　　・　　　　・　
7　　　・　　　　　　・　　　　・　
8　　　・　　　　　　・　　　　・　

───────────────────
sheet2

　A　　　　　　B　　　　 C
1 さしすせそ　 愛知県　　2500

───────────────────

上記のようにsheet1にリストがあり、そのA列の中に●で印をすると
sheet2にその●をした行の内容が表示されるようにしたいのですが、
sheet2 A1 B1 C1 の式を教えてください。
A列の●は一箇所です。

回答No.1

moon00 · ベストアンサー

MATCH関数とOFFSET関数の組み合わせでできます。
sheet2で
A1に
=OFFSET(Sheet1!$A$1,MATCH("●",Sheet1!$A:$A,0)-1,1,1,1)
B1に
=OFFSET(Sheet1!$A$1,MATCH("●",Sheet1!$A:$A,0)-1,2,1,1)
C1に
=OFFSET(Sheet1!$A$1,MATCH("●",Sheet1!$A:$A,0)-1,3,1,1)

それぞれMATCH関数で「●」が何行目にあるか探して、
そこからそれぞれの項目分、オフセットしています。

回答No.4

maruru01

No.3です。

気づくのが遅れましたが、No.2の方と被ってしまいましたね。
ただ、ちょっと気になる点があります。
質問者が誤解する可能性がありますので、あえて指摘させてもらいます。
No.2の回答の中で、
>ちなみに最後の0はこの場合は省いても特に問題はないかと思います。
とありますが、VLOOKUPの用法上最後の「0」は省略すべきではないと思います。
VLOOKUP関数の最後の（第4）引数は検索の型で、「FALSE」（「0」も「FALSE」と見なされます）を指定すると、完全一致検索になり、「TRUE」（または「1」）を指定するか省略すると完全一致しない場合に別の値を検索してしまいます。
それも、データを検索対象列で並べ替えておかないと意図しない値を検索してしまう可能性があります。
ただし、今回の質問の場合は、ただ1箇所に「●」があるだけなので、問題は生じませんが。
今後別の状況でVLOOKUP関数を使用する場合があると、思わぬ結果になることがあるので、あえて指摘させていただきました。
あと、「0」は「FALSE」と見なされるのですが、VLOOKUP関数の第4引数は、「TRUE」と「FALSE」の2種類の指定で、間違えやすいのがMATCH関数の第3引数が「-1」「0」「1」の3種類の指定することと混同してしまうことです。
まあ、結果オーライと言えばそれまでですが。

回答No.3

maruru01

こんにちは。maruru01です。

別の方法です。
Sheet2のA1に、

=IF(COUNTIF(Sheet1!$A:$A,"●"),VLOOKUP("●",Sheet1!$A:$D,COLUMN(B1),FALSE),"")

と入力して、B1:C1にコピーします。

回答No.2

yama_x

これでもいけるかと。
Sheet2のA1
　=vlookup("●",sheet1!A:D,2,0)
Sheet2のB1
　=vlookup("●",sheet1!A:D,3,0)
以降、右から２番目の部分が、4、5、となります。
この数値は指定した範囲(A:D)の何列目かを意味します。

ちなみに最後の0はこの場合は省いても特に問題はないかと思います。