マクロを使ってコメントを大量に挿入したい。Excel2002

質問

都市名が北から並んでいる表があり、各都市名にカーソルを合わせると各都市に応じたコメントが表示されるようにしたいです。表示させたいコメントの種類が５種類あり、塗りつぶし効果でコメントの背景に画像を表示させたりと、１つのコメントを作るのにちょっと手間がかかります。
少しでも手早くと思い、マクロの記録で手順を５パターン登録して、マクロの実行でコメントを表示させたいと考えております。でサンプルをひとつ作成し実行したのですがエラーになってしまいます。

（１）End with以降のselection.shaperange.fill～以降が駄目みたいで「オブジェクトはこのプロパティーまたはメソッドをサポートしていません」とエラーメッセージが表示されます。何がいけないのでしょうか？

（２）G62のセルにコメントを挿入したいときのサンプルなんですが、G62だけじゃなくてどこのセルにでも対応できるようにしたいんですがどう書き直せば良いのでしょうか？

800字以内との規制があるみたいで関係ないと思われるエラー以降の部分を削除させて頂きました。何卒宜しくお願いいたします。

Sub Macro1()
' Macro1 Macro
' Range("G62").AddComment
Range("G62").Comment.Visible = False
Range("G62").Comment.Text Text:=""
With Selection.Font
.Name = "ＭＳ Ｐゴシック"
.FontStyle = "太字"
.Size = 9
.Strikethrough = False
.Superscript = False
.Subscript = False
.OutlineFont = False
.Shadow = False
.Underline = xlUnderlineStyleNone
.ColorIndex = xlAutomatic
End With
Selection.ShapeRange.Fill.Transparency = 0#
Selection.ShapeRange.Line.Weight = 0.75
Selection.ShapeRange.Line.DashStyle =

　　中略

　End Sub

回答No.4

misatoanna · ベストアンサー

＃2　misatoanna　です。

> コードの6行目の "C:\MyFiles\Photos\Cats.jpg"

この　"　"　内に、塗りつぶし効果で使う画像ファイルの実際のフルパスを書き込め
ば表示されるはずなのですが。

次は、必要ないでしょうが、ついでです。
２枚目のシートの指定にもとづいて、１枚目のシートの各セルにコメントを挿入
する処理です。
２枚目のシートには、
　　　　A　　　　　B　　　　　C
　　1　\My Documents\GraphicData\Pic
　　2　B6　　秘密！　　　　　Photo004.jpg
　　3　F2　　大きすぎ　　　　Masao_2.jpg
　　4　C12　 メチャクチャ　　Xmas2004.jpg
　　5
のように、２行目以降のＡ列にコメントを挿入するセル番地、Ｂ列にコメント文、
Ｃ列には背景に使用する画像ファイルのフルパスが入力されているとします。
セルA1は、画像ファイルが格納されているフォルダのフルパスです。
'
Sub CrtCmmt()
　　Dim i, myPath, myCL
　　Sheets(1).Select
　　myPath = Sheets(2).Range("A1").Value & "\"
Pfm:
　　i = i + 1
　　myCL = Sheets(2).Cells(i + 1, 1).Value
　　If myCL = "" Then Exit Sub
　　Range(myCL).Select
　　Selection.AddComment
　　Selection.Comment.Visible = True
　　Selection.Comment.Text Text:=Sheets(2).Cells(i + 1, 2).Value
　　Selection.Comment.Shape.Select True
　　Selection.ShapeRange.Fill.UserPicture myPath & Sheets(2).Cells(i + 1, 3).Value
　　ActiveCell.Comment.Visible = False
　　GoTo Pfm
End Sub

お礼

本当にありがとうございます。
最初にご回答頂いたものでもちゃんと画像が背景に挿入されました。フルパスの前のアンダーバーが抜けておりました。
今回のものはさらに便利で、画像もコメントの中に入れる文章も簡単に表示させることができました。
これで大丈夫です。
重ねてのご回答、本当にありがとうございます。

回答No.3

Wendy02

こんにちは。
私も考えてみました。

＞表示させたいコメントの種類が５種類あり、塗りつぶし効果でコメントの背景に画像を表示させたりと、１つのコメントを作るのにちょっと手間がかかります。
コメントが5種類あるとしたら、以下のように(,)コンマ区切りにして、総合コメントに書いておきます。

以下は、ActiveCell に入れられるようになっていますが、UserFormのモードレスモードなどのほうが、セルを自由に選べて便利です。Application.Input でも出来ないことはありませんが、勝手が悪いのです。

後は工夫してください。

Const myComment As String = "本日は晴天なり,本日は、曇天なり,本日は、雨天なり,本日は、風強し"
Sub CellCommentIn()
　Dim ret As Variant, i As Long
　Dim msg As String, myComments As Variant
　myComments = Split(myComment, ",")
　For i = LBound(myComments) To UBound(myComments)
　　msg = msg & i + 1 & "." & myComments(i) & vbCr
　Next
　ret = Application.InputBox(msg & "コメントの数字を選んでください", Type:=2)
　If VarType(ret) = vbBoolean Or ret = "" Then Exit Sub
　With ActiveCell
　　'もし、コメントがあれば最初に削除する
　　If Not .Comment Is Nothing Then
　　　.Comment.Delete
　　End If
　　.AddComment
　　.Comment.Visible = False
　　.Comment.Text Text:=myComments(ret - 1)
　　With .Comment.Shape

　　'ここは、特別な設定しなければ、要らないかもしれない
　　　With .TextFrame.Characters.Font
　　　　.Name = "ＭＳ Ｐゴシック"
　　　　.FontStyle = "太字"
　　　　.Size = 9
　　　　.ColorIndex = xlAutomatic
　　　End With
　　　.Fill.Transparency = 0#
　　　.Line.Weight = 0.75
　　'中略
　　End With
　End With
End Sub

お礼

早速のご回答にもかかわらず、色々と試行させて頂いておりまして、御礼が遅くなり失礼致しました。
内容は完璧で、とても簡単に数種類のコメントを挿入することができました。こんな風にコメントが選択できる方法があるんですね。とっても勉強になりました。
Wendy02さんには以前にも違う質問でご教授頂いておりまして、本当にありがとうございます。
お忙しいところのご回答に心より感謝申し上げます。

回答No.2

misatoanna

選択されているセル(ひとつ)にコメントと背景画をセットする簡単な例です。
複数セルへの自動挿入ルーティン部分は省略しています。

エラーは、背景画を塗りつぶすときにコメントが表示されていないからだと
思いますので、※印の行のように指定すればよいでしょう。

Sub CrtCmmt()
　　Selection.AddComment
　　Selection.Comment.Visible = True　　　　'※
　　Selection.Comment.Text Text:="これはテストです。"
　　Selection.Comment.Shape.Select True　　'※
　　Selection.ShapeRange.Fill.UserPicture "C:\MyFiles\Photos\Cats.jpg"
　　ActiveCell.Comment.Visible = False　　　'※
End Sub

お礼

いろいろと試させて頂きました。とっても便利で活用させて頂きたいと思います。

とても初歩的な事で失礼かもしれないんですが、
書いていただいたコードの6行目の "C:\MyFiles\Photos\Cats.jpg"
の部分を指定の画像に書き換えればよいんですよね？
何度やっても画像がコメントの背景に設定されないんですが、単純に書き換えても駄目なんでしょうか？
重ねての質問、大変恐縮なんですが、お手すきの時で構いませんので宜しくお願い致します。

回答No.1

merlionXX

B1からB10セルにコメントを挿入し、コメントの文字は同じ行のF列から持ってくるマクロです。ご参考まで。

Sub TEST01()
For i = 1 To 10
With Cells(i, 2)
.AddComment
.Comment.Visible = False
.Comment.Text Text:=Cells(i, 6).Text
End With
Next
End Sub

お礼

試してみました。こんな簡単にコメントを入れる方法があるんですね。凄いです。
勉強になりました。ありがとうございます。