エクセルのマクロ 複数条件について質問です

質問

• エクセルのマクロを使用して、複数の条件に基づいて検索を行い、セルを赤で塗りつぶす方法について質問があります。
• 具体的には、C3セルに入力された文字列とD3セル、E3セルに入力された文字列とを比較して、C11からC1000のセルに該当するものを赤く塗りつぶしたいです。
• また、C3セル、D3セル、E3セルの3つのセル全てに文字が入力された場合にマクロを実行するように設定したいと思っています。

回答No.2

tsubu-yuki · ベストアンサー

えーと・・
お望みの処理を「マクロを使わず」にあえて手作業で行う場合、
あなたならどうしますか？
「複数条件で検索」しか思いつかず、答えに近づけないなら、
おそらく、ＶＢＡ以前に基本機能の復習をオススメします。
「検索」機能は複数の条件を受け付けないので、
お望みの処理には不向きです。

思いつく方法は、例えば
（１）全行に対し、Ｃ・Ｄ・Ｅ列を３行目と照らし合わせ、
　　　全部合致していたら塗りつぶす。
（２）Ｃ列で検索をかけ、当たった行のＤ・Ｅ列を照らし合わせ、
　　　合致していたら塗りつぶす。
（３）Ｃ・Ｄ・Ｅ列をキーにフィルタをかけ、
　　　抽出されたものを塗りつぶし、フィルタを解除する。
他にもありますが、おそらくこのどれか、でしょう。

「普通」という言葉を押し付けるのは好みではないのですが、
複数の条件で対象を絞り込みたいなら、普通はフィルタ機能、
つまり（３）を選択するような気がします。
ちなみにフィルタは
　　With 対象範囲
　　　　.AutoFilter
　　　　.AutoFilter Field:=1, Criteria1:=抽出条件１
　　　　.AutoFilter Field:=2, Criteria2:=抽出条件２
　　　　　　　　・
　　　　　　　　・
　　End With
こんな感じで使えます。
ま、「マクロの記録」してみればわかりやすいですね。

> C3、D3、E3の3つ全てのセルに入力されたらマクロが実行
Worksheet_Changeイベントに、指定してやれば良いですね。
理解しやすいやり方を挙げるとすると
　　If Application.CountA(Range("C3:E3")) = 3 Then
　　　　～処理～
　　End If
でしょうか。

そんなわけで、今日は大サービスな私なら
Private Sub Worksheet_Change(ByVal Target As Range)
　　' 入力したセルが３行目で、Ｃ～Ｅがすべて埋まっていたら実行
　　If Target.Row = 3 And Application.CountA(Range("C3:E3")) = 3 Then
　　　　Application.ScreenUpdating = False

　　　　' 既にフィルタがかかっていたら解除
　　　　Set MF = ActiveSheet.AutoFilter
　　　　If Not MF Is Nothing Then Range("C10").AutoFilter

　　　　' Ｃ列のデータがある範囲の最終行を調べる
　　　　MR = Cells(Rows.Count, 3).End(xlUp).Row
　　　　' Ｃ列の塗りつぶしを一度解除
　　　　Columns("C:C").Interior.Pattern = xlNone

　　　　' Ｃ～Ｅ列にフィルタ処理、それぞれ３行目を基にフィルタ
　　　　With Range("C10:E" & MR)
　　　　　　.AutoFilter
　　　　　　.AutoFilter Field:=1, Criteria1:=Range("C3")
　　　　　　.AutoFilter Field:=2, Criteria1:=Range("D3")
　　　　　　.AutoFilter Field:=3, Criteria1:=Range("E3")
　　　　End With
　　　　' 抽出された行のＣ列に塗りつぶし（赤）
　　　　With Range(Range("C11"), Range("C11").End(xlDown)).Interior
　　　　　　.Pattern = xlSolid
　　　　　　.ColorIndex = 3
　　　　End With

　　　　' フィルタを解除
　　　　Range("C10").AutoFilter
　　End If

　　Application.ScreenUpdating = True
End Sub
くらいかなぁ、と思いますよ。
パソコンと表のサイズに依りますが１０００行程度なら一瞬ですよ。