FlashのActionScriptについて。

質問

ActionScriptについて、質問があります。
例えば,
on (press){
_root.A.gotoAndPlay("5")
}
とシンボルに書いて動かします。
さらにシンボルの中にある、別のシンボル（たとえてBとします。）をうごかそうと更に、次のようにかきます。
on(press){
_root.A.B.gotoAndPlay("3")
}

フレームナンバーはなんでもいいのですが、
どうしてもシンボルBが言う事を聞いてくれません。
なにか間違いがあるのでしょうか？

どうかFlashに詳しい方教えてください！！

回答No.7

DPE · ベストアンサー

＃３です。

どうやら、ＡとＢの両方でマウスイベントを利用していることが原因のようですね。
Ｂの親であるＡでマウスイベントを検出しようとすると、Ａ全体がヒット領域になります。ＢはＡの一部ですから、Ｂの上でマウスを操作したとしても、Flash 内部ではＡの上でのイベントと判断されます。Ｂに設定した on が正常に動作しないのは、このためだと思います。

ＢがＡの中に存在する限り、Ｂ上でのマウスイベントを press や rollOver / rollOut イベントハンドラで検出するのは、まずアテにできないと思った方がいいかも知れません。
ここは１つ発想を変えて、他のイベントハンドラを利用して、擬似的に press や rollOver / rollOut を検出する方法を考えてみてはいかがでしょうか。

まずは簡単な、press のイベントから。
「ムービークリップがクリックされる」とは、

　・マウスのボタンが押された
　・マウスカーソルがムービークリップの上に重なっている

この２点が条件です。
MovieClip のイベントに、マウスのボタンが押された時に発生する mouseDown があります。このイベントが発生した時、マウスカーソルがムービークリップに重なっていた場合だけ処理を行うようにすると、on(press) と似たような処理になります。
ムービークリップの上にカーソルがあるかどうかは、マウスカーソルの座標とムービークリップの衝突判定を取ることで判断できます。衝突判定には、hitTest というアクションを使います。
スクリプトにすると、こんな感じです。このスクリプトは、シンボルＡの中のＢのインスタンスに設定してください。

　// 擬似 onPress 処理
　onClipEvent(mouseDown)
　{
　　//マウスボタンが押された時、カーソルと重なっていれば
　　//クリックと見なす
　　if( this.hitTest ( _root._xmouse , _root._ymouse , true) )
　　{
　　　/* ここに press イベント発生時の処理を書く */
　　}
　}

（↑このスクリプトをコピーして使う場合は、各行頭のスペースを、全て半角のスペースかタブに置き換えてください。このまま使うとシンタックスエラーになります）

次は rollOver と rollOut の処理です。
同じく hitTest を利用します。
ロールオーバーは当然ながら、マウスが動いた時にしか発生しません。となると、使えそうなイベントは、マウスが動いた時に発生する mouseMove です。
ロールオーバーの時もクリックと同じく、ムービークリップとカーソルが重なっているはずです。
ロールオーバーイベントは普通、ムービークリップにカーソルが乗った、その時１度しか発生しません。しかし、「 mouseMove イベントが発生し、かつ、カーソルとムービークリップが重なっていた」という条件だけで判断すると、ムービークリップの上でカーソルが動く度にイベントが発生してしまいます。
最初の１回だけ必要なら、「ロールオーバーを既に実行した」という情報をどこかに残しておいて、この情報を if 文で判断してから実行すればいいことになります。
そこで、この情報を保存する変数を、１つ用意します。同じシンボルから複数のインスタンスを使うことも考えると、Ｂのシンボルのタイムラインに用意した方がいいと思います。ここでは仮に、rollover_flg という名前にします。
この変数には true か false だけを入れることにします。ロールオーバーを実行済みの時 true 、それ以外の時は false です。最初は実行されていませんので、初期値には false を入れておきます。
つまり、ロールオーバーの条件とは、

　・マウスが動いた時、発生する
　・ムービークリップの上にカーソルがある
　・rollover_flg がfalse

この３つです。
１度ロールオーバーを検出したら２度と検出できないようでは困ります。rollover_flg は、ロールアウトが発生した時に false に直して、再度検出できるようにしておきましょう。

ロールアウトもロールオーバー同様、マウスが動いた時に発生します。
ロールオーバーとの違いは、「マウスカーソルがムービークリップの上にない」ということです。この点を利用します。
単にムービークリップとマウスカーソルが重なっていないだけではなく、ロールオーバーが発生した後にしか、ロールアウトは発生しません。
ロールオーバーが発生したかどうかは、rollover_flg に情報が保存されています。
従って、ロールアウトの条件は、

　・マウスが動いた時、発生する
　・ムービークリップの上に、マウスカーソルが重なっていない
　・rollover_flg が true

このようになります。
これらの考え方通りにスクリプトを組むと、大体、こんなところでしょうか。

　// 擬似 onRollOver / onRollOut 処理
　onClipEvent(mouseMove)
　{
　　//マウスが動いた時、カーソルとムービークリップが重なっている場合
　　if( this.hitTest(_root._xmouse,_root._ymouse,true) )
　　{
　　　//フラグが false の時、ロールオーバーと見なす
　　　if( ! rollover_flg )
　　　{
　　　　//ロールオーバーのフラグを立てる
　　　　rollover_flg = true;

　　　　/* ここに rollOver イベント発生時の処理を書く */
　　　}
　　}
　　//マウスとムービークリップが重なっていなかった場合
　　else
　　{
　　　//フラグが true の時、ロールアウトと見なす
　　　if( rollover_flg )
　　　{
　　　　//フラグをクリア
　　　　rollover_flg = false;

　　　　/* ここに rollOut イベント発生時の処理を書く */
　　　}
　　}
　}

ざっと試しただけなので、何か穴があるかも知れません。不明な点や不具合がありましたら、補足してください。
長くなってすみませんでした。

お礼

ながながありがとうございます。

すごく参考になりました。
また何かありましたらお願いします。

本当にありがとうございました。