エクセル2010のシート保護マクロについて

質問

すべてのシートを保護してくれるマクロを教えてほしいのですが、機能として
「ロックされていないセル範囲の選択」と「セルの書式設定」の二つの機能を許可したものを教えてください。また、逆にすべてのシートの保護を解除するマクロもお願いします。
エクセル初心者のため、見当はずれなことを聞いていたら申し訳ありませんが、いくら探しても上記のようなものを探すことができず、、、。シートが80ほどあるもので、困り果てています。
よろしくお願いします。

回答No.2

cj_mover · ベストアンサー

こんにちは。

すべてのシート、ということなら、下に示すような感じで、、、。

パスワードを設定している（する）場合は、
例えば、"abc123" なら、
Password:=""　の部分を　Password:="abc123"
のように、そちらで書き換えて（２箇所）ください。

.ScrollArea = ""　は大抵は必要のないレアなオプションですが、
範囲の選択を許可する場合には、この設定を確実に解除します。
絶対にScrollAreaを設定したりしない、なら、この処理は不要です。

以下のコードを標準モジュールに貼り付けてください。

Sub PotectAllWorkSheets()　'　8751940　保護
　　Dim wks As Worksheet
　　For Each wks In Worksheets
　　　　With wks
　　　　　　.ScrollArea = ""
　　　　　　.EnableSelection = xlUnlockedCells
　　　　　　.Protect Password:="", _
　　　　　　　　DrawingObjects:=True, Contents:=True, _
　　　　　　　　Scenarios:=True, AllowFormattingCells:=True
　　　　End With
　　Next
End Sub

Sub UnpotectAllWorkSheets()　'　8751940　保護解除
　　Dim wks As Worksheet
　　For Each wks In Worksheets
　　　　wks.Unprotect Password:=""
　　Next
End Sub

余計なことかもですが、＃１さんのコードは、
ActiveSheet　を　Worksheets(i)　に書き換えれば機能すると思います。

因みに、こういうマクロを考える時は、
まず、ひとつのシートについて、やりたいことが出来るようなマクロを書いてみる。
これは、［マクロの記録］で実際の作業を手を動かして行えば、
Sub Macro1()
'
' Macro1 Macro
'

'
　　Sheets("Sheet1").Select
　　ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True _
　　　　, AllowFormattingCells:=True
　　ActiveSheet.EnableSelection = xlUnlockedCells
End Sub
↑こういったコードが得られるので、これを骨格にして、
次に「すべてのシート」でループさせること、次に「保護の解除」、
と段階を踏んでひとつひとつ出来るようにして、
解らない段階を質問するようにしていくと上達が早くていいです。

お礼

求めていたことが完璧にできました！
今後のことまでレクチャーいただき、とっても助かりました！
本当にありがとうございます！

回答No.1

mar00

Sub 保護()
For i = 1 To Worksheets.Count
Worksheets(i).Protect DrawingObjects:=True, Contents:=True, Scenarios:=True _
, AllowFormattingCells:=True
ActiveSheet.EnableSelection = xlUnlockedCells
Next i
End Sub

Sub 保護解除()
For i = 1 To Worksheets.Count
Worksheets(i).Unprotect
Next i
End Sub

でどうでしょうか。

お礼

すみません。今回はno.2さんをベストアンサーに選ばさせていただきました。
一番最初に回答いただきありがとうございました！