エクセルで最安値を探すには

質問

いつもありがとうございます。
既出でしたら申し訳ありません。

早速質問なのですが
サンプル画像を添付しましたので御手数ですが、参照下さい。

エクセルF,G,H列に金額が記入してあります。
F2 , G2 H2の中から最安値を選びＢ２に　F2ならJ 　G2ならU　Ｈ2ならS　となるようにし
選ばれた中の数値をＤ列やE列に入るようにする事はできますでしょうか？

アイテム数がかなり多く、非常に困っています。
詳しい方ご教授お願い致します。

回答No.4

tom04 · ベストアンサー

こんばんは！

一例です。
↓の画像のように作業用の表として換算表を作っておきます。
換算表の1行目にはB列に表示したいアルファベットを入力しておきます。
そして換算表の2行目（K2・L2）に「円」以外のレートを円換算で入力します。

J3セルに
=IF(F3="","",F3)
K3セルに
=IF(G3="","",G3*K$2)
という数式を入れ隣のL3セルまでオートフィルでコピー！
J3～L3セルを範囲指定　→　L3セルのフィルハンドルでずぃ～～～！っと下へコピー！

B3セルに
=IF(A3="","",INDEX($J$1:$L$1,,MATCH(MIN(J3:L3),J3:L3,0)))
C3セルに
=IF($B3="","",IF(MATCH($B3,$J$1:$L$1,0)=COLUMN(A1),INDEX($F3:$H3,,MATCH($B3,$J$1:$L$1,0)),""))
という数式を入れ、E3セルまでオートフィルでコピー！

最後にB3～E3セルを範囲指定　→　E3セルのフィルハンドルで下へコピー！

これで画像のような感じになります。
参考になりますかね？m(_ _)m

お礼

ありがとうございました。
お礼遅くなりすみません。

画像付でわかりやすかったです。
今回間に合わなかったのでまたすぐ使わせて頂きます。
助かりました。

また宜しくお願い致します。

回答No.3

aokii

B2セルに以下の式を入れて下にドラッグコピー。
=INDEX(F$1:H$1,MATCH(MIN(F2:H2),F2:H2,0))

C2セルに以下の式を入れてE列までと下にドラッグコピー。
=IF(F2=MIN($F2:$H2),F2,"")

回答No.2

tsubuyuki

> すべて円に換算したらできますでしょうか？

できますよ。

> 今は列を増やし、円に換算した物を見比べて１つずつやっています。

MINと言う関数について調べてみましょう。

回答No.1

aokii

円とドルでは単位が違うので比較できません。

補足

ありがとうございます。

すべて円に換算したらできますでしょうか？
今は列を増やし、円に換算した物を見比べて１つずつやっています。