エクセルのセルの色分け

質問

Excelで、100*100マスくらいの表の各セルに、0-1200の数字がランダムに記入されています。
このセルの数字の範囲ごとに、自動で色分けするようなことはできないでしょうか？
「0-100」は赤色
「200-300」は水色
・・・
という具合です。
手作業でやろうとしたのですが、さすがに無理でした。。。
ご存知の方いましたら、よろしくお願いいたします。

回答No.6

hige_082

一例です

Sub test()
Dim 開始セル
Dim 終了セル
Dim 色 As Integer
Dim Rng As Range

開始セル = "A1"
終了セル = "CV100"

For Each Rng In Range(開始セル & ":" & 終了セル)
Select Case Rng.Value
Case "", 0: 色 = xlNone
Case Is <= 100: 色 = 4 ' 明るい緑
Case Is <= 200: 色 = 6 ' 黄
Case Is <= 300: 色 = 7 ' ピンク
Case Is <= 400: 色 = 8 ' 水色
Case Is <= 500: 色 = 34 ' 薄い水色
Case Is <= 600: 色 = 35 ' 薄い緑
Case Is <= 700: 色 = 36 ' 薄い黄
Case Is <= 800: 色 = 37 ' ペールブルー
Case Is <= 900: 色 = 38 ' ローズ
Case Is <= 1000: 色 = 39 ' ラベンダー
Case Is <= 1100: 色 = 40 ' ベージュ
Case Is <= 1200: 色 = 44 ' ゴールド
End Select
Rng.Interior.ColorIndex = 色
Next Rng
End Sub

初心者向けです

お礼

ありがとうございます。
色々なやり方があるんですね！
この機会に学んでおけば、以後も役に立つと思うので、教えていただいたものを参考に、すこし勉強したいと思います。
どうもありがとうございました。

回答No.5

ka_na_de

こんばんは。
一例です。

Sub test()
　　Dim myRange As Range, myCell As Range
　　Dim myColor As Variant

　　Set myRange = ActiveSheet.UsedRange
　　myColor = Array(3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15)

　　Application.ScreenUpdating = False
　　For Each myCell In myRange
　　　　If myCell.Value >= 0 And myCell.Value <= 1200 Then
　　　　　　myCell.Interior.ColorIndex = myColor(Int(myCell.Value / 100))
　　　　End If
　　Next myCell
　　Application.ScreenUpdating = True

　　Set myRange = Nothing
　　Set myCell = Nothing
End Sub

お礼

ありがとうございます。
言語があまり理解できてないので、（今までフォートランしか使ったことがないので・・・）この機会に少し勉強して、教えていただいたものを参考に進めたいと思います。
どうもありがとうございました。

回答No.4

rivoisu

多分マクロで解決するのが一番いい方法と思います。
"色指定"というシートを用意します。
このシートにA1から下に100,200,300、400などと記入し
100までの値のところにつける色を100のところにつけます。
対象のシートを選択した状態で以下のマクロを起動すると指定した色になります。
Sub sksksk()
Dim ws1 As Worksheet
Dim 対象範囲 As Range
Dim cl As Long
Dim R As Range
Dim i As Long
Dim Lrow As Long
Set ws1 = Worksheets("色指定")
Lrow = ws1.Cells(Rows.Count, 1).End(xlUp).Row
Set 対象範囲 = Selection
For Each R In 対象範囲
cl = 0
For i = 1 To Lrow
If R.Value <= ws1.Cells(i, 1) Then
cl = ws1.Cells(i, 1).Interior.ColorIndex
Exit For
End If
Next
R.Interior.ColorIndex = cl
Next
End Sub

お礼

ありがとうございます！
それぞれの意味が何んとなくしか把握できないので、自分でも調べて書きたいと思います。
本当にありがとうございました。

回答No.3

jhggjkhkh

No.１です。
すいません条件付書式は3つまでしか作れないんでした。
私の回答は無視して下さい。。。
混乱させてすいません。

お礼

2007なのですが、何度も繰り返せば、この方法でもできるんですね！
どうもありがとうございます！！

回答No.2

rapi223

モバイルからなので、
直接の回答はできませんが、
ExcelのVBAでプログラムを書くと
簡単に出来ると思います。

調べて見てください。

お礼

プログラムの書き方を勉強して、上の方のプログラムを参考に書いてみたいと思います。
どうもありがとうございます。

回答No.1

jhggjkhkh

0-1200の数字がランダムに入力されたセル全てを選択して
ツールバーの書式⇒条件付書式　を選択
条件１
セルの値が　次の値の間　0　100　にして書式ボタン⇒パターンで赤を選択してＯＫ

次に追加ボタンで条件２
セルの値が　次の値の間　200　300　にして書式ボタン⇒パターンで水色を選択してＯＫ

これを繰り返して1200までやってＯＫボタンを押せば解決するはずです。