ジャグ配列生成時の1オリジン

質問

ExcelVBAで、CSVFileを取込み、シートを介さずに
配列へ格納する処理をしています。
尚、一行のデータの数が変わる可能性があるため、
ジャグ配列にしています。

　Dim FileNamePath As Variant 'CSVファイルパス
　Dim CSVFile() As Variant
　Dim ch1 As Long
　Dim RowCnt As Long
～略～
　ch1 = FreeFile
　Open FileNamePath For Input As #ch1
　RowCnt = 1
　Do While Not EOF(ch1)
　　ReDim Preserve CSVFile(RowCnt)
　　Line Input #ch1, CSVFile(RowCnt)
　　CSVFile(RowCnt) = Replace(CSVFile(RowCnt), """", "")
　　CSVFile(RowCnt) = Split(CSVFile(RowCnt), ",")
　　RowCnt = RowCnt + 1
　Loop
～略～

この時、後の処理でやりやすくするために配列の添字を
1からにしたく、行の添字となるRowCntを1としています。
同様に列となる添字も1からとしたくて、モジュールの宣言にて
「Option Base 1」としましたが、上記コードでジャグ配列を
生成すると、(多次元配列で言う)2次元目の添字は
0からとなってしまいます。
　例：CSVFile(1)(0)

このような状況で、ジャグ配列でも1オリジンとするには
どのようにすれば良いのでしょうか。
宜しくお願い致します。

回答No.2

Wendy02 · ベストアンサー

こんにちは。

>BシステムのExportFileに変更

そのままExcelではないのですか？そうすると、答えが違ってきます。
そうなら、Excelは必要ないですね。

その出力仕様は分からないのですが、Jug を受け入れられる他のソフトウェアって、Adobe 系列ぐらいしか思いつきません。ExcelのImport は、２次元で可能です。

なお、Option Base 1　は、使わないようにしました。

>何か出来る方法は無いかなと今回思っていました。
簡単なコードですが、このようにすれば出来ると思います。
'-----------------------------------------

Sub SampleMacro1()
　　Dim FileName As Variant
　　Dim TextLine As String
　　Dim CSVFile() As Variant
　　Dim buf As Variant
　　Dim FNo As Integer
　　Dim i As Long
　　Dim j As Long
　　Dim u As Integer

　　FileName = Application.GetOpenFilename("CSV ファイル(*.csv),*.csv", 1, _
　　"ファイル・インポート")
　　If VarType(FileName) = vbBoolean Then Exit Sub

　　FNo = FreeFile()
　　Open FileName For Input As #FNo
　　i = 1 '初期値
　　Do While Not EOF(FNo)
　　　　Line Input #FNo, TextLine
　　　　buf = Replace(TextLine, """", "")
　　　　buf = Split(buf, ",")
　　　　u = UBound(buf)
　　　　' Cells(i, 1).Resize(, u).Value = buf
　　　　buf = SlideArray(buf)
　　　　ReDim Preserve CSVFile(1 To i)
　　　　CSVFile(i) = buf
　　　　i = i + 1
　　Loop
　　Close #FNo
End Sub

Function SlideArray(ar As Variant) As Variant
　　'１次元の配列の添え字初期値を1にずらす
　　Dim arbuf As Variant
　　Dim i As Long
　　Dim v As Variant
　　If Not IsArray(ar) Then Exit Function
　　ReDim arbuf(1 To UBound(ar) + 1)
　　i = 1
　　For Each v In ar
　　　　If IsNumeric(v) Then
　　　　　　arbuf(i) = CDbl(v)
　　　　Else
　　　　　　arbuf(i) = v
　　　　End If
　　　　i = i + 1
　　Next v
　　SlideArray = arbuf
End Function

お礼

おはようございます。
確認が遅くなってしまいました。

なるほど、別配列に移して作り直す処理をFunction化しているのですね。これなら分かりやすいですし、希望の処理が可能になります。
ありがとうございます！

回答No.3

Wendy02

#2の補足
#1の発言内容と、#2のコードは違うことは、予めご了解ください。Excelのワークシートに出すだけだと思ったから、そのまま１行ずつしてよいと申しましたが、それを、ジャグのままで、CSVFileに格納するとなると、相手のソフトウェアの仕様の問題があると思いますし、それを、添え字初期値が、0か1かは、微妙に左右してくるかもしれないと思い、前言の内容を変えました。なお、#2のコードは、出力はしていませんが、変数の格納でお分かりにはなると思います。

Excelを利用するなら、もちろん、シートを利用してもよいとは思いますが、その分、書き込みには、Rangeオブジェクトを使いますから、オーバーヘッドが掛かってしまいます。なお、変数は、Variant 型で、多次元配列を使っていますから、巨大なファイル構造には向きません。

お礼

たびたびのご回答、及び補足説明まで、誠に有難う御座います！
#2についても、すぐに理解できました。
そうなんですよね、Rangeを使うとどうしても重くなってしまって・・・。

またご質問することもあると思います。その際には是非、宜しくお願い致します。

回答No.1

Wendy02

こんにちは。

全体的にみると、一気に、配列変数に納めようとしているらしいですが、そういうコードで最後まで持っていくのは、よほどVBAに自信があるのでしょうか。

最終段階が見えていないので、はっきりは断言できないのですが、そんな厄介なことをしないで、私なら、一行ずつ処理しますね。それで、大勢に影響ないからです。

>　　ReDim Preserve CSVFile(RowCnt)
>　　Line Input #ch1, CSVFile(RowCnt)

テキスト・ストリームをいきなり、配列の中に入れて、

　　CSVFile(RowCnt) = Replace(CSVFile(RowCnt), """", "")
配列の中で処理していますね。それも、

　　CSVFile(RowCnt) = Split(CSVFile(RowCnt), ",")

配列の中で、さら、分割して配列で入れて、ジャグにしているようです。
Split 関数の中の配列を、もう一度組みなおさなくては、1からにはなりません。

単に格納するのに、添え字を1とか0とか、まったく関係がないと思いますし、貼り付けも関係ありません。マトリックスの初期値が、(0,0)も(1,0)も、(1,1)も、位置をずらせばよいだけです。だから、次世代言語は、廃止になったわけですね。

RowCnt = 1　　'←いらないです。

ReDim Preserve CSVFile(RowCnt)

最終的に貼り付ける目的で、UBound の１次元、２次元の添え字を得たら、その領域を、+1 づつ加えればよいわけです。たぶん、Resizeを使うとは思います。

補足

Wendy02様、こんにちは
早速のご回答、誠に有難う御座います。

一部だけを抜き取ったため分かりにくくなり申し訳ありません。
このマクロは、Aシステムの受入Formatに対応させるため、BシステムのExportFileに変更、追記をして出力するというものです。なので、追記用のデータマスタ以外にはシートを使用する必要がなく、貼付が終局ではありませんでした。すみません、回答材料が足りていませんでした。
また、VBAに自信だなんてとんでもないΣ('Д';シートを使う必要がないために、配列で済ましてしまおうと横着をしたようなものです。
____________

＞＞Split 関数の中の配列を、もう一度組みなおさなくては、1からにはなりません。

baseを1にしてSplitを使うのは初めてだったのですが、Splitによって生成される配列の添字は、OptionBaseに関係なく0になるのですね！
HelpのSplit関数項目に注記がなかったため大丈夫なのかと思っていました。
____________

＞＞単に格納するのに、添え字を1とか0とか、まったく関係がないと思いますし、貼り付けも関係ありません。

私も同意見です。ただその上で、何か出来る方法は無いかなと今回思っていました。
今回のようにどうしてもsplitを使って一括で1を始点にしたければ、
CSVFile(RowCnt) = "," & Replace(CSVFile(RowCnt), """", "")
とでもして0を無視するくらいしか無さそうですね(＾＾；
____________

＞＞RowCnt = 1　　'←いらないです。

ああーすみません。前の処理で使った値の初期化でした。紛らわしかったですね。
____________

>>私なら、一行ずつ処理しますね。

僭越ながら私も、一行ずつ処理をするという考え方で作っていました。
もしよろしければWendy02様の一行ずつ処理をするというロジックを、簡単で結構ですので教えていただけませんでしょうか。