エクセルの関数でお願いいたします

質問

Sheet1のデータを元にしてSheet2に記入した内容のように記録できる関数があれば教えて下さい。
どうか宜しくお願いいたします。

Sheet1
1　Ａ　　　　　　　Ｂ　　　　　Ｃ
2　管理ＮＯ　　　種目　　　　　得点
3　250　　　　　リレー　　　　　54
4　250　　　　　玉入れ　　　　　35
5　253　　　　　綱引き　　　　　23
6　257　　　　　玉入れ　　　　　86
7　257　　　　　100ｍ　　　 　　24
8　257　　　　　サッカー　　　　40
9　262　　　　　ハンマー投げ　　34

Sheet2
1　　Ａ　　　　　Ｂ　　　　　Ｃ　　　　　Ｄ　　　　　Ｅ　　　　　Ｆ　　　　　Ｇ
2　　管理ＮＯ　種目　　　得点　　　種目　　　得点　　　種目　　　得点
3　　250　　　リレー　　　54　　　玉入れ　　　35
4　　251
5　　252
6　　253　　　綱引き　　　23
7　　254
8　　255
9　　256
10　　257　　　玉入れ　　　86　　100ｍ　　24　　サッカー　40
11　　258
12　　259
13　　260
14　　261
15　　262　　ハンマー投げ　34
16　　263

回答No.5

zap35 · ベストアンサー

シート２のB3セル（リレーが表示されるセル）に以下の式を貼り付けます
=INDEX(Sheet1!$B:$B,SMALL(INDEX(SUBSTITUTE((Sheet1!$A$1:$A$100=$A3)*1,0,10^5)*ROW(Sheet1!$A$1:$A$100),),COLUMN(B3)/2))
同様にシート２のC3セル（54が表示されるセル）に以下の式を貼り付けます。
=INDEX(Sheet1!$C:$C,SMALL(INDEX(SUBSTITUTE((Sheet1!$A$1:$A$100=$A3)*1,0,10^5)*ROW(Sheet1!$A$1:$A$100),),COLUMN(C3)/2))

B3、C3を右方向、および下方向にコピーしてください。求める結果になるはずです。ただしこの式では「表示するものがないセル」は＃REF!エラーになります。

エラーを回避するにはIF条件を追加します。B3セルの式は
=IF(SMALL(INDEX(SUBSTITUTE((Sheet1!$A$1:$A$100=$A3)*1,0,10^5)*1,),COLUMN(B3)/2)=1,INDEX(Sheet1!$B:$B,SMALL(INDEX(SUBSTITUTE((Sheet1!$A$1:$A$100=$A3)*1,0,10^5)*ROW(Sheet1!$A$1:$A$100),),COLUMN(B3)/2)),"")

C3セルの式は
=IF(SMALL(INDEX(SUBSTITUTE((Sheet1!$A$1:$A$100=$A3)*1,0,10^5)*1,),COLUMN(C3)/2)=1,INDEX(Sheet1!$C:$C,SMALL(INDEX(SUBSTITUTE((Sheet1!$A$1:$A$100=$A3)*1,0,10^5)*ROW(Sheet1!$A$1:$A$100),),COLUMN(C3)/2)),"")
です。動作は確認済みですが、シート１のデータが100行以上ある場合は式中の「A$1:$A$100」を書き換えてください

お礼

本当に大変感謝いたします。　ありがとうございました。

回答No.4

hallo-2007

ピボットテーブルではダメですか？
管理ＮＯ　100ｍ　サッカー　ハンマー投げ　リレー　玉入れ　綱引き　総計
250　　　　　　　　　　　　　　　　　　　　　　　　54　　　35　　　　　　　　89
253　　　　　　　　　　　　　　　　　　　　　　　　　　　　　23　　　　　23
総計　　　24　　　40　　　　　34　　　　　　54　　　121　　23　　　　　296
こんな感じになりますが？

お礼

ピボットテーブルですと実はこの次の作業で(自分にとっては)難しくなります。
ご回答ありがとうございました。

回答No.3

suekun

#1さんがお答えの様に、この回答方法では答えを伝えるのは
至難の業ですね。

考え方として、シート2のB列は、A列の管理番号がシート1にあるか
検索してあったら種目を拾うって感じです。

D列は、二つ目の管理番号同数があるか検索します。
C列もE列も、それぞれ対応する種目が空白でなければ値を拾いに
行けば良いと思いますよ。

一つだけ、関数は値を参照しているだけなので、シート1の値が
変化したらシート2の値も変化します。

つまりそのままでは、「記録」にはなりません。
値に直して貼り付け直すって作業が必要になります。

お礼

参考にさせて頂きます。　質問の内容で足りなかった所もありましたがアドバイスもいただきありがとうございました。

回答No.2

mu2011

一例です。
sheet2のＡ列は、管理ＮＯが設定済みとします。
（１）sheet2のB2に=IF(COUNTIF(Sheet1!$A:$A,$A2)>INT(COLUMN()/2)-1,INDEX(Sheet1!$B:$B,SMALL(IF(Sheet1!$A$1:$A$100=$A2,ROW(Sheet1!$A$1:$A$100),99999),INT(COLUMN()/2))),"")
（２）sheet2のC2に=IF(COUNTIF(Sheet1!$A:$A,$A2)>INT(COLUMN()/2)-1,INDEX(Sheet1!$C:$C,SMALL(IF(Sheet1!$A$1:$A$100=$A2,ROW(Sheet1!$A$1:$A$100),99999),INT(COLUMN()/2))),"")
配列数式の為、入力完了時にshift＋ctrl＋enterキーを同時押下して下さい。
（３）B2:C2を選択して必要分縦横にコピーして下さい。

お礼

また今後の参考にさせて頂きますありがとうございました。

補足

大変お世話になります。
自分のやり方が悪かっかも知れませんが、エラーがでました。
最初の質問内容でシートの行が1つずれていたのが悪かったと思います。次回から気をつけます。

回答No.1

imogasi

エクセルの関数で
（１）表の組み換え　縦のものを横に　且つ
（２）管理NOの出現の数が不定など
（３）さらに出てこない管理番号は出すけれども内容は飛ばす
の組み換えは苦手です。式が極端に複雑になるか、作業列を使って
複雑といったことになります。初級中級の課題ではない。
軽く考えないで。本質問が丸投げである上に、回答者の答えの丸写しになるだけです。
ーー
VBA向きの課題だが、VBAでも中級を超える技量が要る。
VBAが出来ないならあきらめて下さい。

お礼

早速のご回答大変在り難く存じます。
内容が大変な難題であったという事を察せずにご迷惑をお掛けいたしますた。こちらも大変心苦しく感じます。

次回また機会がありましたら、分かる回答で宜しくお願いいたします。