Excelマクロで教えて下さい。

質問

Excelマクロで教えて下さい。
シート1に下記のような表がありまして
その表の有休・公休取得者の名前を日にち別に
シート2にまとめたいのですがマクロを教えて下さい。
・日にちは3ヶ月並びます。
・人数は50人います。
・休みの種類は5種類あります。
・有：有休　公：公休　出：出勤(本来は空欄です)　
表の入力が難くわかり難いですが宜しく御願い致します。
シート1
名前 3/1 3/2 3/3 3/4 3/5
A氏 出 有 有 出 出
B氏 有 有 出 公 出
C氏 出 出 有 有 出
D氏 出 有 出 出 有
E氏 有 出 出 有 公

シート2
有休
3/1 B氏 E氏
3/2 A氏 B氏 D氏
3/3 A氏 C氏
3/4 C氏 E氏
3/5 D氏

公休
3/1
3/2
3/3
3/4 B氏
3/5 E氏

回答No.1

fumufumu_2006 · ベストアンサー

こんなのでどうでしょうか？

>休みの種類は5種類あります。
というので、いくつでも対応できるようにしたつもりです。
Const restStr = "有：有休,公：公休,出：出勤" '抽出する文字と見出し
で追加してください。
質問の中で"："が全角になっていたので、全角でチェックしていますので、restStr内の"："は全角にしてください。
カンマ","は半角です。

Sub sample()
Const restStr = "有：有休,公：公休,出：出勤" '抽出する文字と見出し
Dim ss As Worksheet
Dim ds As Worksheet
Dim sr As Long
Dim sc As Integer
Dim dr As Long
Dim dc As Integer
Dim rest() As String
Dim i As Integer
Dim msg() As String
Set ss = Sheets("sheet1")
Set ds = Sheets("sheet2")
rest() = Split(restStr, ",")
ds.Cells.Clear
dr = 1
For i = 0 To UBound(rest)
msg = Split(rest(i), "：")
ds.Cells(dr, 1) = msg(1)
dr = dr + 1
For sc = 2 To ss.Cells(1, ss.Cells.Columns.Count).End(xlToLeft).Column
ss.Cells(1, sc).Copy Destination:=ds.Cells(dr, 1) '日付をコピー
dc = 2
For sr = 2 To ss.Cells(ss.Cells.Rows.Count, sc).End(xlUp).Row
If ss.Cells(sr, sc) = msg(0) Then
ds.Cells(dr, dc) = ss.Cells(sr, 1)
dc = dc + 1
End If
Next
dr = dr + 1
Next
dr = dr + 1
Next
End Sub

お礼

遅くなりましたありがとうございます。
いい感じに集計できました。
助かりました。