セルの値の入れ替え(Excel)

質問

エクセルで、各々単一のセル(一つだけのセル範囲)の値を単純に入れ替えるマクロを組んで見ました。これを複数列数と複数列数を入れ替えるマクロに拡張したいと考えています。
具体的には、
□■■■→■■■□
□□■■■→■■■□□
のように単純に入れ替えたいと考えています。
条件は、
□と■の間には他のセルが含まれない状態でののみチェンジ
□と■は、同一のシートで同一の行である場合のみチェンジ
書式などについては一切考えないで単純に値のみチェンジ
□と■の間に他のセルが含まれない状態の確認が、スマートに出来ません。お手数をお掛けしますがアドバイスいただけないでしょうか？宜しくお願い致します。
Sub Cell_Chenge()
Dim MyTmp As String
If Selection.Areas.Count = 2 Then
If Selection.Areas.Item(1).Count = 1 And　　　　　　　Selection.Areas.Item(2).Count = 1 Then
MyTmp = Selection.Areas.Item(1).Value
Selection.Areas.Item(1).Value = Selection.Areas.Item(2).Value
Selection.Areas.Item(2).Value = MyTmp
Else
MsgBox "2つのセル範囲は、各々単一のセルでなければなりません。", vbExclamation, "Cell_Chenge"
End If
Else
MsgBox "この操作は、2つのセルを入れ替えるマクロです。", vbExclamation, "Cell_Chenge"
End If
End Sub

回答No.2

noname#52504

いまいちスマートにできませんでしたが、じみ～に処理するならこんな感じでしょうか。

実務で当座必要な場合はともかく、VBAの勉強として考えていらっしゃるなら、
私の書き方は参考にしない方が良いかもしれません(汗

なお、#1さんへの補足の、
　>(3)"A1"、"C1"の場合、チェンジ可能(行が同じで、長さが同じ)
という条件は、質問文の
　>□と■の間には他のセルが含まれない状態でののみチェンジ
と矛盾するように思われますが、とりあえず"A1"、"C1"の場合は不可、ということで作っています。

Sub Cell_Chenge2()

　Dim myTmp() As Variant　　　　'データ退避用
　Dim i As Long　　　　　　　　 'セル範囲を回すカウンタ
　Dim j As Long　　　　　　　　 '各範囲のセルを回すカウンタ
　Dim k As Long　　　　　　　　 'セル全体を回すカウンタ

　With Selection.Areas

　　'範囲の数をチェック
　　If .Count <> 2 Then
　　　MsgBox "この操作は、2つのセル範囲を入れ替えるマクロです。", vbExclamation, "Cell_Chenge"
　　　Exit Sub
　　End If

　　'それぞれの範囲の行数をチェック
　　If .Item(1).Rows.Count <> 1 Or .Item(2).Rows.Count <> 1 Then
　　　MsgBox "複数行を同時に入れ替えることはできません。", vbExclamation, "Cell_Chenge"
　　　Exit Sub
　　End If

　　'範囲１の右隣のセルと、範囲２の左端セルのアドレスを比較
　　If .Item(1).Item(1).Offset(0, .Item(1).Count).Address <> .Item(2).Item(1).Address Then
　　　MsgBox "範囲が隣接していません。", vbExclamation, "Cell_Chenge"
　　　Exit Sub
　　End If

　　'ココからようやく主処理

　　'データを並べ替えて退避する
　　ReDim myTmp(1 To .Item(1).Count + .Item(2).Count)
　　k = 1
　　For i = 2 To 1 Step -1
　　　For j = 1 To .Item(i).Count
　　　　myTmp(k) = .Item(i).Item(j).Value
　　　　k = k + 1
　　　Next j
　　Next i

　　'退避したデータを書き出す
　　For k = 1 To .Item(1).Count + .Item(2).Count
　　　Union(.Item(1), .Item(2)).Item(k).Value = myTmp(k)
　　Next k

　End With

End Sub
（Excel2003で動作確認済）

ちなみに、主処理の部分ですが、
値だけでなく書式ごと入れ替えても良ければ、２行で済みますし変数も不要です。

　　'範囲２を切り取って、範囲１の左側に挿入する
　　.Item(2).Cut
　　.Item(1).Insert Shift:=xlToRight

回答No.1

imogasi

質問の意味が良くわからない。■□などでなく、実際のありそうな例で書いてください。
１セルの値の、文字列を前後逆順にしたいのですか。
＞□と■の間には他のセルが含まれない状態でののみチェンジ
□と■は、同一のシートで同一の行である場合のみチェンジ
の条件の意味を言い直して見てください。
コードから割り出すのは大変。

補足

大変失礼致しました。
A, B, C, D, E
1,T11,T12,T13,T14,
2, ,T22,T23,T24
3,T31,T32,T33,T34,T35
A←列の番号
1←行の番号
","←セルの区切りを表す
Txx←セルの値を表す
とします。
(1)一つ目のセルの選択範囲を"A1:B1"とし、二つ目のセルの選択範囲を"C1:D1"とした場合は、一つ目のセルと二つ目のセルの間に選択されていないセルがはさまれていないのでチェンジ可能
(2)"A1:B1"、"C1"の場合、チェンジ可能(一つ目と二つ目のセル範囲の行は同じで長さは違うが連続している）
(3)"A1:B1"、"D1"の場合、チェンジ不可(行は同じだが、長さが違うし間に"C1"のセルがある)
(3)"A1"、"C1"の場合、チェンジ可能(行が同じで、長さが同じ)
(4)"A1:B1"、"C2:D2"の場合チェンジ不可(列が違う)
(5)"Sheet1\A1:B1"、"Sheet2\C1:D1"の場合チェンジ不可(シートが違う)
このような感じなんですが、気持ちが伝わるでしょうか？
何度もお手数をお掛けして申し訳ありません。
宜しくお願いいたします。