沢山のCSVを一シートにまとめるコマンド

質問

フォルダ内に1000ほどのCSVファイルがあります。
ファイルは18列で、一行目は常にタイトル行になっています。
行数は、まちまちで2～40程。全部外部データの取り込みで
取り込むと30000行ほどになります。

2行目以降からのデータを一括でまとめたいのですが
よい方法はないでしょうか。

回答No.2

noname#97729 · ベストアンサー

' フォルダ内のCSVファイルを統合
Option Explicit
Dim strLine
Dim Fs
Dim objOutput
Dim objIntput
Dim oTarget
Dim oFile
Dim FileEx
Dim t
Dim s
Const ForWriting = 2

Set Fs = WScript.CreateObject("Scripting.FileSystemObject")

Set objOutput = Fs.OpenTextFile("result.txt", ForWriting, True) ' result.txtを書き込みモードで開く

t = 0
s = 0

' 現在のフォルダ内のファイル名を格納
Set oTarget = Fs.GetFolder(".")

For Each oFile In oTarget.Files 'すべてのファイルに繰り返す

FileEx = Fs.GetExtensionName(oFile) ' ファイル名から拡張子を抜き出す
If FileEx = "csv" Then ' 拡張子を比較 (.csv)のとき処理

Set objIntput = Fs.OpenTextFile(oFile.Name,1,0)

strLine = objIntput.ReadLine 'CSVファイルの先頭一行読み込み

Do While objIntput.AtEndOfStream <> True 'ファイルの終端まで処理
strLine = ""
strLine = objIntput.ReadLine ' CSVファイルの読み込み
objOutput.WriteLine strLine ' 出力ファイルに書き出す
s = s + 1
Loop

objIntput.Close
Set objIntput = Nothing

t = t + 1

End If

Next

objOutput.Close
Set objOutput = Nothing
Set Fs = Nothing

MsgBox "処理終了 CSV 数 = " & t & " 出力行数 = " & s

----------------------------------------------------
ＶＢＳｃｒｉｐｔで作りました。
ＣＳＶファイルの一行目を除き残りの行を統合します。

使い方
先頭の　Option Explicit　から　MsgBox　の最後までコピーして
メモ帳などに貼り付けて保存してください。（名前はなんでもいいです）
そして　拡張子を(.txt)から(.vbs)に変更します
アイコンの形がメモ帳からSの形をしたものに変わります。
ＴＥＳＴフォルダをデスクトップにでも作り、そこにＣＳＶファイルをコピーして
同じＴＥＳＴフォルダにSの形をしたアイコン「(.vbs)のファイル」を入れてください
で、Sの形をしたアイコンをダブルクリックすると(result.txt)のファイルができます。

お礼

ありがとうございます。
半手動でやっていたものが一発で解決しました。
なんとお礼を言っていいのやら・・・。ありがとうございました。

回答No.1

vaio09

test1.csv :
HogeHoge,1,2,3
HogeHoge,4,5,6

test2.csv :
HogeHoge,100,200,300
HogeHoge,400,500,600

上記のようなファイル構成で「1列目の"HogeHoge"だけを削除したい、という
ことでしょうか？ご質問の実現結果を

1,2,3
4,5,6
100,200,300
40,500,600

となると想定します。
（文面からは、行と列の用語が混在して、ちょっとわかり難かったです。上記理解は、あくまでも私の理解ですが、以下の考えは、他の処理でも役立ちます）

18列、ということは、,（コンマ）区切りで横方向にデータが並んでいると見られますから、「最初のコンマを含むデータを除くデータを抽出する」処理をファイル数だけ繰り返し、同じ出力ファイルに書き出せば済みます。

sed/grep/awkなどの文字列置換/抽出コマンドを使用したスクリプトを使う方法が考えられます。
Windowsでこれを実現するには、以下を試してください。

1)以下サイトからsedをダウンし、解凍します。
http://www.vector.co.jp/soft/win95/util/se028215.html

2)上記と同じフォルダに、csvファイルをコピーします

3)コマンドプロンプトから1のフォルダに移動します

4)1のフォルダに、以下内容のバッチファイル「test.bat」を作成します

for %%x in (*.csv) do sed -e "s/HogeHoge,//g" %%x >> output.txt

5)test.batを実行します。

この構文のうち、*.csv は、調査対象のCVSファイルのことです。
HogeHoge という部分は、1列目の文字列で、全てのCSVで同じ文字列が入っているとします。

出来上がるファイルは、output.txtという名前で、

1,2,3
4,5,6
100,200,300
40,500,600

という内容になります。

※各CSVファイルは、最終行が必ず改行コードで終わっている必要があります。

お礼

ありがとうございます。
色々な方法があるもんですね。こちらの方法もためさせていただきます。
本当にありがとうございました。