最小値（最大値）を探す

質問

セルB2～B16及びD3～D20中でセルF5の値より小さければその値をF5に書き込むには！！
また、セルF7の値より大きければその値をF7に書き込むには！！
関数で出来なければ、VBAでよろしくお願いします。
こちらのアプリケーションは、エクセル２０００です。

回答No.6

nishi6

補足について、VBA部分を追記、変更してみました。
まだ主旨が理解できていないと思います。日付とデータはそれぞれで最大値・最小値を求めています。

個人的には、数値の最大値・最小値に対応する日付が必要？とも思いますが、補足に『日付も同じようするには・・・』とあるので、日付とデータは無関係に最大値・最小値を求めています。違っていれば補足して下さい。

※日付、データの範囲には一ヶ月単位くらいで入力し、過去の最大値・最小値を表示している雰囲気でしょうか。

Private Sub Worksheet_Change(ByVal Target As Range)
　　Dim chkAreaAll As Range '最小値、最大値を調べる範囲(全部)
　　Dim chkAreaDay As Range '最小値、最大値を調べる範囲(日付)
　　Dim chkAreaNum As Range '最小値、最大値を調べる範囲(数値)

　　Set chkAreaDay = Union(Range("A2:A16"), Range("C3:C20"))
　　Set chkAreaNum = Union(Range("B2:B16"), Range("D3:D20"))
　　Set chkAreaAll = Union(chkAreaDay, chkAreaNum)

　　On Error GoTo ErrorHandler

　　Application.EnableEvents = False '再度イベントが発生するのを止める
　　'最小値、最大値を調べる
　　If Not Intersect(Target, chkAreaAll) Is Nothing Then
　　　　'日付
　　　　Range("E5") = Application.Min(chkAreaDay, Range("E5"))
　　　　Range("E7") = Application.Max(chkAreaDay, Range("E7"))
　　　　'数値
　　　　Range("F5") = Application.Min(chkAreaNum, Range("F5"))
　　　　Range("F7") = Application.Max(chkAreaNum, Range("F7"))
　　End If
　　Application.EnableEvents = True

　　Exit Sub
ErrorHandler:
　　Application.EnableEvents = True
End Sub

補足

日付についてお願いします。日付は、最小値(最大値)の日付をそのまま表示するようにお願いします。つまり、最小値(最大値)データーの左側の日付をそのままE5(E7)にコピーします。また、A2～D20までのデーターが変わってもF5とF7のデーターが更新しない限りE5とE7もそのままの状態です。F5とF7が更新した時は、E5とE7の日付はF5とF7の左側の日付に更新します。　例、E5＝5/1・F5＝123その時データーA2～D20までの中で最小値が103で、103のデーターの左側の日付が5/12その時セルE5＝5/12・セルE7＝103とするには
よろしくお願いします。